Foros Club Delphi

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)
-   Trucos (https://www.clubdelphi.com/foros/forumdisplay.php?f=52)
-   -   Garantizar de 1..N Instancias Activas en Memoria por Aplicación para Delphi y Lazarus (https://www.clubdelphi.com/foros/showthread.php?t=88020)

nlsgarcia 02-04-2015 22:49:01

Garantizar de 1..N Instancias Activas en Memoria por Aplicación para Delphi y Lazarus
 
Club Delphi,

Revisen el siguiente código en Delphi:
Código Delphi [-]
unit SingleInstance;

interface

implementation

uses SysUtils, Forms, Dialogs, Windows;

const
   MutexName : String = 'Test_SingleInstance_Delphi';

var
   Mutex : THandle;

procedure CheckInstance;
begin

   if OpenMutex(MUTEX_MODIFY_STATE,false,PChar(MutexName)) = 0 then
   begin
      Mutex := CreateMutex(nil,False,PChar(MutexName));
      WaitForSingleObject(Mutex,INFINITE);
   end
   else
   begin
      MessageDlg('Existe una Instancia de la Aplicación Activa en Memoria',mtInformation,[mbOk],0);
      Application.Terminate;
   end;

end;

procedure FreeInstance;
begin
   if Mutex <> 0 then
   begin
      ReleaseMutex(Mutex);
      CloseHandle(Mutex);
   end
end;

initialization
  CheckInstance;

finalization
  FreeInstance;

end.
El código anterior en Delphi 7 Sobre Windows 7 Professional x32, permite tener una sola instancia activa en memoria de una aplicación.

Revisen el siguiente código en Lazarus:
Código Delphi [-]
unit SingleInstance;

{$mode objfpc}{$H+}

interface

implementation

uses SysUtils, Forms, Dialogs, Windows;

const
   MutexName : String = 'Test_SingleInstance_Lazarus';

var
   Mutex : THandle;

procedure CheckInstance;
begin

   if OpenMutex(MUTEX_MODIFY_STATE,false,PChar(MutexName)) = 0 then
   begin
      Mutex := CreateMutex(nil,False,PChar(MutexName));
      WaitForSingleObject(Mutex,INFINITE);
   end
   else
   begin
      MessageDlg('Existe una Instancia de la Aplicación Activa en Memoria',mtInformation,[mbOk],0);
      Halt;
   end;

end;

procedure FreeInstance;
begin
   if Mutex <> 0 then
   begin
      ReleaseMutex(Mutex);
      CloseHandle(Mutex);
   end
end;

initialization
  CheckInstance;

finalization
  FreeInstance;

end.
El código anterior en Lazarus Versión #:1.2.6 FPC Version 2.6.4 bajo Windows 7 Professional x32 , permite tener una sola instancia activa en memoria de una aplicación.

Nota:

1- Para tener una sola instancia de una aplicación tanto en Delphi como en Lazarus, solo debe agregarse la unidad SingleInstance al proyecto Delphi/Lazarus, la unidad ejecutara de forma automática el procedimiento CheckInstance al inicializarce y el procedimiento FreeMutex al finalizar.

2- Básicamente el código de Delphi y Lazarus es el mismo, solo varía en la forma de finalizar la aplicación.

3- MutexName, es el nombre de la aplicación para efectos de exclusión el cual debe ser único para las funciones de Mutex.

Revisen esta información:
Espero sea útil :)

Nelson.

Casimiro Notevi 03-04-2015 03:33:21

^\||/^\||/^\||/

nlsgarcia 04-04-2015 20:02:37

Club Delphi,

Revisen este código:
Código Delphi [-]
unit SingleInstance;

interface

implementation

uses SysUtils, Forms, Windows, Dialogs;

const
  SemaphoreName : String = 'Semaphore_SingleInstance_Delphi/Lazarus';
  NumberInstance : Integer = 3;

var
  Semaphore: THandle;
  State : Boolean;
  MsgApp : String;

procedure CheckInstance;
begin

   Semaphore := CreateSemaphore(nil,NumberInstance,NumberInstance,PChar(SemaphoreName));
   if OpenSemaphore(EVENT_MODIFY_STATE,false,PChar(SemaphoreName)) <> 0 then
   begin
      if WaitForSingleObject(Semaphore,0) <> WAIT_OBJECT_0 then
      begin
         MsgApp := Format('El Número Máximo de Instancias de la Aplicación es %d',[NumberInstance]);
         MessageDlg(MsgApp,mtInformation,[mbOk],0);
         State := False;
         Halt;
      end
      else
         State := True;
   end;

end;

procedure FreeInstance;
begin
   if Semaphore <> 0 then
   begin
      if State then ReleaseSemaphore(Semaphore,1,nil);
      CloseHandle(Semaphore);
   end
end;

initialization
  CheckInstance;

finalization
  FreeInstance;

end.
El código anterior en Delphi XE7 Sobre Windows 7 Professional x32, permite por medio de un Semaphore definir el número de instancias activas en memoria de una aplicación en función de los requerimientos de la misma, según se muestra en la siguiente imagen con un máximo de 3 instancias permitidas en este caso:



Nota
:

1- Para controlar el número de instancias de una aplicación tanto en Delphi como en Lazarus, solo debe agregarse la unidad SingleInstance al proyecto Delphi/Lazarus, la unidad ejecutara de forma automática el procedimiento CheckInstance al inicializarce y el procedimiento FreeMutex al finalizar.

2- El código propuesto funciona correctamente en Delphi 7 y Lazarus Versión #:1.2.6 FPC Version 2.6.4 bajo Windows 7 Professional x32.

3- SemaphoreName, es el nombre de la aplicación para efectos de exclusión el cual debe ser único para las funciones de Semaphore.

4- NumberInstance, es el número de instancias máximas permitidas para una aplicación en función de sus requerimientos de performance y/o recursos.

5- Este código es una ampliación del código del Msg #1, ambos son equivalentes funcionalmente si el número de instancias (NumberInstance) es 1 .

Revisen esta información:
Espero sea útil :)

Nelson.

nlsgarcia 05-04-2015 05:30:42

Club Delphi,

Cita:

Empezado por nlsgarcia
...MutexName, es el nombre de la aplicación para efectos de exclusión el cual debe ser único para las funciones de Mutex...
...SemaphoreName, es el nombre de la aplicación para efectos de exclusión el cual debe ser único para las funciones de Semaphore...

:rolleyes:

Revisen este código:
Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ClipBrd,  IdGlobal, IdHash, IdHashMessageDigest;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function GetGUID : String;
var
   GUID : TGuid;
   Hash, IDHash : String;
   DateTimeID : String;

begin
   if CreateGuid(GUID) = S_OK then
   begin
      Clipboard.AsText := GuidToString(GUID);
      Result := Clipboard.AsText;
   end
   else
   begin
      with TIdHashMessageDigest5.Create do
      try
         DateTimeToString(DateTimeID, '{yyyy/mm/dd_hh:nn:ss.zzz}', Now);
         Hash := TIdHash128.AsHex(HashValue(DateTimeID));
         IDHash := '{' +
                   Copy(Hash,1,8) +
                   '-' +
                   Copy(Hash,9,4) +
                   '-' +
                   Copy(Hash,13,4) +
                   '-' +
                   Copy(Hash,17,4) +
                   '-' +
                   Copy(Hash,21,12) +
                   '}';
         Clipboard.AsText := IDHash;
         Result := Clipboard.AsText;
      finally
         Free;
      end;
   end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
   MessageDlg(GetGUID,mtInformation,[mbOk],0);
end;

end.
El código anterior en Delphi 7 sobre Windows 7 Professional x32, permite crear un Globally unique identifier, que identifique de forma unívoca una aplicación para la creación de un Mutex o un Semaphore, como se muestra en la siguiente imagen:



Nota:

1- Este código es un complemento para el código de los Msg #1 y Msg #3.

2- El Globally unique identifier (GUID) generado, esta disponible por medio del Clipboard.

Espero sea útil :)

Nelson.

Ñuño Martínez 27-07-2015 18:32:55

Una preguntita. ¿Por qué para finalizar la aplicación se usa "Application.Terminate" en Delphi y "Halt" en Lazarus? Ya sé que la implementación de TApplication es diferente en VCL que en LCL, pero aun así, ¿no funcionaría el "Application.Terminate" en Lazarus?

Ya sé, podría hacer yo la prueba...

nlsgarcia 28-07-2015 02:42:22

Guillermo,

Cita:

Empezado por Ñuño Martínez
...¿Por qué para finalizar la aplicación se usa "Application.Terminate" en Delphi y "Halt" en Lazarus?...

:rolleyes:

Revisa esta información:



Tomado de : TCustomApplication.Terminate

Según entiendo por las pruebas realizadas, en Lazarus no hay una verificación del método DoRun si Application.Terminate es ejecutado desde la sección de Initialization, por lo cual es necesario usar Halt en este caso.

Saludos,

Nelson.

Ñuño Martínez 11-08-2015 11:26:26

Gracias Nelson. :)

TiammatMX 16-06-2018 01:31:35

Curiosidad..., ¿y funcionará ésto en Delphi Berlin?:confused::confused:

Casimiro Notevi 16-06-2018 10:32:46

Tiene que funcionar :)


La franja horaria es GMT +2. Ahora son las 10:29:50.

Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi