Cerrar todas las Ventanas MDIChild
 

Hola a todos los compañeros del Foro.

Tanto cuanto cierro el formulario principal, como por ejemplo cuando hago un cambio de usuario, realizo la comprobación de si existen ventanas MDIChild abiertas y, en dicho caso, las cierro.

Pero mi problema se presenta cuando en alguna de las ventanas MDIChild necesito hacer una comprobación antes de cerrarla, por ejemplo si ha sido modificado algún dato, y pido al usuario si quiere grabar los datos modificados.

Si me confirma que sí, sigo con la operación de cierre, pero si opta por cancelar la operación de grabación, tengo que cancelar también la operación de cierre en el formulario principal (en la operación de cerrar), o para pedir un nuevo usuario.

Es aquí donde me surge la duda de como saber si la ventana MDIChild se ha cerrado correctamente o no.

He intentado :

Código Delphi [-]
procedure TMainform.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  i : Integer;
begin
  if MDIChildCount <> 0 then
    for I := 0 to MDIChildCount - 1 do begin
      MDIChildren[i].Close;
      Application.ProcessMessages;
      if Assigned(MDIChildren[i]) then begin
        CanClose := False;
        Exit;
      end;
    end;
end;

Para la primera ventana funciona bien. Pero si tengo más de un child abierto, pues no me funciona.

Si quito 'Application.ProcessMessages;' entonces Assigned(MDIChildren[i]) siempre es cierto.

Como tendría que hacerlo ?

Gracias por vuestra ayuda

Lo primero, cuando crees un bucle para cerrar las ventanas deberías hacerlo en orden inverso, de lo contrario al ir cerrando las ventanas los índices cambiaran y puede darte problemas:

Código Delphi [-]
  for I :=MDIChildCount - 1 downto 0 do

Aunque se me ocurre otra solución, interrogar ventana a ventana si pueden cerrarse, y si alguna responde que no abortamos el proceso.

Código Delphi [-]
procedure TMainform.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  i : Integer;
begin
    for I := 0 to MDIChildCount - 1 do 
      if not MDIChildren[i].CloseQuery then
      begin
        CanClose:= FALSE;
        Exit;
      end;
    for I :=MDIChildCount - 1 downto 0 do
       MDIChildren[i].Close;
end;

He optado por una variable pública en el Formulario principal (MainCanClose) que si se opta por cancelar la operación de cierre, se pone al valor deseado dentro del form Child que se está cerrando en ese momento.

... lo que me obliga a modificar todas las rutinas de cierre de todos los formularios MDIChild para incluir esa llamada a la variable del formulario principal.

Código Delphi [-]
type
  TMainform = class(TForm)
...
  public
    MainCanClose : Boolean;
....
    
procedure TMainform.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  i : Integer;
begin

  if MDIChildCount <> 0 then begin

    MainCanClose := True;

    for I := 0 to MDIChildCount - 1 do begin
      MDIChildren[i].Close;
      if not MainCanClose then begin
        CanClose := False;
        Exit;
      end;
    end;

  end;

end;

Código Delphi [-]
procedure TMDIChildCualquiera.FormClose(Sender: TObject; var Action: TCloseAction);
begin
 
  ...
 
  If not PreguntadeCierre then begin
    MainForm.MainCanClose := False;
    Action := caNone;
  end;
 
  ...
 
end;

Si alguien sabe una solución mejor, sin tener que modificar todos los MDIChild, pues le agradecería mucho su comentario.

Saludos ;)

Gracias Domingo ....

A lo mejor viene la solución por ahí como tu dices lo del orden inverso de los índices. No caí en eso.

Lo voy a probar ....

Se me ocurre lanzar el evento OnCloseQuery de cada mdichild, así sabemos si quiere abortar o no.

Supongo que los mdichilds se liberan de memoria al cerrarlos, o tendríamos que restaurar su evento OncloseQuery, que ya son palabras mayores

Código Delphi [-]
procedure TMainform.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  i : Integer;
  Continuar:Boolean;
