Ayuda a pasar este código a firemonkey.
 

hola,
anteriormente el señor ecfisa.
me ayudo a crear un editor hexadecimal, funciona bien en VCL. pero necesito tenerlo en firemonkey.

Código Delphi [-]
implementation 
 
procedure DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
var
  c, i, r: integer;
  ascii: string;
  aux: Byte;
begin
  with TMemoryStream.Create do
  try
    LoadFromFile(aFileName);
    // configurar StringGrid
    SG.Options:= SG.Options - [goVertLine] - [goHorzLine];
    SG.Font.Name:= 'Courrier';
    SG.Font.Size:= 10;
    SG.ColWidths[0]:= 80;
    SG.Cells[0,0]:= 'Offset(h)';
    SG.ColCount:= BPF+2;
    SG.ColWidths[SG.ColCount-1]:= SG.Canvas.TextWidth('X') * BPF;
    SG.Cells[SG.ColCount-1,0]:= 'ASCII';
    for i:= 0 to BPF-1 do
    begin
      SG.ColWidths[i+1]:= 30;
      SG.Cells[i+1,0]:= IntToHex(i,2);
    end;
    SG.RowCount:= Size div BPF;
    // cargar en StringGrid
    Seek(0, soBeginning);
    c:= 0;
    r:= SG.FixedRows;
    while c < Size do
    begin
      SG.Cells[0, r]:= Format('%s',[IntToHex(c, 8)]);
      ascii:= EmptyStr;
      i:= 0;
      while (i < BPF)and(i+c < Size) do
      begin
        Read(aux, SizeOf(Byte));
        SG.Cells[i+1,r]:= IntToHex(aux,2);
        if aux = 0 then aux := 46;
        ascii:= ascii + Chr(aux);
        Inc(i);
      end;
      SG.Cells[SG.ColCount-1,r]:= Format('%s',[ascii]);
      Inc(c, BPF);
      Inc(r);
    end;
  finally
    Free;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ComboBox1.Items.CommaText:= '8,10,16,24,32,48,64,128,255';
  ComboBox1.ItemIndex:= 2;
end;

procedure TForm1.btnFileClick(Sender: TObject);
begin
  with OpenDialog1 do
  begin
    Filter:= '*.*';
    if Execute then
    begin
      Caption:= FileName;
      DumpFile(FileName, StringGrid1,
        StrToInt(ComboBox1.Items[ComboBox1.ItemIndex]) );
    end;
  end;
end;



procedure SaveDump(aFileName:TFileName; SG: TStringGrid);
var
  c,r: Integer;
  s: string;
begin
  with TStringList.Create do
  try
    for r:= SG.FixedRows to SG.RowCount-1 do
    begin
      s:= '';
      for c:= 0 to SG.ColCount-1 do s:= s + SG.Cells[c,r] + ' ';
      SetLength(s,Length(s)-1);
      Add(s);
    end;
    SaveToFile(aFileName);
  finally
    Free;
  end;
end;
...

procedure TForm1.btnSaveToTxtClick(Sender: TObject);
begin
  with SaveDialog1 do
  begin
    Filter:= '*.txt';
    DefaultExt:= '*.txt';
    if Execute then
      SaveDump(FileName, StringGrid1);
  end;
end;

sera posible pasar este código a firemonkey, sin usar un Control StringGrid. es decir que se almacene en una variable, y no en StringGrid. pero sino, lo mas importante para mi es pasar este código a firemonkey. yo hago el resto.

muchas gracias por su ayuda.

elmago00,

Pregunto :

1- ¿Por que no un control TStringGrid? :confused:

2- ¿Que control sugieres usar en lugar del control TStringGrid?.

3- ¿Cuando te refieres a una variable exactamente que quieres decir y por que? :confused:

4- ¿Que versión de Delphi utilizas?.

Espero sea útil :)

Nelson.

gracias por responder Nelson.
veras es que lo intento hacer es abrir el archivo, y editarlo automáticamente, buscando la dirección y la cantidad de caracteres que le siguen. luego reemplazarlos por los que yo pongo. por eso decía si podía hacer lo mismo pero almacenarlo en una variable TStringGrid, sin usar el componente.

pero si no es posible. el interés mayor mio es pasarlo a firemonkey para hacer yo el resto, que es buscar la dirección mas el hexadecimal y reemplazarlo.

uso XE3.

parece algo complejo verdad? pero se resume en pasarlo a firemonkey, ya sea un componente TStringGrid o una variable. cualquiera esta bien. siempre que me permita realizar la búsqueda para hacer lo que necesito.

elmago00,

Pregunto:

1- ¿Cuando indicas buscar por dirección te refieres al Offset (Fila) y los Bytes (Columna) que se muestran en el TStringGrid del ejemplo?.

2- ¿Cuando te refieres a almacenarlo en una variable TStringGrid pero sin el componente, te refieres a poder usarlo por código pero sin la parte visual del mismo?.

Espero sea útil :)

Nelson.

exacto usarlo pero sin que el usuario visualice el componente.
la búsqueda la realizo por "Offset" y reemplazo una determinada cantidad de byte(el hexadecimal) no los modifico todos solo unos cuantos, y luego guardo el archivo.

elmago00,

Ok, veré que puedo hacer :rolleyes:

Pregunto: ¿Cual es la finalidad de este trabajo? :confused:

Nelson.

solo poder abrir un archivo en hexadecimal, y editarlo automáticamente, para un programa que estamos desarrollando.
no es con fines comerciales, ni nada eso.

elmago00,

Eso lo entiendo :rolleyes: , mi pregunta se refiere a:

1- ¿Por que este tipo de procesamiento?, ¿Sabes que pontencialmente estas construyendo un virus? :confused:

2- ¿Cuales son los detalles de la aplicación que quieres realizar?.

3- ¿Por que FireMonkey y no VCL?, ¿Es una aplicación multiplataforma?.

Espero sea útil :)

Nelson.

lo siento no comprendí bien tu pregunta.
lo necesito en firemonkey, por que el software principal esta así. y no podemos mover a VCL. por que el código fuente es mas 40 mil lineas de código.

no tiene nada que ver con virus.
conoces los editores hexadecimales. bien pues eso es lo que necesito, por que el software debe editar un archivo, buscar la dirección que debe cambiar para poder cargar ese archivo.


solo necesito ese código en firemonkey. si es un componente stringGrid o no es lo de menos. solo que no querremos que el usuario haga el cambio, por que el no sabrá que esta insertando como reemplazo a la linea hexadecimal. solo eso.

hagamos una cosa. se que no crees lo que digo.
solo detallen las propiedades que tiene este código pero en firemonkey. por que el StringGrid no funciona igual que en VCL.
yo hago el resto.

gracias por responder a mis consultas.

elmago00,

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Rtti, System.Classes,
  System.Variants, System.UIConsts, FMX.Types, FMX.Controls, FMX.Forms, FMX.Dialogs,
  FMX.StdCtrls, FMX.ListBox, FMX.Layouts, FMX.Grid;

type

  TColumnAccess = class(TColumn)
  end;

  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    ComboBox1: TComboBox;
    OpenDialog1: TOpenDialog;
    SaveDialog1: TSaveDialog;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

procedure DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
var
  c, i, r: Integer;
  Ascii: String;
  Aux: Byte;
  Col, Row: Integer;
  CellCtrl: TStyledControl;

begin

  with TMemoryStream.Create do
  try

    LoadFromFile(aFileName);

    // Configurar StringGrid

    SG.ShowHeader := False;
    SG.ShowHorzLines := False;
    SG.ShowVertLines := False;

    for i := 1 to BPF + 2 do
       SG.AddObject(TStringColumn.Create(nil));

    SG.RowCount:= Size div BPF;

    for Row := 0 to SG.RowCount - 1 do
    begin
       for Col := 0 to SG.ColumnCount - 1 do
       begin

          Application.ProcessMessages;

          CellCtrl := TColumnAccess(SG.Columns[Col]).CellControlByRow(Row);
          if ( CellCtrl <> nil ) and (CellCtrl is TTextCell) then
          begin

             TTextCell(CellCtrl).StyledSettings := [];
             TTextCell(CellCtrl).Font.Family := 'Courrier New';
             TTextCell(CellCtrl).Font.Size := 10;
             TTextCell(CellCtrl).FontColor := claBlack;
             TTextCell(CellCtrl).Font.Style := [];
             TTextCell(CellCtrl).TextAlign := TTextAlign.taCenter;

             if (Col = 0) then
                SG.Columns[Col].Width := 80;

             if (Col <> SG.ColumnCount - 1) and (Col <> 0) then
                SG.Columns[Col].Width := 30;

             if (Col = SG.ColumnCount - 1) then
                SG.Columns[Col].Width := SG.Canvas.TextWidth('X') * BPF;

          end;
       end;
    end;

    SG.Cells[0,0]:= 'Offset(h)';
    SG.Cells[SG.ColumnCount-1,0]:= 'ASCII';

    for i:= 0 to BPF-1 do
    begin
      SG.Cells[i+1,0]:= IntToHex(i,2);
    end;

    // Cargar StringGrid

    Seek(0, soBeginning);
    c:= 0;
    r:= 1;
    while c < Size do
    begin
      SG.Cells[0, r]:= Format('%s',[IntToHex(c, 8)]);
      Ascii:= EmptyStr;
      i:= 0;
      while (i < BPF)and(i+c < Size) do
      begin
        Read(Aux, SizeOf(Byte));
        SG.Cells[i+1,r]:= IntToHex(Aux,2);
        if Aux = 0 then Aux := 46;
        Ascii:= Ascii + Chr(Aux);
        Inc(i);
      end;
      SG.Cells[SG.ColumnCount-1,r]:= Format('%s',[Ascii]);
      Inc(c, BPF);
      Inc(r);
    end;
  finally
    Free;
  end;
end;

// Salvar StringGrig a Archivo TXT
procedure SaveDump(aFileName:TFileName; SG: TStringGrid);
var
  c,r: Integer;
  s: String;
begin
  with TStringList.Create do
  try
    for r:= 0 to SG.RowCount-1 do
    begin
      s:= '';
      for c:= 0 to SG.ColumnCount-1 do s:= s + SG.Cells[c,r] + ' ';
      SetLength(s,Length(s)-1);
      Add(s);
    end;
    SaveToFile(aFileName);
  finally
    Free;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ComboBox1.Items.CommaText:= '8,10,16,24,32,48,64,128,255';
  ComboBox1.ItemIndex:= 2;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  with OpenDialog1 do
  begin
    Filter:= '*.*';
    if Execute then
    begin
      Caption:= FileName;
      DumpFile(FileName, StringGrid1,
        StrToInt(ComboBox1.Items[ComboBox1.ItemIndex]) );
    end;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  with SaveDialog1 do
  begin
    Filter:= '*.txt';
    DefaultExt:= '*.txt';
    if Execute then
      SaveDump(FileName, StringGrid1);
  end;
end;

end.

El código anterior en Delphi XE4 bajo Windows 7 Professional x32, es la implementación del código del Msg #1 en FireMonkey HD, como se muestra en la siguiente imagen:



Espero sea útil :)

Nelson.

gracias Nelson por ayudarme. ya es de madrugada y ustedes me siguen ayudando. mil gracias.

tu código solo tiene un contraste, yo como te dije antes, uso XE3.
y me da dos errores el primero dice:

TTextCell no contiene ningún miembro con el nombre StyledSettings.
es esta linea

Código Delphi [-]
TTextCell(CellCtrl).StyledSettings := [];

veo que tu usas algunas clases que XE3 no están disponibles, como ser: FMX.StdCtrls;

el segundo problema es que abre el archivo pero en blanco, el StringGrid no muestra nada.

perdona tanta molestia, pero cuando el cerebro no da, no queda de otra, que pedir ayuda.

intente no usar la opcion

Código Delphi [-]
TTextCell(CellCtrl).StyledSettings := [];

Pero ahora me permite cerrar la venta. : )

elmago00,

Pregunto:

1- ¿De que tamaño es el archivo en cuestión?.

2- ¿Puedes abrir otros archivos?.

3- ¿La eliminación de la opción mencionada es la única modificación al código propuesto en el Msg #11?.

Espero sea útil :)

Nelson.

elmago00,

Es probable que el archivo probado sea muy grande (La lectura es Byte a Byte), y por ello tarda en ser visualizado, eso se soluciona con la inclusión de Application.ProcessMessages en el ciclo de carga del TStringGrid.

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Rtti, System.Classes,
  System.Variants, System.UIConsts, FMX.Types, FMX.Controls, FMX.Forms, FMX.Dialogs,
  FMX.StdCtrls, FMX.ListBox, FMX.Layouts, FMX.Grid;

type

  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    ComboBox1: TComboBox;
    OpenDialog1: TOpenDialog;
    SaveDialog1: TSaveDialog;
    Button1: TButton;
    Button2: TButton;
    StatusBar1: TStatusBar;
    Label1: TLabel;
    Button3: TButton;
    Button4: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
    procedure SaveDump(aFileName:TFileName; SG: TStringGrid);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  CancelProcess : Boolean;

implementation

{$R *.fmx}

procedure TForm1.DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
var
  c, i, r, b : Integer;
  Ascii: String;
  Aux: Byte;
  Col : Integer;

begin

  with TMemoryStream.Create do
  try

    LoadFromFile(aFileName);

    Caption:= Format('FileName = %s , FileSize = %d Bytes', [aFileName, Size]);

    // Configurar StringGrid

    SG.ShowHeader := False;
    SG.ShowHorzLines := False;
    SG.ShowVertLines := False;

    for i := 1 to BPF + 2 do
       SG.AddObject(TStringColumn.Create(nil));

    SG.RowCount:= Size div BPF;

    for Col := 0 to SG.ColumnCount - 1 do
    begin

        if (Col = 0) then
           SG.Columns[Col].Width := 80;

        if (Col <> SG.ColumnCount - 1) and (Col <> 0) then
           SG.Columns[Col].Width := 30;

        if (Col = SG.ColumnCount - 1) then
           SG.Columns[Col].Width := SG.Canvas.TextWidth('X') * BPF;

    end;

    SG.Cells[0,0]:= 'Offset(h)';
    SG.Cells[SG.ColumnCount-1,0]:= 'ASCII';

    for i:= 0 to BPF-1 do
    begin
      SG.Cells[i+1,0]:= IntToHex(i,2);
    end;

    // Cargar en StringGrid

    Seek(0, soBeginning);
    c:= 0;
    r:= 1;
    b := 0;

    while c < Size do
    begin

      Application.ProcessMessages;

      if CancelProcess then
      begin
         CancelProcess := False;
         Break;
      end;

      SG.Cells[0, r]:= Format('%s',[IntToHex(c, 8)]);
      Ascii:= EmptyStr;
      i:= 0;

      while (i < BPF) do
      begin
        Read(Aux, SizeOf(Byte));
        SG.Cells[i+1,r]:= IntToHex(Aux,2);
        if Aux = 0 then Aux := 46;
        Ascii:= Ascii + Chr(Aux);
        Inc(i);
        if (b < Size) then Inc(b);
      end;

      SG.Cells[SG.ColumnCount-1,r]:= Format('%s',[Ascii]);
      Inc(c, BPF);
      Inc(r);
      Label1.Text := Format('Procesado Byte %d de %d',[b, Size]);

    end;

  finally

    Free;

  end;

end;

// Salvar StringGrig a TXT
procedure TForm1.SaveDump(aFileName:TFileName; SG: TStringGrid);
var
  c,r: Integer;
  s: String;
begin
  with TStringList.Create do
  try
    for r:= 0 to SG.RowCount-1 do
    begin
      s:= '';
      for c:= 0 to SG.ColumnCount-1 do s:= s + SG.Cells[c,r] + ' ';
      SetLength(s,Length(s)-1);
      Add(s);
    end;
    SaveToFile(aFileName);
  finally
    Free;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ComboBox1.Items.CommaText:= '8,10,16,24,32,48,64,128,255';
  ComboBox1.ItemIndex:= 2;
end;

// Carga un Archivo en Modo Hexadecimal en un StringGrid
procedure TForm1.Button1Click(Sender: TObject);
begin
  with OpenDialog1 do
  begin
    Filter:= '*.*';
    if Execute then
    begin
      DumpFile(FileName, StringGrid1,
        StrToInt(ComboBox1.Items[ComboBox1.ItemIndex]) );
    end;
  end;
end;

// Salva un Archivo en Modo Hexadecimal en un StringGrid a TXT
procedure TForm1.Button2Click(Sender: TObject);
begin
  with SaveDialog1 do
  begin
    Filter:= '*.txt';
    DefaultExt:= '*.txt';
    if Execute then
      SaveDump(FileName, StringGrid1);
  end;
end;

// Cancela Carga de un Archivo en Modo Hexadecimal en un StringGrid
procedure TForm1.Button3Click(Sender: TObject);
begin
   CancelProcess := True;
end;

// Inicializa el StringGrid
procedure TForm1.Button4Click(Sender: TObject);
var
   i : Integer;
begin
   StringGrid1.RowCount := 0;
   for i := StringGrid1.ColumnCount - 1 downto 0 do
         StringGrid1.Columns[i].DisposeOf;
end;

end.

El código anterior en Delphi XE4 bajo Windows 7 Professional x32, es la versión 2 del código propuesto en el Msg #11, con unas pequeños cambios en el manejo del Visualizador de Archivos en Hexadecimal en FireMonkey, como se muestra en la siguiente imagen:



El código esta disponible en : Visualizador de Archivos en Hexadecimal en FireMonkey

Espero sea útil :)

Nelson.

muchas gracias al fin lo conseguí, se demora un poco, pero no importa. muchas gracias Nelson^\||/^\||/:)
para que fuera compatible con XE3 lo hice asi.

Código Delphi [-]
procedure DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
var
  c, i, r, b : Integer;
  Ascii: String;
  Aux: Byte;
  Col : Integer;

