Foros Club Delphi - convertir hex a Byte

Para la primera parte podría servirte este procedimiento:

Código Delphi [-]procedure CommaTextToStrs( AStrs: TStrings;const Value: string ;const AchDelim : Char );
var
 P, P1     : PChar;
 S         : string;
 chDelim   : char ;
begin
 chDelim := AchDelim ;
 AStrs.BeginUpdate;
 try
  AStrs.Clear;
  P := PChar(Value);
  while P^ in [#1..' '] do
   P := CharNext(P);
  while P^ <> #0 do
   begin
    if ( P^ = '"' ) then
     S := AnsiExtractQuotedStr(P, '"')
    else
     begin
      P1 := P;
      while (P^ > ' ') and ( P^ <> chDelim ) do
       P := CharNext(P);
      SetString(S, P1, P - P1);
     end;
    AStrs.Add(S);
    while P^ in [#1..' '] do
     P := CharNext(P);
    if P^ = chDelim then 
     repeat
      P := CharNext(P);
     until not (P^ in [#1..' ']);
    end;  // while
  finally
   AStrs.EndUpdate;
  end;
end;

Su uso sería el como sigue:

Código Delphi [-]var
Strs1: TStringList; // Donde estarán guardados tus HEX individuales
inStr: String;        // Tus HEX agrupados 0:10:8:0:E0:6:0:0:2:10:8:0:4:0:0:0

CommaTextToStrs( Strs1, inStr, ':' );

para lo segundo, supongo que con byte te refieres en decimales, esto es lo primero que encontré:

http://www.greatis.com/delphicb/tips...s-hex2dec.html

o para cambiar entre cualquier base este es un buen componente:

http://wenwen.soso.com/z/q156828058.htm

Código Delphi [-]

...
type
  TArrayOfByte= array of Byte;

procedure HexaToByte(Cadena: string; var Vec: TArrayOfByte);
var
  i,p: Integer;
  s: string;
begin
  if Cadena[1] = ':' then
    Delete(Cadena, 1, 1);
  if Cadena[Length(Cadena)] <> ':' then
    Cadena:= Cadena + ':';
  i:= 1;
  repeat
    p:= Pos(':', Cadena);
    s:= Copy(Cadena, 1, p-1);
    if p > 0 then
    begin
      SetLength(Vec, i+1);
      try
        Vec[i]:= StrToInt('$'+ s);
      except
        raise Exception.Create('Error, ( '+s+' ) no es un número hexadecimal');
      end;
      Inc(i);
      Delete(Cadena, 1, p);
    end;
  until p = 0;
end;
...

Código Delphi [-]

procedure TForm1.Button1Click(Sender: TObject);
var
  Vec: TArrayOfByte;
  i: Integer;
begin
  HexaToByte('01:02:03:04:0C:0A:0B:FF:40',Vec);
  (* Mostrar resultado en un Memo  *)
  Memo1.Clear;
  for i:= Low(Vec) to High(Vec) do
    Memo1.Lines.Add(IntToStr(Vec[i]))
end;

Código Delphi [-]

function TextToBuffer(Command: string): TBytes;
  var I: Integer;
      slBuffer: TStringList;
begin
 slBuffer := TStringList.Create;
 try
  slBuffer.Delimiter := ':';
  slBuffer.DelimitedText := Command;
  SetLength(Result, slBuffer.Count);
  for I := 0 to slBuffer.Count - 1 do
    Result[i] := StrToInt('$' + slBuffer[i]);
 finally
  slBuffer.Free;
 end;
end;