¿Validar ShellExecute con Try?
 

Ya se que mi pregunta será un poco tonta pero quiero que mi programa abra una pag web en el exlorador (eso funciona bien), pero quiero que saber si no lo ha conseguido abrir. He probado con:

Código Delphi [-]
try
  ShellExecute(Handle, 'open', 'descargar.htm', nil, nil, SW_SHOW);
except
  sel := MessageDlg('No se ha encontrado el archivo de recuperación, reinstala por favor', mtCustom, [mbOk], 0);
  close;
end;

Hola pokoexperto1.

La función ShellExecute devuelve un valor, que es mayor o igual a 32 cuando se ejecuta con éxito o, de modo contrario, representa el tipo de error.

Podrías intentar algo similar a este ejemplo:

Código Delphi [-]
var
  Msg: string;
  Err: LongWord;
begin
  Err := ShellExecute(Handle, 'open', 'descargar.htm', nil, nil, SW_SHOW);
  if Err <= 32 then
  begin
    case Err of
       2: Msg := 'File not found';
       3: Msg := 'Path not found';
       5: Msg := 'Access denied';
       8: Msg := 'Out of memory';
      26: Msg := 'Cannot share an open file';
      27: Msg := 'File association information not complete';
      28: Msg := 'DDE operation timed out';
      29: Msg := 'DDE operation failed';
      30: Msg := 'DDE operation is busy';
      31: Msg := 'File association not available';
      else
        Msg := 'Unspecified Error';
    end;
    MessageBox(Handle ,PChar(Msg), '', MB_ICONERROR + MB_OK);
  end;

Saludos :)

pokexperto1,

:rolleyes:

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ShellAPI;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
   NameApp : PChar;
   ErrMsg : Integer;

begin

   NameApp := 'C:\Windows\System32\xNotepad.exe';

   ErrMsg := ShellExecute(Handle, nil, NameApp, nil, nil, SW_SHOW);

   if (ErrMsg <= 32) then
      raise Exception.CreateFmt('ShellExecute Error %d : %s',[GetLastError,SysErrorMessage(GetLastError)]);

end;

end.

El código anterior en Delphi 7 sobre Windows 7 Professional x32, Levanta una excepción si la función ShellExecute devuelve un código de error, como se muestra en la siguiente imagen:



Revisa esta información:
Espero sea útil :)

Nelson.

Gracias :D
 

Gracias a todo al final ya esta solucionado.
Por si a alguien le interesa el codigo:D:

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
begin
  if fileexists(directorio + 'ini.ini') then
  begin
  cargarinis;
  end
  else
  begin
    Errorinicio();
  end;
  directorio := getcurrentdir;
  try
    form2.fondo1.Picture.LoadFromFile(directorio + 'fondo1.jpg');
    form2.fondo2.Picture.LoadFromFile(directorio + 'fondo2.jpg');
    form2.platoentero.Picture.LoadFromFile(directorio + 'plato_entero.png');
    form2.platoroto.Picture.LoadFromFile(directorio + 'plato_roto.png');
  except
    Errorinicio();
  end;
end;

procedure TForm1.Errorinicio();
var
  sel: integer;
  error: integer;
begin
  sel := MessageDlg
    ('Parece ser que no tienes los archivos necesarios para el juego, ¿Quieres que lo solucione?',
    mtError, mbOKCancel, 0);
  if sel = 1 then
  begin
    sel := MessageDlg('Se va a abrir el navegador. ¿Proceder?...', mtCustom,
      mbOKCancel, 0);
    if sel = 1 then
      error := ShellExecute(Handle, 'open', 'descargar.htm', nil, nil, SW_SHOW);
      if (error <= 32) then
        sel := MessageDlg
          ('No se ha encontrado el archivo de recuperación, reinstala el juego por favor',
          mtCustom, [mbOk], 0);
      application.Terminate;
    end
  else
  begin
    sel := MessageDlg('El juego se va a cerrar', mtCustom, [mbOk], 0);
    application.Terminate;
  end;
end;