begin

  with TMemoryStream.Create do
  try

    LoadFromFile(aFileName);



    // Configurar StringGrid

    SG.ShowHeader := False;
    SG.ShowHorzLines := False;
    SG.ShowVertLines := False;

    for i := 1 to BPF + 2 do
       SG.AddObject(TStringColumn.Create(nil));

    SG.RowCount:= Size div BPF;

    for Col := 0 to SG.ColumnCount - 1 do
    begin

        if (Col = 0) then
           SG.Columns[Col].Width := 80;

        if (Col <> SG.ColumnCount - 1) and (Col <> 0) then
           SG.Columns[Col].Width := 30;

        if (Col = SG.ColumnCount - 1) then
           SG.Columns[Col].Width := SG.Canvas.TextWidth('X') * BPF;

    end;

    SG.Cells[0,0]:= 'Offset(h)';
    SG.Cells[SG.ColumnCount-1,0]:= 'ASCII';

    for i:= 0 to BPF-1 do
    begin
      SG.Cells[i+1,0]:= IntToHex(i,2);
    end;

    // Cargar en StringGrid

    Seek(0, soBeginning);
    c:= 0;
    r:= 1;
    b := 0;

    while c < Size do
    begin

      Application.ProcessMessages;

      if CancelProcess then
      begin
         CancelProcess := False;
         Break;
      end;

      SG.Cells[0, r]:= Format('%s',[IntToHex(c, 8)]);
      Ascii:= EmptyStr;
      i:= 0;

      while (i < BPF) do
      begin
        Read(Aux, SizeOf(Byte));
        SG.Cells[i+1,r]:= IntToHex(Aux,2);
        if Aux = 0 then Aux := 46;
        Ascii:= Ascii + Chr(Aux);
        Inc(i);
        if (b < Size) then Inc(b);
      end;

      SG.Cells[SG.ColumnCount-1,r]:= Format('%s',[Ascii]);
      Inc(c, BPF);
      Inc(r);


    end;

  finally

    Free;

  end;

end;

// Salvar StringGrig a TXT
procedure SaveDump(aFileName:TFileName; SG: TStringGrid);
var
  c,r: Integer;
  s: String;
begin
  with TStringList.Create do
  try
    for r:= 0 to SG.RowCount-1 do
    begin
      s:= '';
      for c:= 0 to SG.ColumnCount-1 do s:= s + SG.Cells[c,r] + ' ';
      SetLength(s,Length(s)-1);
      Add(s);
    end;
    SaveToFile(aFileName);
  finally
    Free;
  end;
end;


{guardar}

procedure TForm12.Button25Click(Sender: TObject);
begin
 with SaveDialog1 do
  begin
    Filter:= '*.txt';
    DefaultExt:= '*.txt';
    if Execute then
      SaveDump(FileName, StringGrid1);
  end;
end;



{abrir}

procedure TForm12.Button6Click(Sender: TObject);
   var
   valor:string;
begin
    valor:='16';
 with OpenDialog1 do
  begin
    Filter:= '*.*';
    if Execute then
    begin
      Caption:= FileName;
      DumpFile(FileName, StringGrid1,
        StrToInt(valor));
    end;
  end;
end;

{cancelar}

procedure TForm12.Button26Click(Sender: TObject);
begin
CancelProcess := True;
end;

gracias a Ecfisa y Nelson.^\||/

Hola elmago00.

En el hilo anterior había interpretado que querias realizar cambios, de allí que usé un componente que te permitiera hacerlos interactivamente, pero si deseas guardarlo en un archivo de texto para trabajar sobre él, también podrías hacer:

Código Delphi [-]
procedure DumpFile(aFileName:TFileName; const BPF: Word);
var
  c, i, r: integer;
  ascii: string;
  linea: string;
  aux: Byte;
begin
  with TMemoryStream.Create do
  try
    LoadFromFile(aFileName);
    Seek(0, soBeginning);
    with TStringList.Create do
    try
      c:= 0;
      while c < Size do
      begin
        linea:= IntToHex(c, 8)+' ';
        ascii:= EmptyStr;
        i:= 0;
        while (i < BPF) and (i+c < Size) do
        begin
          Read(aux, SizeOf(Byte));
          linea:= linea + IntToHex(aux,2) + ' ';
          if aux in [$0..$20,$80..$90] then aux:= Ord('.');
          ascii:= ascii + Chr(aux);
          Inc(i);
        end;
        linea:= linea + ascii ;
        Add(linea);
        Inc(c, BPF);
        Inc(r);
      end;
      SaveToFile(ExtractFilePath(aFileName) +
        ChangeFileExt(ExtractFileName(aFileName), '') + '.HEX');
    finally
      Free;
    end;
  finally
    Free;
  end;
end;

Uso:

Código Delphi [-]
  DumpFile('c:\windows\notepad.exe',16);

El código te genera el archivo en la misma carpeta del archivo orígen, con el mismo nombre, de extensión .HEX y contiene los mismos datos que veías en el StringGrid.

Saludos :)

elmago00,

:) ^\||/

Una pequeña corrección :rolleyes: :

Código Delphi [-]
procedure TForm1.DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
var
  c, i, r, b : Integer;
  Ascii: String;
  Aux: Byte;
  Col : Integer;

begin

  with TMemoryStream.Create do
  try

    LoadFromFile(aFileName);

    Caption:= Format('FileName = %s , FileSize = %d Bytes', [aFileName, Size]);

    // Configurar StringGrid

    SG.ShowHeader := False;
    SG.ShowHorzLines := False;
    SG.ShowVertLines := False;

    for i := 1 to BPF + 2 do
       SG.AddObject(TStringColumn.Create(nil));

    SG.RowCount := (Size div BPF) + 1;
    if (Size Mod BPF) <> 0 then
       SG.RowCount := SG.RowCount + 1;

    for Col := 0 to SG.ColumnCount - 1 do
    begin

        if (Col = 0) then
           SG.Columns[Col].Width := 80;

        if (Col <> SG.ColumnCount - 1) and (Col <> 0) then
           SG.Columns[Col].Width := 30;

        if (Col = SG.ColumnCount - 1) then
           SG.Columns[Col].Width := SG.Canvas.TextWidth('X') * BPF;

    end;

    SG.Cells[0,0]:= 'Offset(h)';
    SG.Cells[SG.ColumnCount-1,0]:= 'ASCII';

    for i:= 0 to BPF-1 do
    begin
      SG.Cells[i+1,0]:= IntToHex(i,2);
    end;

    // Cargar en StringGrid

    Seek(0, soBeginning);
    c:= 0;
    r:= 1;
    b := 0;

    while c < Size do
    begin

      Application.ProcessMessages;

      if CancelProcess then
      begin
         CancelProcess := False;
         Break;
      end;

      SG.Cells[0, r]:= Format('%s',[IntToHex(c, 8)]);
      Ascii:= EmptyStr;
      i:= 0;

      while (i < BPF) and (b < Size) do
      begin
        Read(Aux, SizeOf(Byte));
        SG.Cells[i+1,r]:= IntToHex(Aux,2);
        if Aux = 0 then Aux := 46;
        Ascii:= Ascii + Chr(Aux);
        Inc(i);
        if (b < Size) then Inc(b);
      end;

      SG.Cells[SG.ColumnCount-1,r]:= Format('%s',[Ascii]);
      Inc(c, BPF);
      Inc(r);
      Label1.Text := Format('Procesado Byte %d de %d',[b, Size]);

    end;

  finally

    Free;

  end;

end;

El código anterior en Delphi XE4 bajo Windows 7 Professional x32, corrige el código del Msg #15 en los casos en que los archivos a visualizar no sean múltiplos del factor de visualización (BPF), como se muestra en la siguiente imagen:



El código esta disponible en : Visualizador de Archivos en Hexadecimal v2 en FireMonkey

Espero sea útil :)

Nelson.

muchas gracias, agradezco mucho que hayan compartido su experiencia en este lenguaje conmigo. muchas gracias^\||/^\||/:D

aprovecho, para preguntarles, se podrá recuperar el archivo con su extensión original.
pues al hacer el cambio en el archivo después de editarlo, no vuelve a funcionar, por que esta en hexadecimal.
¿se puede recuperar el archivo original, pero después de haberlo modificado?.

Hola elmago00.

No me queda claro desde donde o a partir de qué pensas recuperar el archivo original, pero sin dudas agradecerás haber llamado a este procedimiento antes de modificar el ejecutable:

Código Delphi [-]
procedure BeforeDoingCrap(aFileName: TFileName);
begin
  if not CopyFile(PChar(aFileName),
                  PChar(ExtractFilePath(aFileName)+ChangeFileExt(ExtractFileName(aFileName),'')+'.BAK'),
                  True) then
    MessageBox(0,PChar('Error: ' + SysErrorMessage(GetLastError)), '', MB_ICONERROR);
end;

De este modo, si se estropea el ejecutable, basta con borrarlo y luego renombrar el archivo .BAK como .EXE.

Saludos :)

elmago00,

Pregunto:

1- ¿Realizastes las correcciones al código indicadas en el Msg #18?, son vitales para la correcta carga y visualización del archivo en proceso.

2- ¿Que tipo de archivos estas modificando y por que lo haces de esta forma? :confused:

3- En el Msg #10 indicas que la aplicación esta hecha en FireMonkey y que tiene más de 40000 líneas de código, ¿Cual es el objetivo de esta aplicación?.

4- ¿Puedes detallar el proceso de modificación del archivo(s) en cuestión? :confused:

Espero sea útil :)

Nelson.

hola,
este es el tipo de archivo. por favor descarguen el archivo para que lo vean ustedes mismos.

http://www.mediafire.com/download/xj.../inChipset.rar

quiero restaurarlo a su estado original, después de editarlo. es decir guardar cambios.

les adjunto una imagen para que ven la dirección modificar. y la verdad haber si me ayudan ya que reemplazo la cadena hexadecimal, pero la anterior no se borra,
sino que sigue delante de la otra. como si añadiera string y no reemplaza el hexadecimal, pues debo borrar los siguientes 47 caracteres. solo puedo especificar la dirección, pues el hexadecimal es diferente en todos los archivos. no puedo especificar el hexadecimal a reemplazar. solo la dirección.

es poco difícil verdad. debo entregrarlo en dos días jeje

amigos alguna idea de como hacer todo esto? el tiempo se me agota jeje

Esperando respuestas...

si hice las correcciones, eso ya esta solucionado, veo el archivo y lo guardo, esta solucionado.
el tipo de archivo se los pues en el link de descarga.
el objetivo ya lo e detallado en el anterior mensaje. asi como el proceso de edición del mismo.


saludos

Hola elmago00.

Sigo sin entender desde donde queres restaurar el archivo original, pero ya te sugerí una idea. Te ejemplifico el uso:

Código Delphi [-]
...
procedure BeforeDoingCrap(const aFileName: TFileName);
begin
  CopyFile(PChar(aFileName),
           PChar(ExtractFilePath(aFileName)+ChangeFileExt(ExtractFileName(aFileName),'')+'.BAK'),
           True);
end;

procedure FixCrap(const aFileName: TFileName);
begin
  if MessageBox(0,'¿ Desea restaurar el archivo original ?','',MB_ICONQUESTION+MB_YESNO)=IDYES then
  begin
    Windows.DeleteFile(PChar(aFileName));
    if not MoveFile(PChar(ExtractFilePath(aFileName)+ChangeFileExt(ExtractFileName(aFileName),'')+'.BAK'),
       PChar(aFileName)) then
    MessageBox(0,PChar('Error: ' + SysErrorMessage(GetLastError)), '', MB_ICONERROR);
  end;
end;

procedure TForm1.btnLoadFileClick(Sender: TObject);
begin 
  BeforeDoingCrap('C:\Carpeta\notepad.exe'); 
  // En este punto tenes realizado el resguardo y podes hacer 
  // con el archivo original todas las aberraciones se se te ocurran :)
  procedure DumpFile('C:\Carpeta\notepad.exe',16); 
end;


// Boton anti-pánico
procedure TForm1.btnFixClick(Sender: TObject);
begin
  FixCrap('C:\Carpeta\notepad.exe'); // Restaurar original desde copia
end;

Saludos :)

quiero editar el archivo en hexadecimal y guardarlo todo. guardar todo el archivo hexadecimal pero ya modificado y en su extensión original.
para que funciono como antes con la modificacion hecha.

Hola elmago00.
Ahora si te entiendo.

Pero es claro que, el que funcione o no, dependerá de los cambios que realizes. Basta una sóla modificación indebida sobre una dirección de memoria, puntero, segmento, offset, etc, como para hacer que la aplicación se cuelgue o peor aún... haga alguna cosa no deseada.

Saludos :)

elmago00,

Te comento:

1- No has respondido en detalle las preguntas 2, 3 y 4 formuladas en el Msg #22.

2- No especificas ningún detalle de la funcionalidad del archivo inChipset.bin del Msg #23, ¿Que es ese archivo?, ¿Cual es su origen?, ¿Cual es su uso?, ¿Que es lo que quieres modificar y por que?.

Suerte en tu proyecto :cool:

Nelson.

el objetivo es modificar la función de este IC, por que funciona bien, y para eso debemos hacer lo antes descrito.
esto solo de puede hacer en ensamblador y hexadecimal. nosotros lo hacemos en hexadecimal.


y para colmo a la hora de modificar el archivo hexadecimal, no puedo eliminar la cadena anterior por que es diferente en todos los archivos, lo unico que se me ocurre es eliminar un conteo de los siguientes caracteres, pero hasta ahora no veo como.


después de hacer esto debo restaurarlo a su extensión original

ahora si conteste a sus preguntas?

se que es complicado, tienen alguna idea.

intente realizar un conteo de caracteres siguientes para eliminarlo pero nada funciona.
y menos el recuperar el archivo despues de editarlo.

Hola elmago00.
Hola elmago00.

Este código permite abrir, modificar, buscar texto obre la columna ASCII y guardar el archivo modificado con el mismo nombre u otro.

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids, XPMan, Menus, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    MainMenu1: TMainMenu;
    OpenDialog1: TOpenDialog;
    SaveDialog1: TSaveDialog;
    FindDialog1: TFindDialog;
    Archivo1: TMenuItem;
    miOpen: TMenuItem;
    miSave: TMenuItem;
    Buscartexto1: TMenuItem;
    Panel1: TPanel;
    Label1: TLabel;
    ComboBox1: TComboBox;
    StringGrid1: TStringGrid;
    procedure FormCreate(Sender: TObject);
    procedure miOpenClick(Sender: TObject);
    procedure StringGrid1SelectCell(Sender: TObject; ACol, ARow: Integer;
      var CanSelect: Boolean);
    procedure Buscartexto1Click(Sender: TObject);
    procedure FindDialog1Find(Sender: TObject);
    procedure miSaveClick(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FStream: TMemoryStream;
    FColAsc: TStrings;
    FFind: Integer;
    procedure DumpFile(aFileName:TFileName; const BPF: Word);
    procedure SaveDump(aFileName:TFileName; const BPF: Word);
  public
  end;

var
  Form1: TForm1;

implementation {$R *.dfm}

{ Public declarations }
procedure TForm1.FormCreate(Sender: TObject);
begin
  ComboBox1.Items.CommaText:= '8,10,16,24,32,48,64,128,255';
  ComboBox1.ItemIndex:= 2;
  FStream:= TMemoryStream.Create;
  FColAsc:= TStringList.Create;
  with StringGrid1 do
  begin
    Options:= Options-[goVertLine]-[goHorzLine]+[goEditing];
    Font.Name:= 'Courier';
    Font.Size:= 10;
    Col:= 1;
    Row:= 1;
  end;
end;

procedure TForm1.miOpenClick(Sender: TObject);
begin
  with OpenDialog1 do
  begin
    Filter:= '*.*';
    if Execute then
    begin
      Caption:= FileName;
      DumpFile(FileName, StrToInt(ComboBox1.Items[ComboBox1.ItemIndex]) );
    end;
  end;
end;

procedure TForm1.StringGrid1SelectCell(Sender: TObject; ACol,
  ARow: Integer; var CanSelect: Boolean);
begin
  with TStringGrid(Sender) do
    CanSelect:= ((ACol>0)and(ACol < ColCount-1) and
      ((ARow>= FixedRows)and(ARow < RowCount)));
end;

procedure TForm1.miSaveClick(Sender: TObject);
begin
  with SaveDialog1 do
  begin
    Filter:= '*.*';
    if Execute then SaveDump(FileName, 16);
  end;
end;

procedure TForm1.Buscartexto1Click(Sender: TObject);
begin
  with FindDialog1 do
  begin
    FFind:= 0;
    Execute;
  end;
end;

procedure TForm1.FindDialog1Find(Sender: TObject);
begin
  while(FFind < FColAsc.Count)and(Pos(FindDialog1.FindText,FColAsc[FFind])=0) do
      Inc(FFind);
  if (FFind < FColAsc.Count-1) then
  begin
    Inc(FFind);
    StringGrid1.Row:= FFind;
    StringGrid1.Col:= 1;
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FStream.Free;
  FColAsc.Free;
end;


{ Private declarations }
procedure TForm1.DumpFile(aFileName:TFileName; const BPF: Word);
var
  c, i, r: integer;
  ascii: string;
  aux: Byte;
begin
  FStream.LoadFromFile(aFileName);
  with StringGrid1 do
  begin
    ColWidths[0]:= 80;
    Cells[0,0]:= 'Offset (h)';
    ColCount:= BPF+2;
    ColWidths[ColCount-1]:= Canvas.TextWidth('X')*BPF+10;
    Cells[ColCount-1,0]:= 'ASCII';
    for i:= 0 to BPF-1 do
    begin
      ColWidths[i+1]:= 30;
      Cells[i+1,0]:= IntToHex(i, 2);
    end;
    RowCount:= FStream.Size div BPF+1;

    FStream.Seek(0, soBeginning);
    c:= 0;
    r:= FixedRows;
    while c < FStream.Size do
    begin
      Cells[0, r]:= Format('%s',[IntToHex(c, 8)]);
      ascii:= EmptyStr;
      i:= 0;
      while (i < BPF) and(i+c < FStream.Size) do
      begin
        FStream.Read(aux, SizeOf(Byte));
        Cells[i+1,r]:= IntToHex(aux,2);
        if aux in [$0..$0D,$80..$90] then aux:= Ord('.');
        ascii:= ascii + Chr(aux);
        Inc(i);
      end;
      FColAsc.Add(ascii);
      Cells[ColCount-1,r]:= ascii;
      Inc(c, BPF);
      Inc(r);
    end;
  end;
end;

procedure TForm1.SaveDump(aFileName:TFileName; const BPF: Word);
var
  MS: TMemoryStream;
  c,r: Integer;
  buff: array of Byte;
begin
  with StringGrid1 do
  begin
    MS:= TMemoryStream.Create;
    try
      SetLength(buff, BPF);
      for r:= FixedRows to RowCount-1 do
      begin
        for c:= 0 to BPF-1 do buff[c]:= StrToInt('$'+Cells[c+1, r]);
        MS.WriteBuffer(buff[0], BPF);
      end;
      MS.SaveToFile(aFileName);
    finally
      SetLength(buff,0);
      MS.Free;
    end;
  end;
end;
end.

Lamento no haberlo escrito para FireMonkey pero solo cuento con Delphi 7. Con seguridad lo podrás adaptar del modo como comentaste en el mensaje #19.

En todas las pruebas que realizé, modificando constantes de texto, el ejecutable resultante funcionó de modo correcto mostrando los valores modificados.

Descarga desde FTP Club Delphi: EditorHexadecimalBásico

Saludos :)

elmago00,

^\||/

:rolleyes:

Te comento: No puedes salvar la representación Hexadecimal del archivo cargado en el TStringGrid y que este tenga los atributos y comportamiento del original, debes salvar el archivo y sus modificaciones en Binario.

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Rtti, System.Classes,
  System.Variants, System.UIConsts, FMX.Types, FMX.Controls, FMX.Forms, FMX.Dialogs,
  FMX.StdCtrls, FMX.ListBox, FMX.Layouts, FMX.Grid;

type

  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    ComboBox1: TComboBox;
    OpenDialog1: TOpenDialog;
    SaveDialog1: TSaveDialog;
    Button1: TButton;
    Button2: TButton;
    StatusBar1: TStatusBar;
    Label1: TLabel;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    SaveDialog2: TSaveDialog;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
    procedure SaveDumpText(aFileName:TFileName; SG: TStringGrid);
    procedure SaveDumpBinary(aFileName:TFileName; const BPF: Word);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  CancelProcess : Boolean;

implementation

{$R *.fmx}

procedure TForm1.DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
var
  c, i, r, b : Integer;
  Ascii: String;
  Aux: Byte;
  Col : Integer;

begin

  with TMemoryStream.Create do
  try

    LoadFromFile(aFileName);

    Caption:= Format('FileName = %s , FileSize = %d Bytes', [aFileName, Size]);

    // Configurar StringGrid

    SG.ShowHeader := False;
    SG.ShowHorzLines := False;
    SG.ShowVertLines := False;

    for i := 1 to BPF + 2 do
       SG.AddObject(TStringColumn.Create(nil));

    SG.RowCount := (Size div BPF) + 1;
    if (Size Mod BPF) <> 0 then
       SG.RowCount := SG.RowCount + 1;

    for Col := 0 to SG.ColumnCount - 1 do
    begin

        if (Col = 0) then
           SG.Columns[Col].Width := 80;

        if (Col <> SG.ColumnCount - 1) and (Col <> 0) then
           SG.Columns[Col].Width := 30;

        if (Col = SG.ColumnCount - 1) then
           SG.Columns[Col].Width := SG.Canvas.TextWidth('X') * BPF;

    end;

    SG.Cells[0,0]:= 'Offset(h)';
    SG.Cells[SG.ColumnCount-1,0]:= 'ASCII';

    for i:= 0 to BPF-1 do
    begin
      SG.Cells[i+1,0]:= IntToHex(i,2);
    end;

    // Cargar en StringGrid

    Seek(0, soBeginning);
    c:= 0;
    r:= 1;
    b := 0;

    while c < Size do
    begin

      Application.ProcessMessages;

      if CancelProcess then
      begin
         CancelProcess := False;
         Break;
      end;

      SG.Cells[0, r]:= Format('%s',[IntToHex(c, 8)]);
      Ascii:= EmptyStr;
      i:= 0;

      while (i < BPF) and (b < Size) do
      begin
        Read(Aux, SizeOf(Byte));
        SG.Cells[i+1,r]:= IntToHex(Aux,2);
        if Aux = 0 then Aux := 46;
        Ascii:= Ascii + Chr(Aux);
        Inc(i);
        if (b < Size) then Inc(b);
      end;

      SG.Cells[SG.ColumnCount-1,r]:= Format('%s',[Ascii]);
      Inc(c, BPF);
      Inc(r);
      Label1.Text := Format('Procesado Byte %d de %d',[b, Size]);

    end;

  finally

    Free;

  end;

end;

// Salvar StringGrig a TXT
procedure TForm1.SaveDumpText(aFileName:TFileName; SG: TStringGrid);
var
  c,r: Integer;
  s: String;
begin
  with TStringList.Create do
  try
    for r:= 0 to SG.RowCount-1 do
    begin
      s:= '';
      for c:= 0 to SG.ColumnCount-1 do s:= s + SG.Cells[c,r] + ' ';
      SetLength(s,Length(s)-1);
      Add(s);
    end;
    SaveToFile(aFileName);
  finally
    Free;
  end;
end;

// Salvar StringGrig a Binario
procedure TForm1.SaveDumpBinary(aFileName:TFileName; const BPF: Word);
var
  MS: TMemoryStream;
  c,r: Integer;
  buff: array of Byte;
begin
  with StringGrid1 do
  begin
    MS:= TMemoryStream.Create;
    try
      SetLength(buff, BPF);
      for r:= 1 to RowCount-1 do
      begin
        for c:= 0 to BPF-1 do buff[c]:= StrToInt('$'+Cells[c+1, r]);
        MS.WriteBuffer(buff[0], BPF);
      end;
      MS.SaveToFile(aFileName);
    finally
      SetLength(buff,0);
      MS.Free;
    end;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ComboBox1.Items.CommaText:= '8,10,16,24,32,48,64,128,255';
  ComboBox1.ItemIndex:= 2;
end;

// Carga un Archivo en Modo Hexadecimal en un StringGrid
procedure TForm1.Button1Click(Sender: TObject);
begin
  with OpenDialog1 do
  begin
    Filter:= '*.*';
    if Execute then
    begin
      DumpFile(FileName, StringGrid1,
        StrToInt(ComboBox1.Items[ComboBox1.ItemIndex]) );
    end;
  end;
end;

// Salva un Archivo en Modo Hexadecimal en un StringGrid a TXT
procedure TForm1.Button2Click(Sender: TObject);
begin
  with SaveDialog1 do
  begin
    Filter:= '*.txt';
    DefaultExt:= '*.txt';
    if Execute then
      SaveDumpText(FileName, StringGrid1);
  end;
