si archivo existe renombrar con parametro

[jonydread]

hola amigos como el titulo dice
verifico si existe fichero de destino y muestro un mensaje si desea reemplazar
pero quiero eliminar eso y si existe nombrar con una constante por ejemplo
si existe miarchivo.zzz
nombrar como miarchivo(1).zzz
si existe miarchivo(1).zzz
nombrar como miarchivo(2).zzz
y así sucesivamente...

gracias
Saludos!!

[ecfisa]

Hola.

Una forma podría ser:

Código Delphi [-]
...
uses StrUtils;

procedure TomarNombre(Nombre: string; var Nuevo: string);
var
  Num: Integer;
  Ext: string;
begin
  if FileExists(Nombre) then
  begin
    Ext := ExtractFileExt(Nombre);
    Nombre := LeftStr(Nombre, Length(Nombre) - Length(Ext));
    if Pos('(', Nombre) = 0 then
    begin
      Num := 1;
      Nombre := Nombre + '(' + IntToStr(Num) + ')' + Ext;
    end
    else
    begin
      Num := StrToInt(Copy(Nombre, Pos('(', Nombre)+1,
        PosEx(')',Nombre, Pos('(', Nombre))-Pos('(', Nombre)-1));
      Inc(Num);
      Nombre := Copy(Nombre,1,Pos('(', Nombre)-1)+'('+IntToStr(Num)+')' + Ext;
    end;
    if FileExists(Nombre) then
      TomarNombre(Nombre, Nombre);
  end;
  Nuevo:= Nombre;
end;

Llamada de ejemplo:

Código Delphi [-]
...
procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Lines.LoadFromFile('C:\MIARCHIVO.TXT');
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  s: string;
begin
  TomarNombre('C:\MIARCHIVO.TXT', s);
  Memo1.Lines.SaveToFile(s);
end;

Un saludo.

[jonydread]

hola amigo gracias por tu tiempo
aplique el codigo aqui pero no me funciona

Código Delphi [-]
procedure TReg2infConverter.Button2Click(Sender: TObject);
var Origen, Destino,FileName,Path,s: string;
begin
if ExtractFileExt(opendialog1.FileName) = '.reg' then
begin
TomarNombre(opendialog1.FileName, s);
Path:=GetshortName(ExtractFilePath(Opendialog1.FileName));
Filename := Extractfilename(opendialog1.FileName);
Origen := GetshortName(opendialog1.FileName);
Filename:= AnsiReplaceStr(Filename,' ','');
Destino :=ChangeFileExt(Filename, '.inf');
LlamarReg2inf(Handle,'reg2inf.exe',Origen,path+Destino );
end else
MessageDlg('Archivo invalido!', MtError, [mbOK],0);
end;

he probado de diferentes formas pero no me resulta que hago mal??

[ecfisa]

Hola.

Con respecto a ese código no sé ya que hay muchos factores involucrados que pueden estar provocando el fallo.

Pero para que realizes la prueba, te pongo un procedimiento que llama a la función TomarNombre utilizando un TOpenDialog y realiza correctamente lo que buscabas.

Código Delphi [-]
...
implementation

uses StrUtils;

procedure TomarNombre(Nombre: string; var Nuevo: string);
var
  Num: Integer;
  Ext: string;
begin
  if FileExists(Nombre) then
  begin
    Ext := ExtractFileExt(Nombre);
    Nombre := LeftStr(Nombre, Length(Nombre) - Length(Ext));
    if Pos('(', Nombre) = 0 then
    begin
      Num := 1;
      Nombre := Nombre + '(' + IntToStr(Num) + ')' + Ext;
    end
    else
    begin
      Num := StrToInt(Copy(Nombre, Pos('(', Nombre)+1,
        PosEx(')',Nombre, Pos('(', Nombre))-Pos('(', Nombre)-1));
      Inc(Num);
      Nombre := Copy(Nombre,1,Pos('(', Nombre)-1)+'('+IntToStr(Num)+')' + Ext;
    end;
    if FileExists(Nombre) then
      TomarNombre(Nombre, Nombre);
  end;
  Nuevo:= Nombre;
end;

// codigo de prueba
procedure TForm1.Button1Click(Sender: TObject);
var
  Ori, Des: TMemoryStream;
  i: Integer;
  b: Byte;
  Nombre: string;
begin
  if OpenDialog1.Execute then
  begin
    Ori:= TMemoryStream.Create;
    Des:= TMemoryStream.Create;
    try
      Ori.LoadFromFile(OpenDialog1.FileName);
      TomarNombre(OpenDialog1.FileName, Nombre);
      for i:= 0 to Ori.Size - 1 do
      begin
        Ori.Read(b, 1);
        Des.Write(b, 1)
      end;
      Des.SaveToFile(Nombre)
    finally
      Ori.Free;
      Des.Free
    end;
  end;
end;
end.

Un saludo.

[jonydread]

muchas gracias funciona perfecto!!

[[escafandra]]

Hace varios meses publiqué una función para encontrar un nombre de archivo no repetido y proponer un nuevo nombre como lo hace Windows. La fuente es esta y el código este:

Código Delphi [-]
function FileNameOnCollision(FileName: String): String;
var
  FileExt: String;
  n: integer;
begin
  Result:= FileName;
  FileExt:= ExtractFileExt(FileName);
  SetLength(FileName, Length(FileName) - Length(FileExt));
  n:= 2;
  while FileExists(Result) do
  begin
    Result:= FileName + '(' + IntToStr(n) + ')' + FileExt;
    inc(n);
  end;
end;

Ejemplo de uso:

Código Delphi [-]
  Label1.Caption:= FileNameOnCollision(ExtractFilePath(Application.ExeName) + 'texto.txt');

Saludos.