OnDragdrop y OnDragOver
 

Muy buenas. Tengo un componente propio que deriva de la clase TCustomControl.
Lo que deseo es poder arrastrar y soltar un panel encima de este componente mío.
El código mediante el cual he intentado esto es el siguiente:

Código Delphi [-]
  TDragDropEvent = procedure(Sender, Source: TObject; X, Y: Integer) of object;
  TDragOverEvent = procedure(Sender, Source: TObject; X, Y: Integer; State: TDragState; var Accept: Boolean) of object;

 TMiNuevoComponente = class(TCustomControl) 
 private
    fDragDropEvent : TDragDropEvent;
    fDragOverEvent : TDragOverEvent;
    ...
  published
    property OnDragDrop1: tDragDropEvent read fDragDropEvent write fDragDropEvent;
    property OnDragOver1: tDragOverEvent read fDragOverEvent write fDragOverEvent;
    ...
 end;

Pero sin éxito. En mi formulario he asignado un trozo de código en ambos eventos pero ninguno llega a dispararse. He observado que dentro de la clase TMiNuevoComponente puedo acceder a dos propiedades (OnDragDrop y OnDragOver) pero no se de que me puede servir.

Gracias.

¿Qué código usas para disparar esos eventos?

A través del object inspector:

Código Delphi [-]
procedure TMiFormulario.MiComponenteDragDrop1(Sender, Source: TObject; X, Y: Integer);
begin
  showmessage('blabla')
end;

El valor de la propiedad dragmode del panel que quiero mover es dmAutomatic

Me lo temía. Lo que tienes que hacer es sobrecargar (OVERRIDE) varios métodos de la clase TCustomControl. No sé exactamente cuales, pero serían los que tengan nombres con "Drag" y/o "Drop". Por ejemplo, DoDragMsg, aunque no estoy seguro del todo. Nunca he usado drag'n'drop así que no sabría decirte.

Pero en realidad no necesita nada de eso, o al menos eso creo. TCustomControl ya tiene todo para manejar el drag & drop, así que lo único que debe hacer es codificar los eventos OnDragDrop, OnDragOver. Aquí puede ver una explicación general de su uso.

LineComment Saludos

Acabo de volver de vacaciones así que pido disculpas por contestar tan tarde.
primero, muchas gracias por las respuestas pero sigo sin encontrar solución.

Pero tengo pregunta-pista, a ver si va por aquí la solución. He observado que puedo arrastrar y soltar el panel encima de otros panels. Al mismo tiempo, he podido observar que el panel NO lo puedo arrastrar encima de los objetos del tipo TSpeedButton.
Sabe alguien el motivo? Gracias.

Mostranos el codigo

Hola.

Los eventos OnDragDrop y OnDragOver estan declarados en la seccion protected de la clase TControl de la que deriva TSpeedButton, para usarlos tendrías que desproteger la clase TSpeedButton.

Un ejemplo:

Código Delphi [-]
...
type
  TSpeedButton = class(Buttons.TSpeedButton);
 
  TForm1 = class(TForm)
    SpeedButton1: TSpeedButton;
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
    procedure Panel1Click(Sender: TObject);
  private
    procedure SpeedButtonDragOver(Sender, Source: TObject; X, Y: Integer;
      State: TDragState; var Accept: Boolean);
    procedure SpeedButtonDragDrop(Sender, Source: TObject; X, Y: Integer);
  public
  end;

...
implementation

procedure TForm1.FormCreate(Sender: TObject);
begin
  SpeedButton1.OnDragDrop := SpeedButtonDragDrop;
  SpeedButton1.OnDragOver := SpeedButtonDragOver;
end;

procedure TForm1.SpeedButtonDragOver(Sender, Source: TObject; X, Y: Integer;
  State: TDragState; var Accept: Boolean);
begin
  Accept := Source is TPanel;
end;

procedure TForm1.SpeedButtonDragDrop(Sender, Source: TObject; X, Y: Integer);
begin
  TSpeedButton(Sender).Caption := TPanel(Source).Caption;
end;

procedure TForm1.Panel1Click(Sender: TObject);
begin
   TPanel(Sender).BeginDrag(True);
end;

Saludos :)

@AgustinOrtu
Aquí está el problema, que no sabía codificar el comportamiento de los dos eventos. Gracias por responder :D.

@Ecfisa
genial tu respuesta, es la solución ! Mil gracias.
Pero ya que estoy, debo reconocer que no me explico como es que funciona.
A ver, según dices, los dos eventos están declarados como protected en la clase TControl.
después de esta línea:

Código Delphi [-]
type
  TSpeedButton = class(Buttons.TSpeedButton);

que pasa con la nueva clase TSpeedButton ? Los dos eventos dejan de ser protected? Puedes desarrolar un poco tu respuesta? Seguro que me resultará más que interesante y útil. Gracias.

Si, las propiedades protegidas serán visibles (desprotegidas) dentro del ámbito de la declaración y tendrán la durabilidad del mismo. Revisa este artículo que desarrolla una explicación muy clara: Accessing protected members of a component.

Notarás que hay una pequeña diferencia entre el artículo y el ejemplo anterior , tomando el artículo quedaría:

Código Delphi [-]
type
  THackSpeedButton = class(TSpeedButton);

  TForm1 = class(TForm)
    SpeedButton1: TSpeedButton;
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
    procedure Panel1Click(Sender: TObject);
  private
    procedure SpeedButtonDragOver(Sender, Source: TObject; X, Y: Integer;
      State: TDragState; var Accept: Boolean);
    procedure SpeedButtonDragDrop(Sender, Source: TObject; X, Y: Integer);
  public
  end;
...

implementation

procedure TForm1.FormCreate(Sender: TObject);
begin
  THackSpeedButton(SpeedButton1).OnDragDrop := SpeedButtonDragDrop;
  THackSpeedButton(SpeedButton1).OnDragOver := SpeedButtonDragOver;
end;

procedure TForm1.SpeedButtonDragDrop(Sender, Source: TObject; X,
  Y: Integer);
begin
  TSpeedButton(Sender).Caption := TPanel(Source).Caption;
end;

procedure TForm1.SpeedButtonDragOver(Sender, Source: TObject; X,
  Y: Integer; State: TDragState; var Accept: Boolean);
begin
   Accept := Source is TPanel;
end;

procedure TForm1.Panel1Click(Sender: TObject);
begin
  TPanel(Sender).BeginDrag(True);
end;

También te podría resultar interesante este enlace: Clases interpuestas

Saludos :)

excelentes recursos, muchas gracias.