begin
  if MDIChildCount <> 0 then
    for I := 0 to MDIChildCount - 1 do 
    begin
      if Assigned(MdiChildre[i].OnCloseQuery) then
      begin
         MdiChildre[i].OnCloseQuery(Self, Continuar);
         if Continuar then
         begin
           MdiChildre[i].OnCloseQuery := nil; // quitamos el evento, para que no se repita.
           MdiChildre[i].Close; // ya sabemos que se cerrará sin problemas
         end
         else
           Exit;
      end
      else 
          mdichildren[i].Close; // este no se puede quejar al cerrarlo, no tiene OnCloseQuery asignado
    end;
end;

Saludos

... Yo tampoco caí en el orden inverso jejeje, copié y pegué de guglu.

Una cosita, creo que el CloseQuery está precisamente para eso, para preguntar si se debe cerrar una ventana o no, de hecho, si se asigna false a CanClose, no se lanza el evento OnClose. Por ello, se debería hacer las cosas de forma independiente.

En el CloseQuery se hace la validación de si debe cerrarse o no, asignando la variable CanClose;

En el FormClose, solamente establecer el Action correspondiente, que suele ser cafree.

Saludos

Lepe, tienes toda la razón, el evento OnQueryClose está para eso, para preguntar si se quiere o no cerrar.

Aunque había leido muchas veces acerca de ello, nunca cae uno ciertamente hasta que le hace falta.

Y me parece perfecta la pregunta previa de si está o no asignado el evento OnCloseQuery para alguno de los MDIChild.

Muchas gracias tanto a Seoane como a Lepe.

Estoy en ello, cuando termine con todo, pondré el código definitivo. ;)

Yo lo haría así:

Cerrar los formularios hijo

Código Delphi [-]
(* No hay necesidad de preguntar si hay hijos abiertos *)
for I := MDIChildCount - 1 downto 0 do
  MDIChildren[i].Close;

OnCloseQuery del formulario hijo:

Código Delphi [-]
const
  Flags = MB_ICONWARNING or MB_YESNOCANCEL;

begin
  if HayCambios then
    case Application.MessageBox('¿Desea guardar los cambios?', 'Confirmar', Flags) of
      ID_YES: { código para guardar cambios };
      ID_NO: { no hacer nada };
      ID_CANCEL: abort { al ser una excepción, cancelará lo que reste del ciclo };
    end;
end;

// Saludos

Gracias Roman también por tus comentarios.

Sigo atascado, y no sé el por qué ... :mad: .

De vuelta a mi aplicación de reservas de hoteles. Estoy intentando cerrar las reservas individuales que estén abiertas, que son MDIChild.

En cada Form de reserva tengo puesta una Transacción. Todo funciona perfectamente si cierro las ventanas individualmente. Pero al intentar llamar desde el formulario principal al evento OnCloseQuery de cada una de las reservas, y confirmar si o no para grabar cambios, pongo la Transacción inactiva al cerrar esa reserva.

Pues al parecer, y ya digo que para mi incomprensiblemente, me cierra también las transacciones correspondientes a cualquier otra reserva que tenga abierta.

Estoy más que seguro que no hay error de que se mezclen nombres y llamadas a cada una de las transacciones. Además funciona perfectamente si lo que hago es cerrar cada reserva 'a mano', sin la llamada desde el formulario principal y su correspondiente comprobación del OnCloseQuery de cada MDIChild.

:confused: :confused:

No entiendo cuál es el problema. Tú estás mandando cerrar todas las ventanas, y eso cerrará las transacciones de las ventanas que no tengan modificaciones y que estén antes de alguna que se cancele. Es decir, es el comportamiento esperado ¿no?

// Saludos

Precisamente no.

Perdón, pero no lo expresé correctamente antes. Es que me dá error.

Cuando intento cerrar la segunda reserva, resulta que su propia transacción se ha cerrado ya, al parecer al momento de cerrar la transacción de la primera reserva, y por lo tanto me dá error, porque dice que la transacción está inactiva.

Es muy raro. Insisto, no 'debe' de haber errores en cada instancia de la transacción para cada una de las reservas, porque está situada en el propio form (ya lo discutimos ampliamente en otro hilo acerca de la conveniencia o no de colocarla en el propio form), y me he asegurado ya 5 o 6 veces que no existen errores en las llamadas desde otro sitio.

