Como obtener la Capacidad Total del Disco Duro, independientemente de las particiones

[JoAnCa]

Como obtener la capacidad total del Disco Duro independientemente de las particiones que tenga, en los trucos y foros, lo que me he encontrado me dan la de la particion seleccionada, no la del disco total, que es la que necesito. :rolleyes:

Un ejemplo de la informacion que necesito es:

ProductoID: Maxtor 6V080E0 (Ok, ya tengo la forma)
Num. Serie: V20TFSNG (Ok, tambien)
Capacidad: 80 GB (?? No tengo como obtenerla)
Tipo: IDE (IDE o SATA) (?? Tampoco lo tengo ?)

Quisiera que me digan como obtener los dos datos que me faltan

[Neftali [Germán.Estévez]]

En la sección de ejemplos de mi página tienes uno titulado "Tamaño de ficheros/directorios y espacio en disco"; Con el puedes obrener el espacio en disco de las particiones, pero si sabes el Serial o Et. de volumen de cada partición, puedes sumar las que pertenecen al mismo disco y calcular así el espacio libre y ocupado de los discos completos.

[Jose_Pérez]

En la sección de ejemplos de mi página tienes uno titulado "Tamaño de ficheros/directorios y espacio en disco"; Con el puedes obrener el espacio en disco de las particiones, pero si sabes el Serial o Et. de volumen de cada partición, puedes sumar las que pertenecen al mismo disco y calcular así el espacio libre y ocupado de los discos completos.

Estimado Neftali: He buscado el artículo al que haces referencia en tu web, pero no lo encuentro. Por favor, ¿podrías poner aquí el enlace?

Precisamente necesito diferenciar si una unidad es un disco físico o una partición para posteriormente sumar los tamaños.

Saludos.

[Neftali [Germán.Estévez]]

Para temas de tamaño, hay dos ejemplos en la web que te pueden servir.
La demo del componente TDiskInfo (http://neftali.clubdelphi.com/?p=240).
Por otro lado hay un ejemplo antiguo para calcular tamaños de ficheros, discos, directorios, aquí (neftali.clubdelphi.com/ejemplos_files/file_directory_sizes.zip).

No se si te van a servir para lo que necesitas, ya que pides que quieres diferenciar entre discos y particiones.

A día de hoy yo te recomendaría WMI.
Con las clases Win32_DiskDriveToDiskPartition (con esta puedes saber qué particiones pertenecen a cada disco) y Win32_LogicalDisk (con esta saber toda la información de cada partición) puedes hacer lo que necesitas de forma muy fácil.

Otras veces hemos hablado en los foros de WMI. Busca los mensajes y échales un vistazo.

AÑADO:
Acabo de encontrar este ejemplo de otro hilo. Te lo adjunto, para que veas cómo puedes hacerlo.

[Jose_Pérez]

Gracias por tu rápida respuesta. He descagado el archivo InformacionDisco.zip, pero al descromprimirlo me dice que alchivo tiene un formato desconocido o está dañado. ¿Podrías intentar colgarlo de nuevo, por favor?

[Neftali [Germán.Estévez]]

:confused::confused::confused:
Prueba con este en .RAR

[Casimiro Notevi]

Sólo comentar que he descargado y me funcionan perfectamente tanto el zip como el rar

[Neftali [Germán.Estévez]]

Es muy probable, pero es verdad que alguna vez ha pasado en los foros.
Comprimo directamente desde TotalCommander y las librerías que utiliza a algunos usuarios les da problemas. Es una intriga que o hemos llegado a desvelar.

[escafandra]

Una aproximación al problema a bajo nivel puede ser leer directamente la unidad física, para extraer la tabla de particiones, donde encontraremos el tamaño en sectores de cada una. En este ejemplo muestro como hacerlo asumiendo que el tamaño de un sector es 512 bytes:


uses
Windows, SysUtils;

type

// Entrada de la tabla de particiones
PARTITION_ENTRY = record
Boot_Flag: BYTE; // Bandera de arranque
CHS_Begin: array [1..2] of BYTE;
_Type: BYTE; // Tipo de sistema de archivos
CHS_End: array [1..2] of BYTE;
LBA: DWORD; // Sector del ID volumen de la particición
NumberOfSectors: DWORD; // Tamaño en sectores de la partición
end;
PPARTITION_ENTRY = ^PARTITION_ENTRY;


function GetSizeOfPhysicalDisk(Name: String): UINT64;
var
hFile: Cardinal;
MBR: PByteArray;
BytesRead: Cardinal;
PE: array [0..4] of PARTITION_ENTRY;
i: integer;
Sectors: DWORD;
begin
Sectors:= 0;
GetMem(MBR,$0200);
hFile:= CreateFile(PChar(Name), GENERIC_READ, FILE_SHARE_READ, nil, OPEN_EXISTING, FILE_FLAG_NO_BUFFERING, 0);
if hFile <> INVALID_HANDLE_VALUE then
begin
SetFilePointer(hFile, 0, nil, FILE_BEGIN);
ReadFile(hFile, MBR^, 512, BytesRead, nil);
CopyMemory(@PE, Pointer(DWORD(MBR)+446), 16*4);
for i:=0 to 3 do inc(Sectors, PE[i].NumberOfSectors);
CloseHandle(hFile);
end;
FreeMem(MBR);
Result:= (UINT64(Sectors)-1) * 512;
end;


Un ejemplo de uso:

var
TotalSize: UINT64;
begin
TotalSize:= GetSizeOfPhysicalDisk('\\.\PhysicalDrive0');
end.



Saludos.

[Jose_Pérez]

Una aproximación al problema a bajo nivel puede ser leer directamente la unidad física, para extraer la tabla de particiones, donde encontraremos el tamaño en sectores de cada una. En este ejemplo muestro como hacerlo asumiendo que el tamaño de un sector es 512 bytes:

Realmente no es tan difícil obtener al tamaño de cada partición. Lo complicado es saber que particiones pertenecen a un mismo disco físico para así poder agruparlas y sumar los tamaños.

[Jose_Pérez]

AÑADO:
Acabo de encontrar este ejemplo de otro hilo. Te lo adjunto, para que veas cómo puedes hacerlo.

Quizás olvidé decir que estoy trabajando con Delphi 5. Al cargar la aplicación, para empezar, no encuentra la clase TValueListEditor. Y al ejecutar me dice que en la unidad Type.bas no están declarado los siguientes identificadores: PLongint, PInteger, PSmallInt, PDouble, y PByte

¿Qué debo hacer?

[escafandra]

Realmente no es tan difícil obtener al tamaño de cada partición. Lo complicado es saber que particiones pertenecen a un mismo disco físico para así poder agruparlas y sumar los tamaños.

Pues si te fijas en el código, encuentra las particiones de un mismo disco físico y suma sus tamaños.

Si lo que prenendes es saber que disco físico corresponde a una unidad, tampoco es tan complicado.


Saludos.

[escafandra]

Expongo otro ejemplo para calcular el tamaño de un disco sabiendo una unidad de volumen. La filosofía se basa en encontrar el número de disco físico a partir de una letra de unidad para luego explorar las unidades activas y ver si pertenecen al disco físico previamente conocido. El resto es sumar.

Este método puede contar algo de menos espacio que puede estar perdido en sectores no usados. En realidad el verdadero espacio disponible para el usuario después de formatear una unidad es menor que el nominal.


uses
Windows, SysUtils;

function GetPhysicalDrive(Volume: Char): integer;
var
hFile: THandle;
Vde: array [0..56] of BYTE;
BytesReturned: Cardinal;
begin
Volume:= char((ord(Volume) or 32)-32);
Result:= -1;
hFile:= CreateFile(PAnsiChar('\\.\' + Volume + ':'),0,0,nil, OPEN_EXISTING, 0, 0);
if hFile <> INVALID_HANDLE_VALUE then
begin
if DeviceIoControl(hFile, IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS, nil, 0, @Vde, SizeOf(Vde), BytesReturned, nil) then
Result:= PBYTE(DWORD(@Vde)+8)^;
CloseHandle(hFile);
end;
end;

function GetDriveSizeFromVol(D: char): UINT64;
var
LD: DWORD;
Ch: char;
Disk: DWORD;
begin
Result:= 0;
Disk:= GetPhysicalDrive(D);
LD:= GetLogicalDrives();
Ch:= 'A';
while LD <>0 do
begin
if ((LD and $1) = 1) and (GetPhysicalDrive(Ch) = Disk) then
Inc(Result, DiskSize(Ord(Ch) - Ord('A') + 1));
LD:= LD shr 1;
inc(Ch);
end;
end;



Un ejemplo de uso:

var
TotalSize: UINT64;
begin
TotalSize:= GetDriveSizeFromVol('c');
Writeln(TotalSize);
ReadLn;
end.



Saludos.

[Jose_Pérez]

En principio esa es la idea que yo perseguía.

Estoy intentando probarlo, pero me da un error de identificador no declarado. 'IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS'

He añadido las unidades Windows y SysUtils a uses. Trabajo con Delphi 5

[escafandra]

Estoy intentando probarlo, pero me da un error de identificador no declarado. 'IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS'

const
IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS = $00560000;


Saludos.

[escafandra]

Coloco de nuevo el código completo para que no aparezca el problema con la Cte IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS en los usuarios que copien el código tal cual:


uses
Windows, SysUtils;

const
IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS = $00560000;

function GetPhysicalDrive(Volume: Char): integer;
var
hFile: THandle;
Vde: array [0..56] of BYTE;
BytesReturned: Cardinal;
begin
Volume:= char((ord(Volume) or 32)-32);
Result:= -1;
hFile:= CreateFile(PAnsiChar('\\.\' + Volume + ':'),0,0,nil, OPEN_EXISTING, 0, 0);
if hFile <> INVALID_HANDLE_VALUE then
begin
if DeviceIoControl(hFile, IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS, nil, 0, @Vde, SizeOf(Vde), BytesReturned, nil) then
Result:= PBYTE(DWORD(@Vde)+8)^;
CloseHandle(hFile);
end;
end;

function GetDriveSizeFromVol(D: char): UINT64;
var
LD: DWORD;
Ch: char;
Disk: DWORD;
begin
Result:= 0;
Disk:= GetPhysicalDrive(D);
LD:= GetLogicalDrives();
Ch:= 'A';
while LD <>0 do
begin
if ((LD and $1) = 1) and (GetPhysicalDrive(Ch) = Disk) then
Inc(Result, DiskSize(Ord(Ch) - Ord('A') + 1));
LD:= LD shr 1;
inc(Ch);
end;
end;


Un ejemplo de uso:

var
TotalSize: UINT64;
begin
TotalSize:= GetDriveSizeFromVol('c');
Writeln(TotalSize);
ReadLn;
end.



Saludos.

[Jose_Pérez]

Muchas gracias Escafandra. Es lo que necesitaba. También mi agradecimiento a Neftali.

Saludos.