Ver la Versión Completa : Clases e Interfaces
Virata
05-09-2004, 11:44:11
Hola a todos.
Antes de lanzar esta pregunta he buscado en los foros sin encontrar nada al respecto. Espero que alguien me sepa contestar. Ahí va:
Estoy creando varios controles cada cual de una clase diferente.
Estos controles deben almacenarse en un array y para arreglar el tema de las diferencias de clase, he creado un interfaz con un metodo y la he implementado en todos ellos.
De esta manera declaro el array del tipo de la interfaz y así puedo acceder al procedimiento comun a todos descrito en la interfaz , pero que cada clase implementa a su modo.
array[1].HazAlgo;
Según el objeto que contenga en cada caso hará una cosa u otra.
Mi problema es que estos objetos los tengo que enviar a otro procedimiento que recibe como parámetro un objeto TObject (admite cualquier objeto) y necesito conocer si dicho objeto implementa una determinada interfaz para que haga o no algo.
He probado con getInterface pero no acabo de ver como funciona.
En fin, gracias de antemano.
Salu22222
Hola Virata:
Prueba de esta forma:
procedure Miprocedimiento(Objeto:TObject);
begin
if Supports(Objeto,IMiInterface) then
(Objeto as IMiInterface).HazAlgo;
end;
No lo he probado, pero creo que es así. Por cierto que la función Supports (o mejor dicho las funciones porque hay distintas variantes) están definidas en la unidad SysUtils.
Espero que te sirva.
Saludos.
P.D.: No me había dado cuenta de que era tu primer mensaje. Bienvenido al Club.
jachguate
05-09-2004, 16:48:58
También podes valerte directamente del método QueryInterface de la interfaz IUnknown, que supongo, será lo que la funcion Supports hace.
Hasta luego.
;)
roman
05-09-2004, 21:51:57
También podes valerte directamente del método QueryInterface de la interfaz IUnknown
Pero la rutina recibe on TObject, no un IUnknown (o IInterface) por lo que para usar QueryInterface primero tendría que obtener una interfaz a IUnknown y ver si esa implementa IMiInterface. Esto es más o menos lo que hace la función Supports.
// Saludos
jachguate
05-09-2004, 22:11:57
claro... seria algo como:
Procedure TMiForm1.Button1Click(Sender : TObject);
Begin
try
(sender as TInterfacedObject).QueryInterface...
except
on EInvalidTypeCast do
ShowMessage('Objeto no implementa ninguna interfaz!');
end;
end;
roman
05-09-2004, 22:21:09
Sí bueno, pero resultó más directo lo de Supports ¿no? :p
Por otro lado puedes tener objetos que no desciendan de TInterfacedObject pero que sí implemente la interfaz.
// Saludos
jachguate
06-09-2004, 02:40:51
Sí bueno, pero resultó más directo lo de Supports ¿no? :p
Por otro lado puedes tener objetos que no desciendan de TInterfacedObject pero que sí implemente la interfaz.
// Saludos
Tenes toda la razón. Sabiendo que el primer método era funcional, mi intervención pretendía dar una alternativa, digamos, a mas bajo nivel, que propiciara un poco mas de investigación de parte del interesado.
Al menos, he captado tu interes.. espero que ocurra lo mismo con quien inició el hilo.. :D
Saludos.
Virata
06-09-2004, 09:12:01
Efectivamente jachguate, tienes todo mi interes.
A ver si tengo un rato y paso a probar los procedimientos que me habeis indicado. Muchisimas gracias.
Salu22222
Virata
06-09-2004, 09:51:29
Hola de nuevo.
Os voy a poner el codigo de prueba que estoy realizando.
Esta es la interface:
unit MyInterface;
interface
type
IMyInterface = interface ['{6E93F07C-AD0C-494B-85BC-A960AF01EF0A}']
procedure HacerAlgo();
end;
implementation
end.
Esta es la clase, hereda de TTimer por heredar de algo. En la realidad heredará de TGraphicControl.
unit MyClass;
interface
uses QExtCtrls,Dialogs,MyInterface;
type
TMyClass=Class(TTimer,IMyInterface)
procedure HacerAlgo();
end;
implementation
procedure TMyClass.HacerAlgo();
begin
showmessage('Estoy haciendo algo');
end;
end.
y este es el código del form con el boton.
unit Unit1;
interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls,ExtCtrls,MyClass,MyInterface ;
type
TForm1 = class(TForm)
Button1: TButton;
Timer1: TTimer;
procedure Button1Click(Sender: TObject);
procedure Miprocedimiento(Objeto:TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.Button1Click(Sender: TObject);
var
MiClase:TMyClass;
begin
MiClase:=TMyClass.create(self);
MiProcedimiento(MiClase);
MiClase.Free;
end;
procedure TForm1.Miprocedimiento(Objeto:TObject);
begin
if Supports(Objeto,IMyInterface) then
(Objeto as IMyInterface).HacerAlgo();
end;
end.
Si en MiProcedimiento recibo el parámetro Objeto como TMyClass, funciona bien, pero no tiene gracia ya que este procedimiento debe aceptar cualquier tipo de objeto.
En el caso de declarar Objeto como TObject, se produce el siguiente error de compilación:"Operator not aplicable to this operand type" en la línea "(Objeto as IMyInterface).HacerAlgo();" y es por la sentencia as
Puedo hacer typecast a Objeto para que sea TMyClass, pero el problema es que no todos los objetos que recibirá será TMyClass.
No se como puedo arreglarlo.
Gracias de nuevo.
Salu22222
Virata
06-09-2004, 10:04:01
Hola de nuevo.
Releyendo vuestros mensajes se me ha ocurrido hacer lo siguiente:
procedure TForm1.Miprocedimiento(Objeto:IInterface);
begin
if Supports(Objeto,IMyInterface) then
(Objeto as IMyInterface).HacerAlgo()
else
showmessage('este no tiene la interface');
end;
Y ahora si funciona.:D
También lo puedo hacer con IUnknown y funciona igualmente.
Gracias
Salu22222
roman
06-09-2004, 15:40:04
En el caso de declarar Objeto como TObject, se produce el siguiente error de compilación:"Operator not aplicable to this operand type" en la línea "(Objeto as IMyInterface).HacerAlgo();" y es por la sentencia as
Recién me doy cuenta que en efecto el uso de Supports era incorrecto tal como se había puesto originalmente.
Si aún deseas usar TObject en lugar de IInterface como tipo de datos del parámetro lo puedes hacer con Supports que acepta un tercer parámetro en el que se recibe una interfaz en caso de soportarse:
procedure MiProcedimiento(Obj: TObject);
var
Intf: IMyInterface;
begin
if Supports(Obj, IMyInterface, Intf) then
Intf.HacerAlgo();
end;
// Saludos
Virata
06-09-2004, 16:23:19
Ciertamente este último uso de Support me parece más limpio y funciona correctamente en el caso de que un objeto implemente un tipo determinado de interface.
Gracias por todo.
Salu22222
Ciertamente, es mas elegante. Ya dije que no lo había comprobado, estaba poniéndolo de memoria. Perdonad por el tiempo perdido.
roman
06-09-2004, 17:09:28
Ya dije que no lo había comprobado, estaba poniéndolo de memoria. Perdonad por el tiempo perdido.
Ciertamente lo habías dicho. No tienes que disculparte, realmente tu solución fue la que a fin de cuentas se usó.
Va un 'regaño' amistoso para el amigo Virata: al ver que no funcionaba el Supports tal como se escribió originalmente lo mínimo era consultar la ayuda acerca de la función en donde te hubieras dado cuenta de inmediato del uso correcto. ;)
// Saludos
Virata
07-09-2004, 10:10:15
Acepto el regaño de buen grado ;) .Las prisas nunca son buenas consejeras. Gracias de nuevo y perdonad las molestias.
Salu22222
vBulletin v3.6.8, Derechos ©2000-2024, Jelsoft Enterprises Ltd.