Bueno, al parecer terminó funcionando :p

Se ha quedado de la siguiente manera :

Código Delphi [-]
procedure TMainform.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  i : Integer;
begin
  for i := MDIChildCount - 1 downto 0 do begin
   if Assigned(MDIChildren[i].OnCloseQuery) then begin
     MDIChildren[i].Close;
     Application.ProcessMessages;
   end;
  end;
  for i := MDIChildCount - 1 downto 0 do
    MDIChildren[i].Close;
end;

Primero intento cerrar todas las ventanas en las cuales necesite hacer una comprobación antes del cierre, y por lo tanto aquellas que tengan un 'OnCloseQuery', y después sigo con las que no lo tienen.

Te esta manera si el usuario decide 'abortar' el proceso de cierre, aquellas ventanas que no necesiten de comprobación seguirán abiertas.

En el OnCloseQuery de las MDIChild que lo necesiten :

Código Delphi [-]
procedure TMDIChild.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
var
  Option : String;
begin
 
  if Modificado then begin
 
    if (WindowState = wsMinimized) or (Height <> Constraints.MaxHeight) or (Width <> Constraints.MaxWidth) then begin
      WindowState := wsNormal;
      Height      := Constraints.MaxHeight;
      Width       := Constraints.MaxWidth;
      BorderIcons := BorderIcons - [biMaximize];
    end;
 
    if not Active then Show;  // Esto lo saqué de otro hilo y viene muy bien si
                                       // el MDIChild no está visible por delante de los demás
 
    Mostrar_Mensaje('Se realizaron Cambios. Quiere Guardar dichos Cambios ?',1);
    Option := Mostrar_Mensaje.ShowModal;
    Mostrar_Mensaje.Free;

    If Option = 'CANCEL' then begin
      CanClose := False;
      Abort;
    end;
 
    // Realizar las operaciones oportunas para grabar o descartar cambios
 
  end;
 
end;

Si no se necesita de esta comprobación, se ejecutará directamente el código que se halle en OnClose, entre otras la liberación de la memoria mediante el Free correspondiente.

Además incluyo la rutina que utilizo para la misma comprobación cuando se intenta hacer un cambio de usuario mediante mi propia pantalla de LogIn. Al cambiar de usuario lo que hago es también obligar a cerrar todas las ventanas activas.

Código Delphi [-]
procedure TMainform.LogInClick(Sender: TObject);
var
  i : Integer;
  Option   : Integer;
  Aux_Name : String;
begin
 
  if MDIChildCount <> 0 then begin

    Mostrar_Mensaje('Se cerrarán todas las Ventanas Abiertas. Continuar?',0);

    Option := Mostrar_Mensaje.ShowModal;
    Mostrar_Mensaje.Free;

    if Option = 1 then begin
      for i := MDIChildCount - 1 downto 0 do begin
        if Assigned(MDIChildren[i].OnCloseQuery) then begin
          MDIChildren[i].Close;
          Application.ProcessMessages;
        end;
      end;
      for i := MDIChildCount - 1 downto 0 do
        MDIChildren[i].Close;
    end
    else Exit;

  end;
 
  ActionMainMenuBar1.Enabled := False;
  LogIn := TLogIn.Create(Self);
  LogIn.ShowModal;
  LogIn.Free;
  ActionMainMenuBar1.Enabled := True;
 
end;

Después de todos los comentarios de los compañeros, no sé realmente por qué he tenido que incluir el 'Application.ProcessMessages'. La cuestión es que puedo tener abiertas varias instancias de un mismo form (en mi caso reservas de habitaciones). Y comenté anteriormente el problema que tenía con la transacción de cada una de esas instancias del mismo form.

Lo que si he podido comprobar con certeza es que si incluyo dicho 'Application.ProcessMessages' todo funciona correctamente, en cambio si lo omito, al cerrar la transacción de la primera instancia del form de reservas, me cierra también las transacciones de las demás instancias.

Saludos a todos, y una vez más gracias a todos por la ayuda prestada. ;)