[roman]

Hola,

Siento que nuestro compañero gushynet se está yendo por un camino equivocado al tratar de resolver con clonaciones lo que puede resolverse con métodos usuales.

Según lo que él describe, yo lo plantearía así: en lugar de poner el método Asignar de la clase base como abstracto, lo implementaría de manera que copie las propiedades comunes, y, tal como él mismo dice, redefiniría este método en TTematica para copiar la propiedad extra.

Código Delphi [-]
interface

type
  TParrafo = class
  private
    FContenido: String;

  public
    property Contenido: String read FContenido write FContenido;
    procedure Asignar(P: TParrafo); virtual;
  end;

  TPregunta = class(TParrafo)
  end;

  TRespuesta = class(TParrafo)
  end;

  TTematica = class(TParrafo)
  private
    FDescripcion: String;

  public
    property Descripcion: String read FDescripcion write FDescripcion;
    procedure Asignar(P: TParrafo); override;
  end;

implementation

{ TParrafo }

procedure TParrafo.Asignar(P: TParrafo);
begin
  Self.FContenido := P.Contenido;
end;

{ TTematica }

procedure TTematica.Asignar(P: TParrafo);
begin
  inherited;

  if (P is TTematica) then
  begin
    Self.FDescripcion := TTematica(P).Descripcion;
  end
end;

end.

Tal como lo pongo aquí, se pueden copiar unos a otros sin problemas. Si una Tematica se asigna a un Parrafo (o Pregunta o Respuesta), el método usado es el de la clase base, por lo que se copia únicamente la propiedad Contenido. Si se asigna a otra Tematica entonce se usa el método redefinido que usa el heredado y añade la copia de la propiedad Descripcion.

Finalmente, si un Parrafo (o Pregunta o Respuesta) se copia a una Tematica, el método Asignar de TTematica copia los campos base (Contenido) pero evita copiar el campo extra que no existe en el objeto fuente.

// Saludos