Comprobar llave en el Registro
 

Hola a todos.

La duda es como puedo averiguar si una determinada llave existe en el registro, osea por ejemplo si la llave existe me abra un mensaje diciendo que esta y si no pues no.

El caso que leer y escribir en registro se pero no consigo hacer eso con un If y else.

salu2

Hola KnoX_RuS.

Código Delphi [-]
...
uses Registry, StrUtils;

function ExistsKey(const ARootKey: HKEY; const AKey: string): Boolean;
begin
  Result:= True;
  with TRegistry.Create do
  try
    RootKey := ARootKey;
    if not OpenKey(AKey, False) then
      Result:= False;
  finally
    Free
  end
end;

Llamada de ejemplo:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
const
  Valor = '\Software\Microsoft\Windows\CurrentVersion';
begin
  Caption:= IfThen(ExistsKey(HKEY_LOCAL_MACHINE, Valor), 'Existe', 'No existe');
end;

Un saludo.

Hola KnoX, creo que ya me conoces..

Para hacerlo, puedes usar KeyExists, declarando previamente el unit registry en Uses y la clase TRegistry.

La opción de nuestro amigo ecfisa es completamente válida también.

Un saludo!

Hey que hay metal, gracias a los 2 consegui solucionarlo con buestra ayuda.


salu2

Bueno lo quise hacer con keyExist y no me salio.

Lo hice asi:
Donde los MessageBoxA iria otro code eso lo puse para comprovar si funciona.

salu2 y gracias

Hola.

Código Delphi [-]
...
uses Registry;
...
begin
 with TRegistry.Create do
   if KeyExists('Software\Microsoft\Windows\CurrentVersion\Run\Sidebar') then
     MessageBoxA(0,'LLave encontrada!','Bien', 64)
   else
     MessageBoxA(0,'LLave no encontrada!','Mal', 64)
end;
...

Saludos.

Bueno me da error en el penultimo end;

Y me hace falta mirarlo en HKEY_CURRENT_USER osea siempre me dice que no se encontro la llave cuando borro ese penultimo end;

salu2 y gracias por la ayuda que me estas dando.

Hola.

Disculpá, lo hice de memoria y me olvidé de RootKey... :o:)

Código Delphi [-]
begin
  with TRegistry.Create do
  begin
    RootKey:= HKEY_CURRENT_USER;
    if KeyExists('Software\Microsoft\Windows\CurrentVersion\Run\Sidebar') then
      MessageBoxA(0,'LLave encontrada!','Bien', 64)
    else
      MessageBoxA(0,'LLave no encontrada!','Mal', 64);
  end;
end;

Saludos.

Humm el code parece estar bien del todo pero me sige dando llave no encontrada cuando esa llave si existe en cualquier windows 7.

saludos.

Hola.

La verdad no puedo decir nada por que no tengo Windows 7, pero hice esta prueba que funciona sin problemas:

Código Delphi [-]
uses Registry;

procedure TForm1.Button1Click(Sender: TObject);
const
  AKEY: array[0..1] of string=('Software\Microsoft\Windows\CurrentVersion', // existente
                               'Software\Microsoft\Windows\CurrentVerXXXX'); // inexistente
var
  v: Integer;
  r: TRegistry;
begin
  Randomize;
  v:= Random(2);
  with TRegistry.Create do
  try
    RootKey:= HKEY_CURRENT_USER;
    if KeyExists(AKEY[v]) then
      MessageBoxA(0,PChar(AKEY[v]+': Encontrada'),'Bien', 64)
    else
      MessageBoxA(0,PChar(AKEY[v]+': No existe'),'Mal', 64);
  finally
    Free;
  end;
end;

Un saludo.

Estuve viendo y si pongo solo direccion de carpeta '\Software\Microsoft\Windows\CurrentVersion\Run\' si dice que existe pero las llaves de las carpetas no las comprueva osea si pongo '\Software\Microsoft\Windows\CurrentVersion\Run\Sidebar' dice que no existe.


saludos.

Hola.

Ahora veo..., lo que sucede es que lo que estas buscando no es una clave es un valor.

Entonces en tu caso sería:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
begin
  with TRegistry.Create do
  try
    RootKey:= HKEY_CURRENT_USER;
    if OpenKey('Software\Microsoft\Windows\CurrentVersion\Run\', False) then
      if ValueExists('Sidebar') then
        ShowMessage('Valor existente')
      else
        ShowMessage('Valor inexistente');
  finally
    Free;
  end;
end;

Saludos.

Ostia es verda, perdoname por confundirte ahora sique si jeje.

Muchas gracias y saludos! :D