mantener un panel siempre al fondo en mdi aplicación
 

Hola amigos, gusto como siempre,

tengo una aplicación MDI con un panel de fondo de contenedor de otros controles,
como hago para mantener el panel siempre al fondo de los demas formularios??
tengo esto:

Código Delphi [-]
procedure TPanel.Loaded;
begin
  inherited;
  Windows.SetParent(Handle, MainForm.ClientHandle);
end;
 
procedure TPanel.WMWindowPosChanging(var Message: TWMWindowPosChanging);
begin
 inherited;
 Message.WindowPos^.hwndInsertAfter := HWND_BOTTOM;
end;

Aparentemente con esto bastaría, pero cuando cambio de formularios mediante el menu de sistema en la opción "siguiente", el panel se sobreposiciona sobre el formulario que cambie, podria ser manejando el mensaje que llama al siguiente formulario, pero mmm nose, me gustaria si con el mensaje wm_windowposchanging del panel bastaria

Gracias

_CALI,

Revisa este código:

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
begin
   SetWindowPos(Self.Handle,HWND_BOTTOM, 0, 0, 0, 0, SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE);
end;

El código anterior mantiene el formulario en la última posición del orden Z (Posición más baja), esto garantiza que nunca se superponga a otro formulario.

Revisa esta información:
Espero sea útil :)

Nelson.

Hola _CALI

Cuando diseñaron las aplicaciones Multiple Document Interface, la idea no fué que el MDIForm fuera contenedor de otros controles que MDIChilds, ToolBars o controles que posean la propiedad Align.

Un MDIChild se ubicará dentro del área cliente libre del MDIForm. Esta área consiste en todo el espacio no ocupado por controles alineados a alguno de los cuatro bordes (alBottom, alTop, alRight, alLeft).
Según entiendo, deseas que el TPanel quede por debajo de los MDIChilds, y por lo te mencioné arriba, no veo el modo de hacer lo que buscas con un control no alineado en un entorno MDI.
La solución más sencilla entonces, es darle alguna de esas alineaciones al TPanel y de ese modo los MDIChilds no serán solapados por él.

Otra alternativa que se me ocurre es ocultar el TPanel mientras exista al menos un MDIChild abierto y visualizarlo si no lo hay. Para evaluar esto, habrá que disparar y capturar algún evento cuando cualquiera de ellos se cierra.

Te adjunto un ejemplo que consta de un MDIForm y tres MDIChils que se comportan de este modo por que el código me parece un poco extenso para ser claro en un mensaje.

Saludos. :)

Gracias por tu colaboración ecfisa y a los demás tambien,
Talvez no fui muy claro, pero lo que quiero es que el panel se muestre siempre el ultimo sitio del Z orden, asi hayan formularios hijos abiertos
Aquí les dejo la solucion que escribi:

la definición del panel esta en el formulario padre,
primero que nada hay que colocar un panel en el formulario padre y luego sobre el panel cualquier control

Código Delphi [-]
type
  TPanel = class(Vcl.ExtCtrls.TPanel)
  protected
   procedure Loaded; override;
   procedure WMWindowPosChanging(var Msg: TWMWindowPosChanging);
   message WM_WINDOWPOSCHANGING;
 end;
 
type
 TMain = class(TForm)
  ...
 
var
  Main: TMain;
 
implementation
 
procedure TPanel.Loaded;
begin
  inherited;
  Windows.SetParent(Handle, Main.ClientHandle);
end;
procedure TPanel.WMWindowPosChanging(var Msg: TWMWindowPosChanging);
begin
  if (Msg.WindowPos^.flags and SWP_NOZORDER) = 0 then
      Msg.WindowPos^.hwndInsertAfter := HWND_BOTTOM;
 inherited;
end;

luego en el formulario hijo...

Código Delphi [-]
const
 WM_GETACTIVEFORM = WM_USER + 100;
 
type
 TChild = class(TForm)
...
private
procedure WMWindowPosChanging(var Msg: TWMWindowPosChanging);
   message WM_WINDOWPOSCHANGING;
procedure WMGetActiveForm(var Msg: TMessage); 
   message WM_GETACTIVEFORM;

var
  Child: TChild;
 
implementation
 
procedure TChild.WMGetActiveForm(var Msg: TMessage);
var i: integer;
begin
 for i := 0 to MDIChildCount - 1 do
  begin
   if MDIChildren[i].WindowState <> wsMinimized then
      begin
      MDIChildren[i].BringToFront;
      Break;
      end;
  end;
end;
 
procedure TChild.WMWindowPosChanging(var Msg: TWMWindowPosChanging);
 begin 
 
       if Msg.windowpos^.hwndInsertAfter <> HWND_TOP  then
          begin
          Msg.windowpos^.hwndInsertAfter := HWND_TOP;
          PostMessage(Handle, WM_GETACTIVEFORM, 0, 0);
          end;

inherited;
end;

Manejando los mensajes WM_WINDOWPOSCHANGING del panel y el formulario hijo, se consige que el panel este siempre al fondo y otra cosa mas..

se dieron cuenta que cuando minimizan un formulario, este se queda como ActiveMDIChild?,
con un mensaje de ususario lo que hace es establecer el ActiveMDIChild del ultimo formulario activo al minimizarlo.


Saludos y Gracias denuevo !!!

_CALI,

Esta aplicación implementa tu requerimiento:



Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Menus, ExtCtrls;

type
  TForm1 = class(TForm)
    MainMenu1: TMainMenu;
    Forms1: TMenuItem;
    Form21: TMenuItem;
    Form31: TMenuItem;
    Form41: TMenuItem;
    Exit1: TMenuItem;
    Panel1: TPanel;
    procedure Form21Click(Sender: TObject);
    procedure Form31Click(Sender: TObject);
    procedure Form41Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Exit1Click(Sender: TObject);
  private

    // Control de Orden Z del TPanel

    FPanelWndProc: TWndMethod;
    procedure PanelWndProc(var M: TMessage);

  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

Uses Unit2, Unit3, Unit4;

{$R *.dfm}

// Inicio del Código de Control del Orden Z del TPanel

procedure TForm1.FormCreate(Sender: TObject);
begin
  Windows.SetParent(Panel1.Handle, ClientHandle);
  // Sobreescribe el Panel1 WindowProc
  FPanelWndProc := Panel1.WindowProc;
  Panel1.WindowProc := PanelWndProc;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  // Restaura Panel1 WindowProc
  Panel1.WindowProc := FPanelWndProc;
end;

procedure TForm1.PanelWndProc(var M: TMessage);
var
  P: ^WINDOWPOS;
begin
  if M.Msg = WM_WINDOWPOSCHANGING then
  begin
    P := Pointer(M.LParam);
    // Siempre coloca Panel1 en el Orden Z Bottom
    P.hwndInsertAfter := HWND_BOTTOM;
  end;
  FPanelWndProc(M);
end;

// Fin del Código de Control del Orden Z del TPanel

procedure TForm1.Form21Click(Sender: TObject);
begin
   Form2.Show;
end;

procedure TForm1.Form31Click(Sender: TObject);
begin
   Form3.Show;
end;

procedure TForm1.Form41Click(Sender: TObject);
begin
   Form4.Show;
end;

procedure TForm1.Exit1Click(Sender: TObject);
begin
   Application.Terminate;
end;

end.

El código anterior mantiene el TPanel en el Orden Z mas inferior, permitiendo que el TPanel siempre este visible y nunca se superponga a un MDIChild. Todo el código de control esta en el MDIForm, no hace falta colocar ningún código adicional en los MDIChild. Quizás esta solución pueda ser adaptada a tu proyecto.

La aplicación implementada esta en el siguiente link: http://terawiki.clubdelphi.com/Delph...+MDI+Forms.rar

Espero sea útil :)

Nelson.

...Claro, pero aver dibuja el panel del porte del formulario padre y luego minimiza los formularios hijos y comprenderás mejor lo que digo.