Inserción masiva en Firebird
 

Hola a tod@s.

Necesito hacer una inserción de muchos datos y tengo el problema de que al paso que va puede tardar más de un año.

Yo pensaba que podía utilizar:

Código Delphi [-]
Query.Close;
Query.SQL.Text := 'SELECT * FROM MyTable WHERE Id=0;';
Query.Open;
For I := 0 To nRecords - 1 Do
    Begin
    Query.Insert;
    Query.FieldValues['Name'] := Value;
    ... ...
    Query.Post;
    End;

Pero, a partir de la primera inserción, me da error diciendo que intento acceder a una consulta cerrada y me obliga a hacer:

Código Delphi [-]
For I := 0 To nRecords - 1 Do
    Begin
    Query.Close;
    Query.SQL.Text := 'SELECT * FROM MyTable WHERE Id=0;';
    Query.Open;
    Query.Insert;
    Query.FieldValues['Name'] := Value;
    ... ...
    Query.Post;
    End;

Con lo cual me obliga a hacer una búsqueda y una inserción, pero yo no necesito hacer la búsqueda porque pueden haber registros repetidos.

¿Alguien sabe cómo puedo mejorar la velocidad?

Gracias.

No se qué componentes utilizas, pero deberías utilizar el TQuery más simple.

Código Delphi [-]
    Query.Close;
    Query.SQL.Text := 'INSERT INTO MyTable (ID, DESCRIPCION, ...) VALUES (?ID, ?DESCRIPCION, ...)';
    For I := 0 To nRecords - 1 Do
    Begin
       Query.Close;
       Query.ParamaByName['ID'] := id;
       Query.ParamaByName['DESCRIPCION'] := descripcion;
       ...
       Query.ExecQuery;
    End;
    Query.Close;

ExecQuery no devuelve datos por lo que debería ser mucho más rápido.

Si las tablas están en la misma BD es mucho mas eficiente un INSERT..SELECT:

Código SQL [-]
INSERT INTO MyTable (ID, DESCRIPCION, ...)
SELECT (ID, DESCRIPCION, ...) FROM origen

Gracias por la respuesta, pero se trata de insertar datos que están en un archivo externo y debo procesar antes de su inserción.

Hola,

en qué formato están los datos a importar?

Cuántos datos son?

Saludos

Los archivos fuente están en formato CSV, pero esa información (comprimida) no la puedo pasar directamente a Firebird, yo cojo los datos fuente, los proceso y el resultado es el que pasa a Firebird.

Las fuentes 1,4 GB, pero el resultado de mi proceso generan sobre 500GB.

Desactiva trigers, índices y demás antes de iniciar y lo vuelves a activar cuando terminas.

Gracias, ya está así.

No sé si otro motor me puede permitir hacer inserciones si tener que cerrar y abrir con una consulta cada inserción.

¿Cerrar y abrir consulta cada inserción? ¿A qué te refieres?

De todas formas, hay muchas cosas a tener en cuenta de las que no has dado ninguna información.
Aparte de que si son 500 GB, ¿eso lo importas una vez o acaso es algo que haces cada día?

Ninguna BD va a ser rápida importando 500 GB de datos, y menos todavía leyéndolo de un fichero de texto CSV.
Luego las consultas sí son rápidas, no influye el tamaño de la BD... si está bien diseñada.

Y aparte no sabemos qué equipo está ejecutando esa BD, qué sistema operativo, qué configuración, cuánta memoria tiene, cómo tienes configurado los caché, directorios temporales, si los discos son rápidos, si hay mucha gente conectada, de qué tamaño son los discos, etc. etc. etc.

Por no saber, no sabemos ni qué componentes usas, ni cómo están configurados, ni... nada de nada.

Lee esta documentación... habla de 100.000 registros y de que va rápido.

https://www.ibexpert.net/ibe/pmwiki....1s%20elementos

Seguramente tienes que hacer un análisis más profundo, hacer la carga por la noche para no impactar en el rendimiento, ... no sé, hay varias medidas que puedes tomar, pero dependerán de la situación.

Tampoco sabemos cada cuánto tiempo tienes que importar ese volumen de datos. O si de ese volumen todos los datos se insertan o algunos se insertan y otros se actualizan.

Por de pronto veo que haces Query1.Insert. Así poco vas a poder correr. Todo apunta a que tengas que hacer INSERTs a tutiplén directamente.

Tengo un proceso mensual que carga casi 100.000 registros de una bbdd a otra ( no son firebird ) y tarda 3 minutos y medio. La BBDD ni está optimizada ni nada, tampoco el proceso, no me he roto mucho la cabeza. Se lanzan tantas INSERT como registros.
"Actualizados 96449 registros mediante 96449 instrucciones."

Mira a ver y sigue informando.

Saludos

Si utilizas Firedac, mírate esta opción para inserción masiva: https://docwiki.embarcadero.com/Code...y.Batch_Sample

Yo edito la base de datos con SQL Manager Lite, por favor si penáis que ibExpert es mejor, me lo decís.

No obstante, no sé si el IDE que utilizo para editar la estructura de la base de datos, puede resolver mi problema.

Casimiro es cierto que he facilitado poca información, pero en mi humilde opinión eso no afecta a mi consulta inicial.

¿Hay alguna forma con la que pueda insertar sin tener que cerrar y hacer una consulta?

Contenido de mi primer post:

Código Delphi [-]
Query.Close;
Query.SQL.Text := 'SELECT * FROM MyTable WHERE Id=0;';
Query.Open;
For I := 0 To nRecords - 1 Do
    Begin
    Query.Insert;
    Query.FieldValues['Name'] := Value;
    ... ...
    Query.Post;
    End;

Pero, a partir de la primera inserción, me da error diciendo que intento acceder a una consulta cerrada y me obliga a hacer:
Código Delphi [-]
For I := 0 To nRecords - 1 Do
    Begin
    Query.Close;
    Query.SQL.Text := 'SELECT * FROM MyTable WHERE Id=0;';
    Query.Open;
    Query.Insert;
    Query.FieldValues['Name'] := Value;
    ... ...
    Query.Post;
    End;

Pero si has dicho que estás importando desde un fichero CSV, ¿entonces para qué sirve ese "select de alguna tabla"?

Eso es irrelevante, da igual la marca de las herramientas con las que reparas el motor del coche :)
Discrepo totalmente, todo lo que pregunto es muy importante, principalmente porque (repito) no tenemos información, date cuenta que cada uno que te contesta te dice algo totalmente distinto porque no podemos centrarnos en tu caso en particular.
Y precisamente, tu pregunta:

Demuestra que estás bastante perdido, porque nos da la sensación que estás obsesionado en resolver un error que no tiene nada que ver con el proceso que quieres solucionar, porque como te han comentado antes, ese código no es válido para lo que quieres hacer... suponiendo que sepamos qué quieres hacer :/
No se entiende ese código si estás importando un fichero de texto.
Perdón si parezco algo brusco, es sólo mi forma de "hablar" :D

A ver si soy capaz de explicarme:

1 - tengo información un archivo CSV.
2 - Esta información está en formato no compatible con el motor, por ejemplo: la fecha viene "2010.10.15,23.40" = 15/10/2010 23:40:0.
Esto me obliga a leer el archivo SCV desde mi aplicación Delphi, hacer conversiones, cálculos (aritméticos, trigonométricos, etc.
3 - El resultado de estas conversiones y cálculos es lo que debo guardar en la base de datos.

Si ejecuto la aplicación realizando todo el trabajo: Lectura de CSV, conversiones y cálculos, el trabajo termina en 20 minutos.
El problema es que si además intento guardar la información en la base de datos, el proceso puede tardar más de un año (cálculo aproximado empíricamente en función del tiempo que utilizo para tratar 1/100000 partes del fichero CSV.

No sé si hay alguna manera de hacerlo más rápido, porque si tarda un año, cuando acabe ya no sirve la información.

Trabajo con ADOConection y ADOQuery

Bien, vamos por partes, dices que leer el .csv procesarlo y demás tarda 20 minutos, ok. ¿Y dónde/en qué/cómo/ están esos datos ya procesados para guardarlos en la BD?

¿ADO para firebird? olvida eso.
Utiliza los componentes de la paleta Interbase: IBdatabase, ibTransaction, dataset, query, etc. O sea, IBX, puede ser el propio de delphi o los libres.

¡Ves cómo si necesitamos información! ;)

Mi aplicación guarda los datos ya procesados en un registro:

Código Delphi [-]
Type
    MyType=Record
    Fecha:tDatatime;
    Campo1:Double;
    ...
    ...
    End;

Entonces es cuando necesito insertar estos datos en una tabla de Firebird configurada igual que mi registro Delpfi.

Yo siempre he trabajado con ADO (no sé si es la mejor opción) hasta ahora he tenido suficiente, pero nunca había tenido la necesidad de insertar tantos registros seguidos.

Vamos progresando :)
¿Entonces tienes 500 GB en memoria RAM? ¿cuánta RAM tiene ese equipo? :confused:
¿De cuántos registros estamos hablando?



Para que te hagas una idea de la diferencia de velocidad con diferentes componentes, esto ya es muy antiguo y es orientativo, se realizaron una serie de test de insersión, búsqueda, etc. y el resultado fue este:

Memoria RAM = 16 GB
Windows 10
SO 64bits
Disco SSD 1TB

Pero no almaceno los registros en mi aplicació, ya que una vez generados los guardo en la base de datos.

Si están en memoria en un "TRecord" y dices que son 500 GB... ¿no serán 500 MB?
Es que con 500 GB ni siquiera puedes usar ese disco de 1 TB
Bueno, a lo que vamos, ahora sí lo tenemos bastante claro para ayudar :)
Y ya digo, con IBX. Dentro de un rato preparo un simple código para lo que quieres.

Muchísimas gracias, ya que nunca he trabajado con InterBase.

En memoria sólo tengo un Record de 80Byte.

Éste es el que debo generar (siempre el mismo) y guardar en la DB.

Cuando termine el proceso, calculo que la DB ocupará 500GB.

Vamos centrando el tiro...

Cuantos registros/filas hay en tu csv?
Cuanto tardas en crear otro csv con la información preparada? Porqué lo guardas en memoria?
Puedes procesar cada registro e insertarlo de la misma? asi te ahorras duplicar la info. Poner una traza por si te falla para volver a cargar desde donde falla.

Insertar 100.000 registros no puede demorar más de 3 minutos.

Por cada fila del csv lanzas una SQL de INSERT tal y como te han indicado desde las primeras respuestas.

Abro el csv.
por cada fila que lea:
proceso o pongo la información en formato correcto.
hago INSERT de ese registro. Si la insert la tienes parametrizada, tarda menos, es decir, parametro1 = valor1, parametro2= valor2, etc ->
SqlInsert.Open; Creo que era asñi, ya no recuerdo la sintaxis
leo siguiente fila
hasta acabar

Michas gracias, creo que el problema era ADO, ahora lo estoy preparando para utilizar InteBase.

Lo primero que he observado es que trabaja directamente sobre la DB sin OCDB, me imagino que esto ya es un progreso.

Cuando haya probado el sistema con InterBase, hago un post. ( posiblemente mañana, porque ahora tengo que salir)

Repito muchas gracias.

Te dejo un ejemplo que funciona en Delphi 6 con los componentes Interbase.
La base de datos es Firebird 2.5

Es un bucle de 10.000 inserciones que se repite 10 veces (100.000 inserciones).
Este es el log (unos 30 segundos).

Es importante en las inserciones masivas no hacer commit por cada registro. En el ejemplo se realizan cada 10.000 inserciones. Debes ver cuál es el mejor intervalo para tus datos.

En vez de los bucles, deberías modificarlo para recorrer el CSV calculando lo que necesites.
El SQL para el INSERT también deberás modificarlo según tus necesidades...

Código Delphi [-]
procedure TFMPruebas.BInsMasivaClick(Sender: TObject);
var
  IBDB: TIBDatabase;
  IBT: TIBTransaction;
  IBQ: TIBQuery;
  i, j: integer;
begin
  inherited;
  IBDB := TIBDatabase.Create(Self);
  IBT := TIBTransaction.Create(Self);
  try
     // Conexión a la base de datos
     IBDB.DatabaseName := '192.168.0.1:C:\Datos\Base.FDB';
     IBDB.DefaultTransaction := IBT;
     IBT.DefaultDatabase := IBDB;

     // Aquí te pedirá nombre de usuario y contraseña
     IBDB.Connected := True;

     // Inicio transaccion
     IBT.StartTransaction;

     IBQ := TIBQuery.Create(Self);
     try
       IBQ.DataBase := IBDB;
       IBQ.Transaction := IBT;

       // SQL para insertar los datos
       IBQ.SQL.Text := 'INSERT INTO TMP_TEMPORALES (NOMBRE, ENTRADA) VALUES (:NOMBRE, :ENTRADA)';

       MDebug.Lines.Add(FormatDateTime('hh:nn:ss', Now) + ' Inicio');
       for i := 0 to 9 do
       begin
         for j := 1 to 10000 do
         begin
           IBQ.Params.ParamByName('NOMBRE').AsString := IntToStr(i*10000 + j);
           IBQ.Params.ParamByName('ENTRADA').AsInteger := i*10000 + j;
           IBQ.ExecSQL;
         end;

         // Hago commit de la transaccion cada 10000 registros.
         IBQ.Transaction.Commit;
         IBQ.Transaction.StartTransaction;
         MDebug.Lines.Add(FormatDateTime('hh:nn:ss', Now) + ' Bucle '+IntToStr(i));
       end;
       MDebug.Lines.Add(FormatDateTime('hh:nn:ss', Now) + ' Fin');
     finally
       IBQ.Free;
     end;
  finally
    IBDB.Free;
    IBT.Free;
  end;
end;

Hola otra vez, ya he preparado el trabajo con InterBase.

Asigno Valores

Código Delphi [-]
IBQuery.Params.ParamByName('Id').AsLargeInt := Template.Id;

Son 29 campos y la asignación de valores a los parámetros se realiza si problemas, pero al hacer

Código Delphi [-]
IBQuery.ExecSQL;

Me da un error = "Attempt to get information about an unprepared dynamic SQL statement"

Alguna idea de lo que estoy haciendo mal?

Tengo algunos campos que en la DB son de tipo Char(1) y en mi aplicación son de tipo AnsiChar.

Para pasar el valor lo ago con AsAnsiString=AnsiChar, no sé si es correcto

La otra duda es que el Id en mi aplicación es de tipo Int64 y en la DB es de tipo BigInt

Para pasar el valor lo ago con AsLargeInt=Int64.

No sé si el error puede estar aquí?

Por favor, pon el código ;)

Antes de empezar a leer del archivo fuente *.csv:

Código Delphi [-]
IBTransaction.StartTransaction;
IBQuery.SQL.Text := 'INSERT INTO Templates (Id, Value1, Value2, Value3'+//
  ' VALUES (:Id, :Value1, :Value2, :Value3)';

Donde:
Id en Delphi es de tipo Int64 y en DB BigInt
Value1 en Delphi es de tipo AnsiChar y en DB Char(1)
Value2 en Delphi es de tipo SmallInt y en DB También
Value3 en Delphi es de tipo Boolean y en DB también

En Delphi estos campos se agrupan en un Record.

En cada inserción:

Código Delphi [-]
IBQuery.Params.ParamByName('Id').AsLargeInt := MyRecord.Id;
IBQuery.Params.ParamByName('Value1').AsAnsiString := MyRecord.Value1;
IBQuery.Params.ParamByName('Value2').AsAnsiString := MyRecord.Value2;
IBQuery.Params.ParamByName('Value3').AsAnsiString := MyRecord.Value3;
IBQuery.ExecSQL;

Pongo un BreakPoint en la primera asignación, no da ningún error hasta llegar a ExecSQL.

Perdona es:

Código Delphi [-]
IBQuery.Params.ParamByName('Id').AsLargeInt := MyRecord.Id;
IBQuery.Params.ParamByName('Value1').AsAnsiString := MyRecord.Value1;
IBQuery.Params.ParamByName('Value2').AsSmaillInt := MyRecord.Value2;
IBQuery.Params.ParamByName('Value3').AsBoolean := MyRecord.Value3;
IBQuery.ExecSQL;

Y el record?

Perdona.

Código Delphi [-]
    MyRecord:Record
        Id:Int64;
        Value1:AnsiChar;
        Value2:SmallInt;
        Value3:Boolean;
    End;

Lo de leer el .csv y pasarlo a un record y luego del record a la base de datos... es un paso que te puedes ahorrar perfectamente.
Lo lees del csv y lo guardas en la BD, nada más.

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  csvFile: TStringList;
  line: string;
  fields: TStringList;
  i: Integer;
begin
  csvFile := TStringList.Create;
  fields := TStringList.Create;
  try
    csvFile.LoadFromFile('C:\ruta\archivo.csv');
    IBTransaction1.StartTransaction;
    IBDataSet1.Transaction := IBTransaction1;
    IBDataSet1.Open;
    try
      for i := 0 to csvFile.Count - 1 do
      begin
        line := csvFile[i];
        fields.CommaText := line;
        IBDataSet1.Insert;
        IBDataSet1.FieldByName('campo1').Value := fields[0];
        IBDataSet1.FieldByName('campo2').Value := fields[1];
        IBDataSet1.FieldByName('campo3').Value := fields[2];
        // ...
        // Aquí puedes hacer los procesos que necesitas con algunos datos
        // ...
        IBDataSet1.Post;
      end;
      IBTransaction1.Commit;
      ShowMessage('Registros insertados correctamente.');
    except
      on E: Exception do
      begin
        IBTransaction1.Rollback;
        ShowMessage('Error al insertar registros: ' + E.Message);
      end;
    end;
  finally
    csvFile.Free;
    fields.Free;
  end;
end;

Este código carga el archivo CSV en un objeto TStringList, luego abre una transacción y un conjunto de datos utilizando los componentes IBTransaction y IBDataSet, respectivamente. Luego, itera sobre cada línea del archivo CSV y separa los campos utilizando el método CommaText del objeto TStringList. Finalmente, inserta cada registro en la base de datos utilizando el método Insert y asignando los valores de los campos correspondientes.

Prueba a poner una línea para que ejecute Prepare a propósito.

Código Delphi [-]
IBTransaction.StartTransaction;
IBQuery.SQL.Text := 'INSERT INTO Templates (Id, Value1, Value2, Value3'+//
  ' VALUES (:Id, :Value1, :Value2, :Value3)';
IBQuery.Prepare;

Deberás ponerlo después de cada StartTransaction o después de cada vez que cambie el SQL del Query.

Con respecto a los tipos de dato yo no me preocupo mucho.
El componente de Delphi hará las conversiones necesarias.

Todos los enteros (smallint, integer, bigint) .AsInteger
Todos los textos (char(), varchar()) .AsString
Todos las fechas (date, time, ...) .AsDateTime
Todos los decimales (double precision, numeric(x,x), ...) .AsFloat

Para trabajar con booleanos en Firebird 2.5 debes tratarlos como un smallint con valores (0,1) o como un char/varchar() con valores ('S','N')
Por lo tanto deberás hacer la conversión necesaria

Código Delphi [-]
function BoolToInt(Value: boolean) : integer;
begin
  if Value then
    Result := 1
  else
    Result := 0;
end;

BQuery.Params.ParamByName('Id').AsInteger := MyRecord.Id; // Bigint
IBQuery.Params.ParamByName('Value1').AsString := MyRecord.Value1; // varchar()
IBQuery.Params.ParamByName('Value2').AsInteger := MyRecord.Value2; // smallint
IBQuery.Params.ParamByName('Value3').AsInteger := BoolToInt(MyRecord.Value3); // smallint (0,1)

Gracias Casimiro, lo pruebo todo y te comento.

Buen finde.

Bueno Casimiro, estoy a punto de tirar la toalla.

He creado una tabla en una DB Firebird con la siguiente estructura.

Código SQL [-]
CREATE TABLE PRUEBAS (
  ID BIGINT DEFAULT 0 NOT NULL,
  MYINT INTEGER DEFAULT 0 NOT NULL,
  MYFLOAT FLOAT DEFAULT 0 NOT NULL,
  MYBOOL BOOLEAN DEFAULT 'FALSE' NOT NULL,
  MYSTRING CHAR(1) DEFAULT '!' NOT NULL);

Y he implementado un nuevo proyecto Delphi 2010, copiando, pegando y adaptando tu última recomendación.

Código Delphi [-]
Procedure TForm2.Button2Click(Sender:TObject);
Var
    IBDB:TIBDatabase;
    IBT:TIBTransaction;
    IBQ:TIBQuery;
    I, J:Integer;
Begin
Inherited;
IBDB := TIBDatabase.Create(Self);
IBT := TIBTransaction.Create(Self);
Try
    // Conexión a la base de datos
    IBDB.DatabaseName := 'D:\IKDB.GDB';
    IBDB.DefaultTransaction := IBT;
    IBT.DefaultDatabase := IBDB;

    // Aquí te pedirá nombre de usuario y contraseña
    IBDB.Connected := True;

    // Inicio transaccion
    IBT.StartTransaction;

    IBQ := TIBQuery.Create(Self);
    Try
        IBQ.DataBase := IBDB;
        IBQ.Transaction := IBT;

        // SQL para insertar los datos
        IBQ.SQL.Text := 'INSERT INTO Pruebas (Id, MyInt, MyFoat, MyBool, MyString) VALUES (:Id, :MyInt, :MyFloat, :MyBool, :MyString)';

        For I := 0 To 9 Do
            Begin
            For J := 1 To 10000 Do
                Begin
                IBQ.Params.ParamByName('Id').AsLargeInt := I * 10000 + J;
                IBQ.Params.ParamByName('MyInt').AsInteger := Random(1000);
                IBQ.Params.ParamByName('MyFloat').AsFloat := Random * 1000;
                IBQ.Params.ParamByName('MyBool').AsBoolean := Random(2) = 1;
                IBQ.Params.ParamByName('MyString').AsString := Char(Random(25) + 65);
                IBQ.ExecSQL;      <<<<<<<<< Aquí me este error:  'Attempt to get information about an unprepared dynamic SQL statement'
                End;

            // Hago commit de la transaccion cada 10000 registros.
            IBQ.Transaction.Commit;
            IBQ.Transaction.StartTransaction;
            End;

    Finally
        IBQ.Free;
    End;
    IBT.Free;
    IBDB.Free;
Except
    On E:Exception Do
        ShowMessage('ERROR ' + E.Message);
End;
End;

Cómo puedes ver en el código he añadido un indicador <<<<<<<<<<< dónde y qué error me da.

Si puedes mirarlo y decirme done lo hago mal, te lo agradeceré infinito.

Veamos, esto es fácil, te he preparado un sencillo proyecto y te lo adjunto aquí.
No sé qué versión usas de firebird, yo ahora mismo tengo la 2.5 y no existen los campos boolean, así que utilizo integer con 0/1 (0=false 1=true)
Luego, en el proyecto te he corregido algunas cosas y en lugar de crear dinámicamente los componentes, los he creado en tiempo de diseño.
Fíjate en los parámetros del IBDatabase y en los del IBTransaction.
El IBDatabase le pongo la propiedad "login prompt" a false, para que no pregunte el password cada vez.

Y los parámetros del IBTransaction, elijo "Read commited" y automáticamente se rellenan estos parámetros:

Conecto a la BD en el oncreate y desconecto en el onclose. El código es este:

Código Delphi [-]
unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, IBDatabase, IBQuery, IBSQL, DB, IBCustomDataSet;

type
  TForm2 = class(TForm)
    Button1: TButton;
    IBDatabase1: TIBDatabase;
    IBTransaction1: TIBTransaction;
    IBQuery1: TIBQuery;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.Button1Click(Sender: TObject);
Var
  I, J:Integer;
  dIni, dFin : Double;
Begin
  dIni := now();
   
  IBQuery1.Close;
  IBQuery1.SQL.Text := 'INSERT INTO Pruebas (Id, MyInt, MyFloat, MyBool, MyString) VALUES (:Id, :MyInt, :MyFloat, :MyBool, :MyString)';
  IBQuery1.Prepare;
  try
    For I := 0 To 9 Do
    Begin
      For J := 1 To 10000 Do
      Begin
        IBQuery1.Params.ParamByName('id').AsInteger := i *10000 +j;
        IBQuery1.Params.ParamByName('MyInt').AsInteger := Random(1000);
        IBQuery1.Params.ParamByName('MyFloat').AsFloat := Random * 1000;
        IBQuery1.Params.ParamByName('MyBool').AsInteger := Random(2);
        IBQuery1.Params.ParamByName('MyString').AsString := Char(Random(25) + 65);
        IBQuery1.ExecSQL;
      End;
      IBQuery1.Transaction.CommitRetaining;
    end;
  finally
    dFin := now();
  end;

  ShowMessage( FloatToStr(dFin-dIni) );

End;

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if IBTransaction1.InTransaction then
    IBTransaction1.Commit;
  IBTransaction1.Active:=False;
  IBDatabase1.Close;
end;

procedure TForm2.FormCreate(Sender: TObject);
begin
  IBDatabase1.Connected:=true;
  IBTransaction1.Active:=true;
end;

end.

Y si lo ejecutas, obviamente, esto es una broma para firebird, en mi equipo tarda menos de 2 segundos.