Foros Club Delphi

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)
-   Varios (https://www.clubdelphi.com/foros/forumdisplay.php?f=11)
-   -   Error al salir de un modal (https://www.clubdelphi.com/foros/showthread.php?t=93735)

DarthGomis 06-02-2019 02:20:05

Error al salir de un modal
 
2 Archivos Adjunto(s)
Buenas

En resumen el problema que me ha surgido es que al salir de un modal, me salta un error y no se por qué.

Vamos al meollo del asunto, estoy realizando una app y en un momento dado necesito crear un modal para editar el contenido de un memo.

Archivo Adjunto 3723

El problema es que al darle a Ok me salta este error.

Archivo Adjunto 3724

He estado buscando el por qué y no encuentro ninguna solución, el código que uso para salir del modal es este

Código Delphi [-]
procedure TForm2.Button1Click(Sender: TObject);
begin
  ModalResult := mrOk;
end;

Y el boton que activa el modal y procesa la información es este otro

Código Delphi [-]
procedure TForm1.Button3Click(Sender: TObject);
var
  nameData:string;
  numberData:integer;
  dateData:TDateTime;
begin
  with TForm2.Create(self) do
    try
      lineNumber := SendMessage(Memo1.Handle, EM_LINEFROMCHAR, Memo1.Selstart, 0);
      ShowModal;

      if Form2.ShowModal = mrOk then
      begin
        try
          nameData := Form2.Edit1.Text;
          numberData := StrToInt(Form2.Edit2.Text);
          dateData := StrToDate(Form2.Edit3.Text);
          Memo1.Lines[lineNumber] := ('N:'+nameData+
                ';D:'+IntToStr(numberData)+
                ';F:'+DateToStr(dateData));
        except
        ShowMessage('Wrong Data: Please insert correct values');
        end;
      end;
    finally
      Free;
    end;
end;

Igual es una tonteria pero estoy aprendiendo en Delphi y hay cosas que no entiendo muy bien.

Gracias de antemano. Si se necesita más información avisad y os la proporciono.

Al González 06-02-2019 04:01:16

Cita:

Empezado por DarthGomis (Mensaje 530561)
Si se necesita más información avisad y os la proporciono.

Hola.

De entrada no se ve el lugar donde le asignas a la variable Form2 la instancia de objeto creada con la expresión "TForm2.Create(self)". Por cierto, evita en todo lo posible el uso de With (se convirtió en mala práctica conforme creció la sintaxis de Object Pascal y la disponibilidad de recursos de biblioteca).

Si el formulario modal se muestra, quiere decir que en algún punto de tu código, probablemente en el evento OnCreate o algún otro de TForm2, estás realizando la asignación de la nueva instancia de formulario a la variable Form2. Y, por la misma lógica, es probable que al cierre del formulario tengas indicado que éste se destruya. De tal suerte que la sentencia "nameData := Form2.Edit1.Text;" genera la excepción que nos muestras.

Puede que Form2 siga apuntando al lugar de memoria que tenía la instancia, pero, por la destrucción, Edit1 se ha puesto en Nil (si no mal recuerdo, la liberación nativa de un derivado de TForm pone en blanco los campos componentes published). Eso explicaría porque la excepción AV es una lectura de la dirección de memoria 00000000, dado que la propiedad Text de la clase TEdit se lee mediante un método virtual; y, siempre que se va a realizar una llamada a un método virtual, Delphi necesita determinar la clase del objeto, cuyo identificador (puntero) se guarda en los primeros bytes de cada instancia. Ya que el objeto Edit1 es Nil, dichos bytes vendrían a ser, erróneamente, los primeros de la memoria RAM, los cuales son inaccesibles para las aplicaciones.

Todo lo anterior es una mera hipótesis, a falta de más información. Pero puede llevarnos a la respuesta de lo que está pasando de aquel lado de mi monitor y que sólo tú puedes ver y compartirnos. Así que te toca mover...:)

Al González.

Neftali [Germán.Estévez] 06-02-2019 11:12:00

Tal como comenta [Al], el problema es que cuando intentas acceder a la variable Form2 no está asignada.
Te explico cómo hemos llegado a esa conclusión (y cómo puedes llegar tú) para que la próxima vez sepas encontrar un error similar.

Coloca un Breakpoint en el inicio del procedimiento o en una línea donde el programa llega sin error.
Colócate encima desde el editor y pulsa F5, para crear un breakpoint (aparecerá un punto rojo en la línea).



Ahora ejecuta el programa con F9 para hacerlo desde el IDE.



Cuando llegue a ese punto el programa se parará. A partir de ese punto puedes seguir ejecutando línea a línea con F8.
Habrá un momento (en una línea concreta) que te aparecerá el error. Una vez sepas la línea del error, ya es cuestión de centrarse en ella.

Si lo ves te será más fácil.
La primera ejecución sirve para detectar la línea del error, en la segunda paramos en ese punto y revisamos.
Al final del video verás que la variable del Form está a nil, cosa que significa que no está asignada, y por lo tanto te dará error.



Neftali [Germán.Estévez] 06-02-2019 11:15:10

Yo siguiendo el consejo de [Al] de no usar el with; Dejaría el código así (cambiando lo mínimo). Revísalo y s tienes alguna duda pregunta.


Código Delphi [-]
begin
    Form3 := TForm3.Create(self);
    try
      lineNumber := SendMessage(Memo1.Handle, EM_LINEFROMCHAR, Memo1.Selstart, 0);
      if Form3.ShowModal = mrOk then
      begin
        try
          nameData := Form3.Edit1.Text;
          numberData := StrToInt(Form3.Edit2.Text);
          dateData := StrToDate(Form3.Edit3.Text);
          Memo1.Lines[lineNumber] := ('N:'+nameData+
                ';D:'+IntToStr(numberData)+
                ';F:'+DateToStr(dateData));
        except
          ShowMessage('Wrong Data: Please insert correct values');
        end;
      end;
    finally
      Form3.Free;
    end;
end;

DarthGomis 06-02-2019 14:38:09

Muchas gracias a todos, poco a poco voy aprendiendo cosas nuevas.

El código ya funciona

Un saludo.

Al González 06-02-2019 20:06:18

Ahora que reviso nuevamente el código de DarthGomis, caigo en la cuenta de que él estaba llamando dos veces el método ShowModal. La primera vez con la instancia recién creada (que debido al With no reparé en ella) y la segunda vez con la variable Form2.

Como ha mostrado Germán, la excepción es elevada por la expresión Form2.ShowModal (y no la que mal deduje antes, Form2.Edit1.Text). Y es que ShowModal sí es un método virtual (acabo de revisar y TControl.GetText no :o).
Código Delphi [-]
unit Vcl.Forms;
//...
  TCustomForm = class(TScrollingWinControl)
    //...
    function ShowModal: Integer; virtual;
Puede servir como tip: Básicamente, cada vez que obtenemos en Delphi una excepción Access Violation con un mensaje de texto conteniendo la leyenda Read of address 00000000, es bastante probable que se trate de un intento de llamada a algún método virtual empleando una variable objeto Nil (no asignada). En este caso fue la línea de código "if Form2.ShowModal = mrOk then". Y, en general, cualquier AV de lectura o escritura sobre una dirección de memoria 0 o cercana a 0 (000002A4, por ejemplo), es indicativo de intento de operación con un posible objeto Nil.

Cita:

Empezado por DarthGomis (Mensaje 530561)
[...]estoy aprendiendo en Delphi[...]

Celebro que cada vez haya más personas aprendiendo a programar en Delphi. Estupendos foros como Club Delphi estarán ahí para ayudar a resolver tus dudas. Y aspiramos a que tú mismo empieces a ayudar a otros también en poco tiempo. ¡No dejes de participar y compartir! :)

amadis 27-04-2020 14:51:13

Hola compañeros

Tengo una duda respecto de los Form Modal.

Si creo un form de la siguiente forma
Código Delphi [-]
 
Form := TFormCreate(nil);
  try
   Form.ShowModal;
  finally Form.Free;
  end;

Luego en el evento ONCLOSE del Form ¿no debo poner Action := caFree; ? no?.
Porque lo hace en el finally?

Consulto porque siempre tenia el action en el OnClose y el Finally y no tenía problemas.

Pero ahora me sale problema de Operacion de Puntero invalido, cuando intento usar If para saber el MODAL RESULT.

Código Delphi [-]
Form := TFormCreate(nil);
  try
   if Form.ShowModal = mrok
     then showmessage('ok');
  finally Form.Free;
  end;

El error es porque estoy haciendo FREE dos veces, una en el ON CLOSE del Form y otra en el finally.

Cual sería el lugar indicado para el FREE ¿ en el finally del Try? o en el ONCLOSE del Form?

ecfisa 27-04-2020 16:19:28

Hola.

Revisa este artículo: ¿Hay vida después de la muerte?

Saludos :)

kuan-yiu 27-04-2020 16:28:37

Cita:

Empezado por ecfisa (Mensaje 536900)
Hola.

Revisa este artículo: ¿Hay vida después de la muerte?

Saludos :)

Interesante

amadis 28-04-2020 00:01:09

Cita:

Empezado por ecfisa (Mensaje 536900)
Hola.

Revisa este artículo: ¿Hay vida después de la muerte?

Saludos :)

entonces

Los dos métodos (el uso de caFree y el uso explícito de Free), efectivamente, funcionan bien por separado.
Al mezclar las dos técnicas, el algoritmo sigue funcionando bien, y el objeto se destruye una sola vez.

¿no hay una forma correcta? seria así?


La franja horaria es GMT +2. Ahora son las 11:15:55.

Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi