DLL que devuelve un Bitmap
 

Hola amigos. Estoy desarrollando una DLL en Delphi, la cual debe almacenar un bitmap en un parámetro pasado por referencia a una función de esta DLL para que desde cualquier aplicación desarrollada en otros lenguajes puedan llamar a la función y obtener ese bitmap. Estoy trabado con eso. A través del handle del bitmap, tal vez? Si alguien tiene alguna idea, por más remota que sea, desde ya se los agradezco.

si vas a trabajar con otros lenguajes lo mejor es usar los tipos simples: pchar, int, logint, hadle, bool, etc. no queda otra. (salvo mejor sugerencia)

si solo vas a trabajar entre aplicaciones hechas en delphi podrías usar un TBitmap y castearlo como logint para poder usarlo en ambos lados.

saludos

Podríamos intentar algo como esto:

Código Delphi [-]
library bitmaps;

uses Windows, SysUtils, Classes, Graphics, Controls;

function GetBitmap(Parametro: PChar): HBitmap; stdcall;
var
  Bitmap: TBitmap;
  OldBitmap: HBitmap;
  MemDC: HDC;
begin
  Bitmap:= TBitmap.Create;
  try
    Bitmap.Canvas.Font.Size:= 32;
    Bitmap.Width:= Bitmap.Canvas.TextWidth(String(Parametro));
    Bitmap.Height:= Bitmap.Canvas.TextHeight(String(Parametro));
    Bitmap.Canvas.TextOut(0,0,String(Parametro));
    Result:= CreateCompatibleBitmap(Bitmap.Canvas.Handle, Bitmap.Width,
      Bitmap.Height);
    MemDC:= CreateCompatibleDC(Bitmap.Canvas.Handle);
    OldBitmap:= SelectObject(MemDC, Result);
    try
      BitBlt(MemDC,0,0,Bitmap.Width,Bitmap.Height,Bitmap.Canvas.Handle,
        0,0,SRCCOPY);
    finally
      SelectObject(MemDC, OldBitmap);
      DeleteDC(MemDC);
    end;
  finally
    Bitmap.Free;
  end;
end; 

exports GetBitmap;

begin
end.

La librería anterior exporta la función GetBitmap, que devuelve un HBitmap con el texto que le pasamos como parámetro. Este handle, lo podemos usar en cualquier lenguaje, ya que hace referencia a un objeto de la API de windows. Lo que tenemos que recordar es de destruirlo una vez terminemos de usarlo, aunque en el caso de delphi ya se encarga el de destruirlo, como podemos ver en el siguiente ejemplo.

Código Delphi [-]
function GetBitmap(Parametro: PChar): HBitmap; stdcall; external 'bitmaps.dll';


var
  Bitmap: TBitmap;
begin
  Bitmap:= TBitmap.Create;
  try
    Bitmap.Handle:= GetBitmap('Hola');
    Bitmap.SaveToFile('c:\1.bmp');
  finally
    // Al destruir el bitmap tambien destruimos el HBitmap
    Bitmap.Free;
  end;
end;

Para otros lenguajes tendrás que buscar tu como manejar la api, y si al contrario que en el caso anterior no destruyen el HBitmap por su cuenta tendrás usar la función DeleteObject para destruirlo tu mismo cuando ya no lo necesites.