end;

// Cancela Carga de un Archivo en Modo Hexadecimal en un StringGrid
procedure TForm1.Button3Click(Sender: TObject);
begin
   CancelProcess := True;
end;

// Inicializa el StringGrid
procedure TForm1.Button4Click(Sender: TObject);
var
   i : Integer;
begin
   StringGrid1.RowCount := 0;
   for i := StringGrid1.ColumnCount - 1 downto 0 do
         StringGrid1.Columns[i].DisposeOf;
end;

// Salva un Archivo en Modo Hexadecimal en un StringGrid a Binario
procedure TForm1.Button5Click(Sender: TObject);
begin
  with SaveDialog1 do
  begin
    Filter:= '*.*';
    if Execute then SaveDumpBinary(FileName, 16);
  end;
end;

end.

El código anterior en Delphi XE4 bajo Windows 7 Professional x32, es la versión 3 del código propuesto en el Msg #15 con las correcciones incluidas del Msg #18, el cual te permitirá: Cargar, Representar y Editar archivos visualmente en Hexadecimal y salvarlos posteriormente en su representación Hexadecimal (Modo Texto) o Binaria, como se muestra en la siguiente imagen:



El código esta disponible en : Visualizador de Archivos en Hexadecimal en FireMonkey v3

Suerte en tu proyecto :cool:

Nelson.

elmago00,

Continuación del Msg #34

Una pequeña corrección :rolleyes: :

Código Delphi [-]
// Salvar StringGrig a Binario
procedure TForm1.SaveDumpBinary(aFileName:TFileName; const BPF: Word);
var
  MS: TMemoryStream;
  c,r: Integer;
  Buffer: Byte;
  Msg : String;
begin
  with StringGrid1 do
  begin
    MS:= TMemoryStream.Create;
    try
      for r:= 1 to RowCount-1 do
      begin
        for c:= 0 to BPF-1 do
        begin
           if (Cells[c+1, r] <> '') then
           begin
              Buffer := StrToInt('$'+Cells[c+1, r]);
              MS.WriteBuffer(Buffer, 1);
           end;
        end;
      end;
      MS.SaveToFile(aFileName);
    finally
      MS.Free;
      Msg := 'Generación de Archivo Binario Completada Satisfactoriamente';
      MessageDlg(Msg,TMsgDlgType.mtInformation,[TMsgDlgBtn.mbOk],0);
    end;
  end;
end;

Código Delphi [-]
// Salva un Archivo en Modo Hexadecimal en un StringGrid a Binario
procedure TForm1.Button5Click(Sender: TObject);
var
   BPF : Integer;
begin
  with SaveDialog1 do
  begin
    Filter:= '*.*';
    BPF := StrToInt(ComboBox1.Items.Strings[ComboBox1.ItemIndex]);
    if Execute then SaveDumpBinary(FileName, BPF);
  end;
end;

El código anterior en Delphi XE4 bajo Windows 7 Professional x32, corrige el código del Msg #34 en los casos en que los archivos a visualizar no sean múltiplos del factor de visualización (BPF), como se muestra en la siguiente imagen:



Suerte en tu proyecto :cool:

Nelson.

llevo horas tratando, pero creo que mejor haré los cambios, y lo guardare en SaveToStream.
para que guarde los cambios en el archivo original. después de editarlo en memoria.
seguiré tratando y luego les cuento como fue.

elmago00,

Pregunto: ¿Probastes el código del Msg #34 y la corrección del Msg#35?.

Nelson.

Hola elmago00.

¿ Es imprescindible que uses FireMonkey ? Por que el código del mensaje #33 esta probado, hace lo que buscas y funciona correctamente. También pude apreciar que no son tan radicales las modificaciones echas al código que parten de este enlce Codigo Hexadecimal para adecuarlas a FireMonkey.

Por otro lado, si deseas usa un editor hexadecimal mas poderoso, te vuelvo a sugerir lo que te mencioné en el otro hilo: HxD es totalmente gratuito.

Saludos :)

Porsupuesto Nelson y dejame decirte que funciona perfecto. pero bajo un control TSringGrid.
y estoy usando el código de efisa del msg#17 este código me permite almacenarlo en variable y editarlo desde un archivo y sin usar el Control visible.
lo que hago en estos momentos es pasar tu código para que al igual al de ecfisa editarlo en un archivo guardado. y luego pasarlo a binario, tal y como lo tienes tu que funciona, pero que no eso ese método por que se demora, 15 minutos en cargar un archivo de 9mb.

Código Delphi [-]
// Salvar StringGrig a Binario
procedure TForm1.SaveDumpBinary(aFileName:TFileName; const BPF: Word);
var
  MS: TMemoryStream;
  c,r: Integer;
  Buffer: Byte;
  Msg : String;
begin
  with StringGrid1 do
  begin
    MS:= TMemoryStream.Create;
    try
      for r:= 1 to RowCount-1 do
      begin
        for c:= 0 to BPF-1 do
        begin
           if (Cells[c+1, r] <> '') then
           begin
              Buffer := StrToInt('$'+Cells[c+1, r]);
              MS.WriteBuffer(Buffer, 1);
           end;
        end;
      end;
      MS.SaveToFile(aFileName);
    finally
      MS.Free;
      Msg := 'Generación de Archivo Binario Completada Satisfactoriamente';
      MessageDlg(Msg,TMsgDlgType.mtInformation,[TMsgDlgBtn.mbOk],0);
    end;
  end;
end;

este es tu código que trato de usar sin el control.

dirás por que este se complica tanto. por la idea es modificar el archivo sin visualizarlo. así la corrección en el IC se hace mas rápido, y el procesador (que no es muy poderoso) lo ejecuta rápido.

todo el software tiene 15 unit, 6 dll. y 83 procesos y 57 funciones.
los procesos son muy grandes, el mínimo tiene 1200 lineas.

una unit tiene 11.453 lineas. las otras son de 2000. todo esto es bajo firemonkey, pasarlo a vcl es imposible en tan poco tiempo.
y la idea es que todo este en el mismo programa, pues el gerente informático de la otra empresa así lo solicito.(no se por que)


aun con VCL, tu me has ayudado enormemente y que decir de Nelson, tiene un cerebro para firemonkey, que me pregunto ¿son humanos?:):)