Abrir aplicacion, reproducir archivo y esperar a q termine
 

Hola Amigos Foreros.....nuevamente solicitando de su ayuda.

Estoy tratando de hacer un programa en delphi (D6), que me permita lo siguente:

1.- Abrir una aplicación dependiendo del archivo que quiero abrir (archivo de video).
2.- Que dicha aplicación reproduzca el archivo y que se cierre automáticamente cuando termine de reproducirlo.
3.- Que desde delphi, espere a que termina de reproducirlo, para ejecutar otro proceso.

Hasta ahorita tengo esto:

Código Delphi [-]
procedure TForm1.btnReproducirClick(Sender: TObject);
var
   St : array[0..255] of char;
begin

     With lvLista do
     begin
         i:=0;
         While i< Items.Count do
         begin
              if lvLista.Items[i].Checked then
              begin
                   ShellExecute(Handle,'open',StrPCopy(St,Items.Item[i].SubItems.Strings[1]),nil,nil,SW_SHOW);
               end;
              inc(i);
         end;
     end;
end;

Hace algo de lo que necesito....abre el archivo seleccionado junto con la aplicación asociada al archivo....pero necesito que despues de que termine de reproducirse, se ejecute algo mas....y sí le agrego código, despues de ShellExecute, lo ejecuta sin que se haya terminado la reproducción.

Y también me encontré esto:

Código Delphi [-]
procedure TForm1.btnReproducirClick(Sender: TObject);
var
   Ventana: HWND;
   NumProceso:Cardinal;
begin
     Application.Minimize;
     NumProceso:=ejecutarProceso('C:\Program Files (x86)\KaraFun\KaraFun.exe');
     if NumProceso<>0 then
         WaitForSingleObject(numProceso,INFINITE);
     Application.Restore;
end;

El codigo anterior, haria falta para completar lo q necesito. Con este código quedaría resuelto sí en la parte de "NumProceso:=ejecutarProceso('C:\Program Files (x86)\KaraFun\KaraFun.exe');", le pudiera indicar q ejecute el archivo "pista1.cdg" o cualquier otro, talvez de la siguiente forma:

"NumProceso:=ejecutarProceso('C:\Program Files (x86)\KaraFun\KaraFun.exe@pista1.cdg');"....que realmente no sé sí se le pueda pasar como parámetro.

Abre la aplicacion externa que le indico y mi aplicacion esta en espera hasta que el programa q abrio, se cierre. Este proceso incluye una función (ejecutarProceso):

Código Delphi [-]
function ejecutarProceso (nombreProceso : string) : Cardinal;
var
  infoInicio : TStartupInfo;
  infoProceso : TProcessInformation;
begin
  Result := 0;

  FillChar (infoInicio, SizeOf(infoInicio), 0);
  infoInicio.cb := SizeOf(infoInicio);

  if CreateProcess(PChar(nombreProceso), nil,
      nil, nil, false, 0, nil, nil,
      infoInicio, infoProceso) then
    Result := infoProceso.hProcess;
end;

Pero con lo anterior solo logro abrir la aplicación y cuando la cierro...el control vuelve a mi programa de delphi....pero no se como decirle q tambien me reproduzca el archivo en cuanto se abre la aplicacion externa.

Estos códigos hacen lo que requiero, pero por separado....alguna otra forma de hacerlo? o combinar estos códigos para lograr lo q necesito?

Espero haberme hecho entender....agradezco su tiempo compañeros....Saludos.

Prueba a cambiar la función ejecutarProceso por esta (he cambiado los 2 primeros parámetros):

Código Delphi [-]
function ejecutarProceso (nombreProceso : string) : Cardinal;
var
  infoInicio : TStartupInfo;
  infoProceso : TProcessInformation;
begin
  Result := 0;

  FillChar (infoInicio, SizeOf(infoInicio), 0);
  infoInicio.cb := SizeOf(infoInicio);

  if CreateProcess(nil, PChar(nombreProceso), 
      nil, nil, false, 0, nil, nil,
      infoInicio, infoProceso) then
    Result := infoProceso.hProcess;
end;

Y ahora en la llamada pásale no sólo el nombre del EXE, sinó el EXE más el fichero a reproducir; Algo así:

Código Delphi [-]
NumProceso:=ejecutarProceso('C:\Program Files (x86)\KaraFun\KaraFun.exe  C:\Program Files (x86)\KaraFun\pista1.cdg');

Ya dirás...

Ok...gracias Neftali por responder.....lo pruebo y te comento.

No reprodujo el archivo
 

Que tal Neftali.

Modifiqué el código y no reprodujo el archivo, el cual lo toma de un ListView, donde esta todo la ruta del archivo, se lo agregue como parámetro a la funcion "ejecutarProceso", como tu lo indicaste y no funciono....talvez la forma en como se lo paso, es decir tendrá algo que ver que lo tome de un listview?

Saludos.

Código Delphi [-]
procedure TForm1.btnReproducirClick(Sender: TObject);
var
   St : array[0..255] of char;
   NumProceso:Cardinal;
begin
     With lvLista do
     begin
         i:=0;
         While i < Items.Count do
         begin
             if lvLista.Items[i].Checked then
             begin
                 Application.Minimize;
                 NumProceso:=ejecutarProceso('C:\Program Files (x86)\KaraFun\KaraFun.exe '+Items.Item[i].SubItems.Strings[1]);
                 if NumProceso<>0 then
                     WaitForSingleObject(numProceso,INFINITE);
                 Application.Restore;
             end;
             inc(i);
         end;
     end;

end;

Y la función quedó como tu la escribiste.

¿Si pones la llamada directamente sin usar el listview (sólo para probar), lo reproduce?

También tendrás que mirar, si ese programa en concreto, tiene implementada la posibilidad de aceptar parámetros.

Gracias, por contestar.....

Fijate que talvez vaya a ser que el programa externo no acepta parametros....en realidad ignoro si lo hace. Probare lo que comentas de ejecutarlo directamente sin tomarlo del ListView....y en cuanto a que si acepta parametros el ejecutable, pues lo investigare. Yo creo que ese va a ser el problema.

Luego comento que paso.
Saludos

Cuando una ruta tiene espacios se debe colocar entre comillas para que el S.O. entienda desde donde comienzan los parámetros:

Código Delphi [-]
ejecutarProceso('"C:\Program Files (x86)\KaraFun\KaraFun.exe" "C:\Program Files (x86)\KaraFun\pista1.cdg"');

Saludos.

AHHH....ok....SIIII !!!....EFECTIVAMENTE FUNCIONO de esa forma....gracias escafandra !.

Gracias a Neftali y Escafandra por sus aportes....ya se pudo.

Saludos....

Solucionado....
 

Asi quedo el codigo final:

Código Delphi [-]
procedure TForm1.btnReproducirClick(Sender: TObject);
var
   St : array[0..255] of char;
   NumProceso:Cardinal;
begin
     With lvLista do
     begin
         i:=0;
         While i < Items.Count do
         begin
             if lvLista.Items[i].Checked then
             begin
                 Application.Minimize;
                 NumProceso:=ejecutarProceso('"C:\Program Files (x86)\KaraFun\KaraFun.exe" "'+Items.Item[i].SubItems.Strings[1]+'"');
                 if NumProceso<>0 then
                     WaitForSingleObject(numProceso,INFINITE);
                 Application.Restore;
             end;
             inc(i);
         end;
     end;

end;

Con la funcion modificada que propuso neftali

Código Delphi [-]
function ejecutarProceso (nombreProceso : string) : Cardinal;
var
  infoInicio : TStartupInfo;
  infoProceso : TProcessInformation;
begin
  Result := 0;

  FillChar (infoInicio, SizeOf(infoInicio), 0);
  infoInicio.cb := SizeOf(infoInicio);

  if CreateProcess(nil, PChar(nombreProceso), 
      nil, nil, false, 0, nil, nil,
      infoInicio, infoProceso) then
    Result := infoProceso.hProcess;
end;

Un detalle más, cuando termine el proceso debemos cerrar los Handles:

Código Delphi [-]
CloseHandle(infoProceso.hProcess);
CloseHandle(infoProceso.hThread);

Saludos.

Ok, gracias....ahora donde pondría los "Close"?...Dentro de la función?

Auna la ejecución (CreateProcess), la espera (WaitForSingleObject) y el cierre de los dos Handles, en la misma función (ejecutarProceso)

Saludos.