Bloquear caracteres.
 

Saludos cordiales.

Por ejemplo, tengo mi variable declarada como número entero, por lo tanto si ingreso una letra por error, el programa se cerrará....
He averiguado sobre declarar la variable como string y posteriormente convertirla a entero.
Sé de la existencia de: VAL (aunque por el momento lo la he usado) , 'try' y 'except'.
--
He estado pensando que quizás exista otra manera de bloquear caracteres indeseables.
Por ejemplo en android existe un programa llamado 'Unit Converter Ultimate', por lo tanto en este programa los caracteres, las letras están bloquedas, es decir los botones están bloqueados, por lo mismo solo aparece el teclado numérico en pantalla.
-----
Mi objetivo es Windows, no Android.

Sin embargo, ¿Es posible agregar un código, de tal manera, que si el usuario, presiona por equivocación una letra o otro carácter, éste no aparezca en pantalla.?

ej: Si presiona 'q', (La q no se mostrará en pantalla) ; pero si se presiona un número, éste aparecerá en pantalla.
(Utilizo Lazarus)

Gracias por leer el post.

Hola bit

No utilizo Lazarus, pero en Delphi para ese fin uso el siguiente procedimiento, que realiza lo que té necesitas.

Código Delphi [-]
procedure OnlyNumber(Sender: TWinControl);
begin
SetWindowLong(Sender.Handle, GWL_STYLE,
GetWindowLong(Sender.Handle, GWL_STYLE) + ES_NUMBER);
end;

y para llamarlo

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
begin
OnlyNumber(Edit1);
end;

No sé si te servirá en Lazarus.
Ojalá haya podido ayudarte.

Saludos

Hola bit.

Si estas programando para GUI, te faltó aclarar sobre que control deseas realizar la comprobacion. Como lo mas común es que sea una instancia de TEdit, voy a usar este componente para ejemplo.

Para números naturales:

Código Delphi [-]
...
uses Windows;

procedure TForm1.FormCreate(Sender: TObject);
begin
  SetWindowLong(Edit1.Handle, GWL_STYLE,
    GetWindowLong(Edit1.Handle, GWL_STYLE) + ES_NUMBER);
end;

Para números reales:

Código Delphi [-]
// para evitar que pulsen
procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
begin
  with Sender as TEdit do
    ReadOnly:= (not (Key in[ #8,'0'..'9','-',DecimalSeparator])) or
      ((Key = DecimalSeparator)and(Pos(DecimalSeparator, Text)> 0) or
      ((Key = '-')and(SelStart<>0)));
end;

// para evitar que peguen
procedure TForm1.Edit1Exit(Sender: TObject);
var
  d: Double;
begin
  with (Sender as TEdit) do
    if not TryStrToFloat(Text, d) then
    begin
      SetFocus;
      raise Exception.Create('Ingrese un número válido');
    end;
end;

Si en cambio estas en modo consola, la cosa se complica un poco:

Código Delphi [-]
program Project1;

uses Windows, SysUtils;

function Readkey: Char;
var
  hConsoleInput: THandle;
  lpBuffer: INPUT_RECORD;
  nLength: Longword;
begin
  Result:= #0;
  hConsoleInput:= GetStdHandle(STD_INPUT_HANDLE);
  if hConsoleInput <> INVALID_HANDLE_VALUE then
    while ReadConsoleInput(hConsoleInput, lpBuffer, 1, nLength) do
      if (lpBuffer.EventType = KEY_EVENT) and (TKeyEventRecord(lpBuffer.Event).bKeyDown) then
      begin
         Result:= TKeyEventRecord(lpBuffer.Event).AsciiChar;
         Exit;
      end;
end;

// Ejemplo de uso:
var
  ch: Char;
  num : Integer;
begin 
  Write('Ingrese un numero: ');
  repeat
    ch := ReadKey;
    if ch in ['0'..'9'] then
    begin
      write(ch);
      num:= num *10 + Ord(ch)-48
    end;
  until ch = #13;
  Writeln(#10,'Ingreso el numero: ', num);
  Readln;
end.

Saludos :)

Edito: No había visto el mensaje de Iván y repetí la función que publicó :o

Me alegra saber que existe una forma.
He sido poco especifico.
Por el momento, mis programas están escritos en Pascal.
Es un programa muy básico, es en consola, la cual deseo implementar 'aquella característica'.

Código Delphi [-]
program numero;
var
  n:integer;
begin
  writeln('Programa creado por Bit');
  write('Ingrese numero entero positivo:');
  readln(n);
  while (n<=-1) do
  begin
    writeln('Por favor, usted debe ingresar un numero entero positivo:');
    readln(n);
  end;
  writeln('Correcto,El numero ingresado es un entero positivo');
  readln;
end.

Hola bit.

Turbo Pascal traía la unida Crt que incluía funciones para teclado y pantalla, entre las que se encontraba ReadKey que fué la que redefiní en el código de mi mensaje anterior, ya que ni Delphi ni Lazarus la incorporan.

Viendo tu código, te comento que no hay manera de controlar los caracteres ingresados en las funciones Read y Readln; de ese modo no es posible.

Si te fijas el el código para consola del mensaje #3, verás que lo resuelvo con un ciclo y un condicional:

Código Delphi [-]
  repeat                               { repetir }
    ch := ReadKey;                     { esperar una tecla }
    if ch in ['0'..'9'] then           { si la tecla es una cifra }
    begin
      write(ch);                       { mostrarla }
      num:= num *10 + Ord(ch)-Ord('0') { agregar la cifra al numero }
    end;
    { si es otro caracter no se hace nada }
  until ch = #13;                      { hasta que se presione ENTER

De ese modo logro el control que no me permiten Read y Readln.

Saludos :)