Foros Club Delphi

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)
-   Lazarus, FreePascal, Kylix, etc. (https://www.clubdelphi.com/foros/forumdisplay.php?f=14)
-   -   tipos enumerados de ejecutable delphi a dll lazarus (https://www.clubdelphi.com/foros/showthread.php?t=92144)

engranaje 07-08-2017 14:48:21

tipos enumerados de ejecutable delphi a dll lazarus
 
Saludos a todos

Estoy desarrollando una dll en lazarus 1.6.4 para utilizar desde una aplicación también desarrollada por mí en delphi 5. Tengo los fuentes de ambas herramientas.
intentando simplificar al máximo este es el código que compilo en delphi 5:
Código Delphi [-]
unit UDllColor;
interface

type
TColor = (
    oBlack,    
    oWhite,    
    oRed          
  );
  
Procedure PintarColor(aColor:tcolor); external 'color.dll';

implementation
end.

y este el código de la dll en lazarus:
Código Delphi [-]
library color;

{$mode objfpc}{$H+}

uses

 Interfaces, Forms,controls, Dialogs, Classes,sysutils;

type

TColor = (
    oBlack,    
    oWhite,    
    oRed     
    );

Procedure PintarColor(aColor:TColor); export;
begin
  // Mostramos el color elegido
  QuestionDlg('Color' ,'indice del color seleccionado ->'+inttostr(integer(acolor)), mtCustom,     
  [mrCancel,'Cancelar',mrRetry,'Reintentar'],0);
end; 

exports PintarColor;

{$R *.res}

begin
    Application.Initialize;  // Es necesario para poder llama a QuestionDlg;
end.

El caso es que cuando desde delphi llamo a PintarColor pasandole oBlack como parámetro (o sea el primer valor del tipo) todo funciona como espero, sin embargo cuando llamo a PintarColor pasando cualquier otro parámetro, la dll en lazarus en lugar de recibir el número esperado parece recibir otro o por lo menos pinta otro en el dialogo que muestro. Es decir si hago esto en delphi:
Código Delphi [-]
  if integer(oWhite) = 1 then
     PintarColor(oWhite);

El dialogo que pinta la dll es ' indice del color seleccionado -> 1378817 '.

Como pista puedo decir que que si modifico la función del lado de delphi para que acepte enteros y le paso un 1 la dll por supuesto muestra ' indice del color seleccionado -> 1 '

Alguien tienen una pista que me pueda inidicar lo que me puede estar pasando?

Entiendo que tiene fácil solución pasando a utilizar enteros, pero lo cierto que este mismo sistema lo he utilizado con versiones anteriores de lazarus y nunca tuve este problema.

duilioisola 07-08-2017 15:37:30

En la librería Graphics de Delphi se definen los valores para los colores.
Quizás en Lazarus es distinto, ya que estos valores suelen ser internos.
Otra opción es que estés enviando el índice del color y no el color propiamente dicho.

En Delphi 6 he encontrado esta definición en Graphics.pas:

Código Delphi [-]
  clBlack = TColor($000000);
  clMaroon = TColor($000080);
  clGreen = TColor($008000);
  clOlive = TColor($008080);
  clNavy = TColor($800000);
  clPurple = TColor($800080);
  clTeal = TColor($808000);
  clGray = TColor($808080);
  clSilver = TColor($C0C0C0);
  clRed = TColor($0000FF);
  clLime = TColor($00FF00);
  clYellow = TColor($00FFFF);
  clBlue = TColor($FF0000);
  clFuchsia = TColor($FF00FF);
  clAqua = TColor($FFFF00);
  clLtGray = TColor($C0C0C0);
  clDkGray = TColor($808080);
  clWhite = TColor($FFFFFF);
  StandardColorsCount = 16;

engranaje 07-08-2017 15:39:30

Por si pudiera servir de pista he encontrado un comportamiento curiosos en un formulario sencillo con 2 botones de prueba utilizando la dll como expliqué en el punto anterior:

Código Delphi [-]

unit Principal;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls,UDllColor;

type
  TForm1 = class(TForm)
    btnPrueba: TButton;
    btnPrueba2: TButton;
    procedure btnPruebaClick(Sender: TObject);
    procedure btnPrueba2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.btnPruebaClick(Sender: TObject);
begin

   if integer(oWhite) = 1 then
      PintarColor(oWhite);

   if integer(oRed) = 2 then
       PintarColor(oRed);

end;

procedure TForm1.btnPrueba2Click(Sender: TObject);
begin
    if integer(oRed) = 2 then
       PintarColor(oRed);
end;

Si en el onclick del boton solo se hace una llamada a pintarcolor la dll muestra un valor distinto tanto si se le pasa oWhite como oRed, sin embargo si se llama dos veces seguidas a PintarColor, la dll solo muestra un valor distinto en la primera llamada, la segunda llamada devuelve el valor esperado. Sigo peleandome con esto pero confieso que de momento me veo perdido.

engranaje 07-08-2017 15:47:54

Lo siento por error he creado 2 hilos identicos, habría que unificarlos si se puediera.

En cuanto al color, es solo un ejemplo, podia haber puesto TdiasSemana y poner los valores de lunes a domingo. Igual lleva a confusión el nombre elegido. No se trata de un problema con los colores sino con la diferencia entre el valor que se pasa como parametro desde delphi y el que le llega a la dll en lazarus.

duilioisola 07-08-2017 15:52:58

Ahora veo que no estás utilizando la librería Graphics.
Supongo que lo que muestras es solo codigo de ejemplo.
Asegúrate de que no utilizas la unidad Graphics o renombrea
Código Delphi [-]
unit UDllColor;
interface

type
TMiColor = (
    oBlack,    
    oWhite,    
    oRed,          
  );
  
Procedure PintarColor(aColor:TMiColor); external 'color.dll';

implementation
end.

engranaje 07-08-2017 20:49:38

Finalmente he enconrado mi problema. La solución es declarar el tipo en la dll con la directiva de compilador {$PACKENUM 1}
así ;
Código Delphi [-]
 type
 {$PACKENUM 1}      
  TColor = (     oBlack,         
                  oWhite,        
                  oRed             );

De este modo forzamos e número máximo de bytes de espacio a usar pra los tipos enumerados. El valor por defecto es mas alto y como resultado sucede lo que he planteado en esta tarea. Siento la confusión debido a llamar al tipo de ejemplo Tcolor.


La franja horaria es GMT +2. Ahora son las 18:26:05.

Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi