Agregar Campo Calculado en Runtime - (Avanzado)
 

Resulta que yo armo una grilla dinamicamente segun el tipo y nombre de un campo que tomo de la respectiva tabla, para tal fin he diseñado ciertas funciones y procedimientos, de modo tal de indicar simplemente un Query y un grilla, y asi armarlo automaticamente y despreocuparme del tema. Me funciona perfecto y de mil maravillas. El tema está que en un caso en particular de una grilla, debo añadir un campo calculado, puesto a que, necesito calcular un valor al momento de la consulta (es un calculo, si bien no complejo, no lo puedo hacer directamente en la consulta).

Asi relleno mi grilla

Código Delphi [-]
procedure SQLToGrid(oQry : TZQuery; Grilla: TNxCustomGrid);
var Fields: Integer;
    Campo: String;
begin
  Grilla.Columns.Clear;
  Grilla.Color := clWhite;
  for Fields := 0 to oQry.FieldCount - 1 do
  begin
    Campo := oQry.Fields[Fields].DisplayName;
    SetColumna(Grilla,GetTipoCampoSQL(oQry,Fields),
                                      DeterminaNombreColumna(Campo),
                                      DeterminaAnchoColumna(Campo),
                                      true,
                                      EsVisible(Campo));
  end;
end;

El problema radica en que, si agrego los campos manualmente y luego el calculado, en la linea:

Código Delphi [-]
 
for Fields := 0 to oQry.FieldCount - 1 do

me tira error de que esta fuera de rango, pues claro, recorre un campo de más pero este no existe en la tabla, sino que es un calculado en el componente.

Como puedo resolver esto? alguna idea, ocurrencia, sugerencia y o crítica, serán bienvenidas.

Desde ya, muchas gracias.

Supongo que te debe estar fallando al acceder por índice a un Field/Columna que no existe.

Si los de la consulta y los del DBGrid son diferentes, ¿No puedes hacer comprobaciones antes de acceder al campo que necesitas?

Utilizando:

Código Delphi [-]
DBGrid.Columns
DBGrid.Columns[i].Field

Y para el Query Algo similar. Tal vez no entendí bien tu problema.

¿Podrías mostrarnos el mensaje de error exacto (usa Ctrl+C cuando aparezca) y en qué línea se detiene el programa?

Un error como el que señalas no debería ocurrir a menos que durante el ciclo For se estén eliminando campos. ¿Sucede algo como eso?

Saludos.

A ver. A mi me parece que el error no se debe al campo extra sino más bien a que ese campo extra es el único campo que existe.

Recuerden que si no se define ningún campo, ya sea durante el diseño o por código, el dataset genera dinámicamente los campos basándose en la estructura física de la tabla subyacente.

Pero, en el momento en que se agrega un campo, bien sea en diseño o por código, el dataset omite la generación dinámica y el campo o campos agregados son los únicos que existen para el dataset.

Si se abre la tabla antes de añadir el campo extra, pues no sirve de mucho porque no podemos agregar campos mientras la tabla esté abierta, y al cerrarla desaparecen los campos generados dinámicamente.

Lo único que se me ha ocurrido es:

1. Abrir la tabla
2. Copiar la lista de definiciones de campos (FieldDefs) a una lista temporal
3. Cerrar la tabla
4. Agregar todos los campos, basándose en las definiciones que tenemos guardadas.
5. Agregar cualquier campo extra
6. Abrir la tabla.

No lo he probado a fondo pero esto parece funcionar:

Código Delphi [-]
var
  FieldDefs: TFieldDefs;
  FieldDef: TFieldDef;
  Field: TField;
  NewField: TStringField;
  I: Integer;

begin
  Table1.Open;
  Table1.Close;

  FieldDefs := TFieldDefs.Create(Table1);
  FieldDefs.Assign(Table1.FieldDefs);

  for I := 0 to FieldDefs.Count - 1 do
    Field := FieldDefs[i].CreateField(Table1, nil, FieldDefs[i].Name);

  NewField := TStringField.Create(Table1);
  NewField.FieldName := 'Foo';
  NewField.Size := 10;
  NewField.FieldKind := fkCalculated;
  NewField.DataSet := Table1;

  Table1.Open;
end;

// Saludos

No se necesitan tantas variables ya que una vez abierta la tabla, FiledDefs ya no se borra al cerrarla.


Versión 2

Código Delphi [-]
var
  NewField: TStringField;
  I: Integer;

begin
  if Table1.FieldDefs.Count = 0 then
    Table1.Open;

  Table1.Close;

  for I := 0 to Table1.FieldDefs.Count - 1 do
    Table1.FieldDefs[i].CreateField(Table1, nil, Table1.FieldDefs[i].Name);

  NewField := TStringField.Create(Table1);
  NewField.FieldName := 'Foo';
  NewField.Size := 10;
  NewField.FieldKind := fkCalculated;
  NewField.DataSet := Table1;

  Table1.Open;
end;

// Saludos

Yo pense exactamente lo mismo, y como primera medida se me ocurrio agregar manualmente cada uno de los campos de la consulta, para evitar la generación dinámica, y asi tambien, agregar la definición del campo calculado. Esto funciona bien si solo agrego definiciones de campos que se encuentren en la consulta, no asi cuando agrego un campo calculado.

Cuyo mensaje de error es:

---------------------------
Debugger Exception Notification
---------------------------
Project Test.exe raised exception class EListError with message 'List index out of bounds (15)'. Process stopped. Use Step or Run to continue.
---------------------------
OK Help
---------------------------

Los puntos de ruptura que he puesto en el debbug, me llevan a la linea

Código Delphi [-]
for Fields := 0 to oQry.FieldCount - 1 do

En ningún caso elimino campos, y por seguridad y certeza he verificado todo el procedimiento para que tampoco sucediera algo similar por descuido.

Una clara evidencia de que solo esta tomando los 15 campos cuyas definiciones estan en la consulta, y no esta tomando el campo n16 que es el calculado. No entiendo porque el FieldCount no toma el campo calculado como un campo más, si bien este debe calcularse internamente desde el componente.

Tendría que modificar esto, de forma tal que integre además los campos calculados.

Creo que el problema está en:

Código Delphi [-]
  
for Fields := 0 to oQry.FieldCount - 1 do
  begin
    Campo := oQry.Fields[Fields].DisplayName;
    ShowMessage(Campo); 
  end;

Saludos

Tendrías que mostrarnos cómo estás añadiendo los campos y en qué momento. Tal como dije antes, el ejemplo que puse funciona correctamente y con un campo calculado. Acabo de adaptarlo a un query a la base DBDEMOS con la consulta

Código SQL [-]
select * from employee

El código queda así:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  NewField: TStringField;
  I: Integer;

begin
  if Query1.FieldDefs.Count = 0 then
    Query1.Open;

  Query1.Close;

  for I := 0 to Query1.FieldDefs.Count - 1 do
    Query1.FieldDefs[i].CreateField(Query1, nil, Query1.FieldDefs[i].Name);

  ShowMessage(Format('%d campo(s)', [Query1.FieldCount])); // seis campos

  NewField := TStringField.Create(Query1);
  NewField.FieldName := 'FullName';
  NewField.Size := 36;
  NewField.FieldKind := fkCalculated;
  NewField.DataSet := Query1;

  ShowMessage(Format('%d campo(s)', [Query1.FieldCount])); // siete campos

  Query1.Open;
end;

procedure TForm1.Query1CalcFields(DataSet: TDataSet);
begin
  DataSet['FullName'] := DataSet['LastName'] + ' ' + DataSet['FirstName'];
end;

Si los campos los añades (todos) manualmente, necesariamente debe darte la cuenta, sin importar el tipo de campo.

Agrego

Si además, añado esto a un segundo botón:

Código Delphi [-]
procedure TForm1.Button2Click(Sender: TObject);
var
  I: Integer;

begin
  for I := 0 to Query1.FieldCount - 1 do
    ShowMessage(Query1.Fields[i].DisplayName);
end;

funciona sn problemas.

// Saludos

Si roman, funciona correctamente. Ahora continuando con el debbug de todo el proceso, descubro que el error proviene de la siguiente funcion:

Código Delphi [-]
 
type
   TTipoCampo = (tcINTEGER, tcSTRING, tcDOUBLE, tcCURRENCY, tcBOOLEAN, tcDATE, tcMEMO);
 
function GetTipoCampoSQL(oQry : TZQuery; Index: Integer) : TTipoCampo;
var TipoField: TFieldDef;
begin
  TipoField := oQry.FieldDefs.Items[Index];
  case TipoField.DataType of
    ftUnknown:        result := tcSTRING;
    ftString:         result := tcSTRING;
    ftSmallint:       result := tcBOOLEAN;
    ftInteger:        result := tcINTEGER;
    ftWord:           result := tcDOUBLE;
    ftBoolean:        result := tcBOOLEAN;
    ftFloat:          result := tcDOUBLE;
    ftCurrency:       result := tcCURRENCY;
    ftBCD:            result := tcSTRING;
    ftDate:           result := tcDATE;
    ftTime:           result := tcDATE;
    ftDateTime:       result := tcDATE;
    ftBytes:          result := tcDOUBLE;
    ftVarBytes:       result := tcDOUBLE;
    ftAutoInc:        result := tcINTEGER;
    ftBlob:           result := tcMEMO;
    ftMemo:           result := tcMEMO;
    ftGraphic:        result := tcMEMO;
    ftFmtMemo:        result := tcMEMO;
    ftParadoxOle:     result := tcMEMO;
    ftDBaseOle:       result := tcMEMO;
    ftTypedBinary:    result := tcMEMO;
    ftCursor:         result := tcMEMO;
    ftFixedChar:      result := tcMEMO;
    ftWideString:     result := tcSTRING;
    ftLargeint:       result := tcINTEGER;
    ftADT:            result := tcINTEGER;
    ftArray:          result := tcSTRING;
    ftReference:      result := tcINTEGER;
    ftDataSet:        result := tcINTEGER;
    ftOraBlob:        result := tcSTRING;
    ftOraClob:        result := tcSTRING;
    ftVariant:        result := tcINTEGER;
    ftInterface:      result := tcINTEGER;
    ftIDispatch:      result := tcINTEGER;
    ftGuid:           result := tcSTRING;
    ftTimeStamp:      result := tcINTEGER;
    ftFMTBcd:         result := tcSTRING;
  end;
end;

Cuyo error es:

---------------------------
Debugger Exception Notification
---------------------------
Project Test.exe raised exception class EListError with message 'List index out of bounds (15)'. Process stopped. Use Step or Run to continue.
---------------------------
OK Help
---------------------------

Nota: la definición si o si la tengo que modificar con esa función puesto a que diversos campos deben ser re-adaptados a otro tipo de datos. Esto funcionó perfectamente hasta que puse un campo calculado.

Bueno, pero entonces el error no estaba donde nos habías dicho. Ahora tiene más lógica porque supongo que los campos calculados no entran en el arreglo FieldDefs (no lo he verificado). Quizá en la función GetTipoCampo podrías usar el arreglo Fields en lugar de FieldDefs.

// Saludos

SOLUCIONADO

En primera instancia el error estaba ahi. Luego de modificar la función acorde a tu idea, se me generó un error en la función.
Efectivamente los calculados no deben entrar en el arreglo FieldDefs, puesto a que probando no he podido acceder a esos campos. Lo que hice es utilizar el arreglo Fields como sugeriste y sanear asi la excepción, utilizando la propiedad Calculated.
Todo me ha vuelto a funcionar de maravillas permitiendome agregar cuanto campo calculado necesite.

Muchas gracias a todos.