Contar letras en un TMemo

[[Caral]]

Hola egostar
No se a que te refieres con los enter, supongo que a los espacios vacios entre las letras.
No se pero se me ocurre que si es text, por que no definir un:

Código Delphi [-]
If X = ' ' then
//otra cosa

Osea que si el espacio esta vacio no lo lea.
No se se me ocurre.
Saludos

[[egostar]]

Hola Caral, gracias por tu interes.

Me refiero a los ENTER que son los saltos de linea, no a los espacios entre palabras, esos si los estoy contando.

Saludos.

[[Bicho]]

Hola, quizá una función como esta te sirva:

Código Delphi [-]
 function Palabras(Cadena:string):integer;
 var
    n:integer;
    AntEspacio:boolean;
 begin
   AntEspacio:=FALSE;
   If Cadena='' then Result:=0 else Result:=1;
   for n:=1 to Length(Cadena) do
   begin
     if AntEspacio and
        (Cadena[n]<>' ')and
        (Cadena[n]<>#13)and
        (Cadena[n]<>#10)
                   then Inc(Result);

     AntEspacio:=(Cadena[n]=' ') or
                 (Cadena[n]=#13) or
                 (Cadena[n]=#10);
   end;
 end;

Saludos

[[ArdiIIa]]

Veamos

Código Delphi [-]
procedure TForm1.ContarLetras(Sender: TObject);
Var
I,Z: Integer;
cTemp :  String;
begin
Z := 0;
cTemp := Memo1.Lines.Text;
For I := 1 To  Length(cTemp) DO
if ord(cTemp[i]) < 32 then
inc(Z);

ShowMessage( IntToStr( Length(cTemp) - Z ));

end;

[[egostar]]

Muchas gracias ArdiIIa

Quedo de 10

Aqui pongo como quedó el código completo espero que sirva para futuras consultas.

Código Delphi [-]
unit UContadorLetras;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Buttons;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    StaticText1: TStaticText;
    Label1: TLabel;
    BitBtn1: TBitBtn;
    procedure FormShow(Sender: TObject);
    procedure Memo1Change(Sender: TObject);
    procedure ContarLetras;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  Letras: Integer;

implementation

{$R *.DFM}

procedure TForm1.ContarLetras;
Var
  I,Z: Integer;
  cTemp :  String;
begin
  Z := 0;
  cTemp := Memo1.Lines.Text;
  For I := 1 to  Length(cTemp) do
      if ord(cTemp[i]) < 32 then
         inc(Z);
  StaticText1.Caption := IntToStr(Length(cTemp) - Z);
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  Letras := 0;
  StaticText1.Caption := inttostr(Letras);
end;

procedure TForm1.Memo1Change(Sender: TObject);
begin
  ContarLetras;
end;

end.

Saludos y nuevamente gracias.

[[egostar]]

Vaya

Tambien este funcionó a la perfeccion.

Código Delphi [-]
unit UContadorLetras;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Buttons;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    StaticText1: TStaticText;
    Label1: TLabel;
    BitBtn1: TBitBtn;
    procedure FormShow(Sender: TObject);
    procedure Memo1Change(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  Letras: Integer;

implementation

{$R *.DFM}

procedure TForm1.FormShow(Sender: TObject);
begin
  Letras := 0;
  StaticText1.Caption := inttostr(Letras);
end;

procedure TForm1.Memo1Change(Sender: TObject);
var
  Str: String;
  i,j: integer;
begin
  Str:= Memo1.Lines.Text;
  j:= 0;
  for i:= 1 to Length(Str) do
    if (Str[i] <> #13) and (Str[i] <> #10) then
      inc(j);
  StaticText1.Caption:= IntToStr(j);
end;

end.

Muchas gracias seoane.

[[Caral]]

Hola, Bueno, los dos funcionan muy bien y hacen casi lo mismo, pero:
Me he quedado con que cuentan tambien los espacios en blanco, como hacer para que no los cuente.
Osea contar letras, pues que cuente letras, no espacios entre ellas, al igual que no cuenta el enter o salto de renglon.
Saludos

[[egostar]]

Perdon Bicho pero no vi tu post antes de contestar a los demas, gracias por el aporte.

Saludos.

[[seoane]]

Volviendo al método numero uno, el ortodoxo

Supongo que esto funcionaría:

Código Delphi [-]
procedure TForm1.Memo1Change(Sender: TObject);
var
  Str: String;
  i,j: integer;
begin
  Str:= Memo1.Lines.Text;
  j:= 0;
  for i:= 1 to Length(Str) do
    if (Str[i] <> #13) and (Str[i] <> #10) then
      inc(j);
  StaticText1.Caption:= IntToStr(j);
end;

Aunque supongo que ya habrías pensado en una solución parecida, entonces me pregunto si lo que te preocupaba es el tiempo que se tarda en contar los caracteres. Si es así lo podemos afinar un poco mas:

Código Delphi [-]
function Longitud(Str: PChar): Integer;
asm
        MOV     Result,0
        DEC     EAX
@@SIG:
        INC     EAX
        CMP     BYTE PTR [EAX],0
        JE      @@SALIR
        CMP     BYTE PTR [EAX],13
        JE      @@SIG
        CMP     BYTE PTR [EAX],10
        JE      @@SIG
        INC     Result
        JMP     @@SIG
@@SALIR:
end;

procedure TForm1.Memo1Change(Sender: TObject);
begin
  StaticText1.Caption:= IntToStr(Longitud(PChar(Memo1.Lines.Text)));
end;

En cuanto al segundo método, es complicado, piensa que cuando usas Enter se introducen dos caracteres y no uno, que puedes seleccionar y borrar mas de un carácter a la vez y ya no hablamos si utilizas el portapapeles ...

[[egostar]]

Empezado por seoane

Aunque supongo que ya habrías pensado en una solución parecida, entonces me pregunto si lo que te preocupaba es el tiempo que se tarda en contar los caracteres. Si es así lo podemos afinar un poco mas:

Realmente no me preocupa el tiempo en el conteo, incluso es imperceptible, de todos modos estoy analizando tu código ASM que me parece muy interesante aunque un poco fuera de mi alcance en este momento.

Saludos.