Busqueda en TStringGrid
 

Buenos días compañer@s

El tema que me intraquliza el día de hoy es el siguiente:

Estoy trabajando con un TStringGrid con una sola columna, en éste almaceno en forma ordenada la información, pero mi duda surgue al saber si existe algún método que me permita localizar la celda en la que se encuentre dicha información.

Agradezco su colaboración


GerTorresM
Colombia

La propiedad Cols te permite acceder a cada columna como un TStrings y un TStrings tiene el método IndexOf para buscar:

Código Delphi [-]
if StringGrid1.Cols[0].IndexOf('Término a buscar') <> -1 then
  ShowMessage('Encontrado')
else
  ShowMessage('No encontrado');

LineComment Saludos

Por otra parte, si tu StringGrid sólo tiene una columna, ¿no te sería más cómodo trabajar con un ListBox?

LineComment Saludos

No permitas que un componente visual se convierta en tu estructura de datos. Lo mas adecuado es guardar la informacion en la estructura que mejor se adapte a tus necesidades (si necesitas busquedas eficientes podes usar algun tipo de arbol, pero si en lugar de realizar muchas busquedas, tenes muchas operaciones de insercion, quiza una lista desordenada se comporte mejor).

Luego tenes que "conectar" tu estructura con el control usando algo que medie entre la estructura y el control. A mi me parece valido que cada "nodo" conozca cual es su indice dentro del componente visual, es decir, que tenga una propiedad en la que el control indique cual es la posicion en la que "dibujo" este elemento; o al reves, que el componente respete el indice de cada nodo el cual es definido en tu estructura

Teniendo esto, cambiar entre componentes, cambiar la estructura, o realizar operaciones como la que indicas en las que el control visual "no tiene soporte", es trivial, y lo mejor, esta todo separado y ordenado y no todo mezclado

Si estás usando un TStringGrid con la columna ordenada, yo optaría por una variante a la solución que te ha dado Román, que te va a aportar mucha más velocidad.
Los TStringList poseen el método Find, que es realmente rápido cuando la lista está ordenada.

Es posible que haciendo un CAST de la columna puedas utilizar este método, mucho más rápido que el IndexOf que es secuencial.

Me marca un Acces Violation.

LineComment Saludos

Muchas gracias
 

Muchas gracias:

El conocimiento de este club es algo enviadable, y como no tomar la sugerencia, vamos a aplicar el TStringList !

Pero no puedes aplicarlo directamente. La clase TStrings no posee el método Find por lo cual no puedes usarlo ni siquiera através de un moldeo. Esto funcionaría si TStrings tuviera el método Find pero estuviera protegido (creo que en esto pensaba Neftali).

En lo personal, si estás manejando listas relativamente cortas yo usaría un ListBox y su método IndexOf, que, aunque secuencial, será suficiente si la lista no es muy grande.

En caso de tener listas muy grandes, sería mejor optar por lo que apunta AgustinOrtu, y puede hacerse de forma sencilla:

1. Usas un ListBox en modo virtual (propiedad Style = lbVirtual)
   
   
2. Usas un TStringList aparte. Éste podrías declararlo en tu formulario y crearlo y destruirlo con él:
   
   

   Código Delphi [-]
   interface
   
   type
     TForm1 = class(TForm)
       ListBox1: TListBox;
   
     private
       Lista: TStringList;
     end;
   
   implementation
   
   procedure TForm1.FormCreate(Sender: TObject);
   begin
     Lista := TStringList.Create;
     Lista.Sorted := true;
   end;
   
   procedure TForm1.FormDestroy(Sender: TObject);
   begin
     Lista.Free;
   end;

3. Al agregar un elemento usas el método Add del TStringList:
   
   

   Código Delphi [-]
   procedure TForm1.Agregar(S: String);
   begin
     Lista.Add(S);
     ListBox1.Count := Lista.Count;
   end;

   
   Observa que estás agregando directamente al TStringList y no al ListBox, pero debes actualizar la propiedad Count del ListBox para que éste sepa cuántos elementos debe dibujar.
   
   
4. Para buscar un elemento, ahora sí, usas el método Find:
   
   

   Código Delphi [-]
   procedure TForm1.Buscar(S: String);
   var
     I: Integer;
   
   begin
     if Lista.Find(S, I) then
       ListBox1.ItemIndex := I;
   end;

5. Finalmente, para que el ListBox refleje la información del TStringList, usas su evento OnData:
   
   

   Código Delphi [-]
   procedure TForm1.ListBox1Data(Control: TWinControl; Index: Integer; var Data: String);
   begin
     Data := Lista[Index];
   end;

LineComment Saludos

Tiene razón (como siempre) Román.
Contesté demasiado rápido lo que tenía en la cabeza, sin acabar de pensarlo del todo... :o:o

Efectívamente el CAST directo dará un Access Viotation.
En ese caso habría que usar un TStringList auxiliar, asignar los elementos (asumiendo que están ordenados como has dicho) y realizar la búsqueda sobre este segundo objeto.
El problema es que para una lista pequeña, posíblemento lo que se gana en la búsqueda, se perderá en la asignación. :(