Excepcion incontrolable al detectar medios extraibles

[beginner01]

Hola.

Revisaste el enlace que te dejé? hay varios "flags" que se le pueden pasar a la función según el tipo de error que tengas. En mi caso funciono con SEM_FAILCRITICALERRORS pero en tu caso puedes probar con las demás o leer la explicación que dan a ver si te sirve.

[ecfisa]

Hola champy.

Proba de este modo:

Código Delphi [-]
function MicroSDPresent: Boolean;
var
  i    : char;
  FName: string;
  Error: LongWord;
begin
  Error := SetErrorMode(SEM_FAILCRITICALERRORS);
  Result:= False;
  for i := 'D' to 'Z' do
  begin
    if GetDriveType(PChar(i+':\')) = DRIVE_REMOVABLE then
      Result:=  CreateFile(PChar(Format('\\.\%s:\%s',[i,'prueba.txt'])),
      GENERIC_READ, 0, nil, CREATE_ALWAYS,
      FILE_ATTRIBUTE_NORMAL, 0) <> INVALID_HANDLE_VALUE;
  end;
  SetErrorMode(Error);
end;

// llamada:
...
begin
  if MicroSDPresent then
    ShowMessage('MicroSD presente')
  else
    ShowMessage('MicroSD ausente');
end;

Saludos.

[[nlsgarcia]]

champy,

Revisa este código:

Código Delphi [-]
Procedure GetDrive(FileName : String);
var
   Driver: Pchar;
   i, Length: Integer;
   SearchFile : Boolean;
   OldErrorMode: word;

begin

   OldErrorMode:= SetErrorMode(SEM_NOOPENFILEERRORBOX);

   SearchFile := False;
   GetMem(Driver, 100);
   Length := GetLogicalDriveStrings(100, Driver);

   try
      for i := 0 to Length-1 do
      begin
         if GetDriveType(Pchar(Driver[i] + ':\')) = DRIVE_REMOVABLE then
         begin
            If FileExists(Driver[i] + ':\' + FileName) then
            begin
               MessageDlg('Archivo Sincronizado en Medio Removible', mtinformation, [mbok], 0);
               SearchFile := True;
               break;
            end;
         end;
      end;
   finally
      SetErrorMode(OldErrorMode);
      FreeMem(Driver);
      if not Searchfile then
         MessageDlg('Archivo No Sincronizado en Medio Removible', mtinformation, [mbok], 0)
   end;

end;

Esta variante incluye las recomendaciones de beginner01 con el flag SEM_NOOPENFILEERRORBOX.

Revisa esta información:

SEM_NOOPENFILEERRORBOX:
If this flag is set, the operating system does not display a message box when it fails to find a a file. Instead, the error is returned to the calling process.

Espero sea útil

Nelson.

[ecfisa]

Hola champy.

Mira... voy a retocar un poco la función que hice a las apuradas ya que deja el archivo temporal en la tarjeta de memoria.
Y creo que a otros, tanto como a mí, podría no gustarles ese detalle...

Así que la nueva versión es:

Código Delphi [-]
function MicroSDPresent: Boolean;
var
  i    : char;
  FName: string;
  Error: LongWord;
  Hnd  : THandle;
begin
 Error := SetErrorMode(SEM_FAILCRITICALERRORS);
  Result:= False;
  for i := 'D' to 'Z' do
    if GetDriveType(PChar(i+':\')) = DRIVE_REMOVABLE then
    begin
      FName:= Format('\\.\%s:\%s',[i,'@@@prueba@@@.txt']);
      Hnd:= CreateFile(PChar(FName),
              GENERIC_READ, 0, nil, CREATE_ALWAYS,
              FILE_ATTRIBUTE_NORMAL, 0);
      if Hnd <> INVALID_HANDLE_VALUE then
      begin
        Result := True;
        CloseHandle(Hnd);
        DeleteFile(PChar(FName));
      end;
    end;
  SetErrorMode(Error);
end;

Saludos.

[[nlsgarcia]]

champy,

Revisa este código:

Código Delphi [-]
Procedure GetDrive(FileName : String);
var
   Driver: Pchar;
   i, Length: Integer;
   SearchFile : Boolean;
   OldErrorMode: word;
   searchResult : TSearchRec;

begin

   OldErrorMode:= SetErrorMode(SEM_NOOPENFILEERRORBOX or SEM_FAILCRITICALERRORS);

   SearchFile := False;
   GetMem(Driver, 100);
   Length := GetLogicalDriveStrings(100, Driver);

   try
      for i := 0 to Length-1 do
      begin
         if GetDriveType(Pchar(Driver[i] + ':\')) = DRIVE_REMOVABLE then
         begin
            if FindFirst(Driver[i] + ':\' + FileName, faArchive, searchResult) = 0 then
            begin
               MessageDlg('Archivo Sincronizado en Medio Removible', mtinformation, [mbok], 0);
               SearchFile := True;
               break;
            end;
         end;
      end;
   finally
      SetErrorMode(OldErrorMode);
      FreeMem(Driver);
      if not Searchfile then
         MessageDlg('Archivo No Sincronizado en Medio Removible', mtinformation, [mbok], 0)
   end;

end;

Esta variante combina dos flags de la función SetErrorMode y utiliza FindFirst para verificar si el archivo esta presente en la unidad.

Espero sea útil

Nelson.

[champy]

Al fin. Funcionó.

La función MicroSDPressent de eficsa me da True cuando la tarjeta está disponible sin sacar el mesajito del sistema.

SetErrorMode no estaba sirviendo de mucho, lo probe con todas las flags, supongo que por que no se trata de una excepcion propiamente dicha, es más bien un "Dialogo del sistema" indicando que la unidad no tiene disco.



En cualquier caso, ya está solucionado

Solo modifiqué la función para que me haga de comprobación de una unidad concreta, y listo, problema resuelto

Código Delphi [-]
function MicroSDPresent(i : char): Boolean;
var
  FName: string;
  Error: LongWord;
  Hnd  : THandle;
begin
 Error := SetErrorMode(SEM_FAILCRITICALERRORS);
  Result:= False;
    if GetDriveType(PChar(i+':\')) = DRIVE_REMOVABLE then
    begin
      FName:= Format('\\.\%s:\%s',[i,'@@@prueba@@@.txt']);
      Hnd:= CreateFile(PChar(FName),
              GENERIC_READ, 0, nil, CREATE_ALWAYS,
              FILE_ATTRIBUTE_NORMAL, 0);
      if Hnd <> INVALID_HANDLE_VALUE then
      begin
        Result := True;
        CloseHandle(Hnd);
        DeleteFile(PChar(FName));
      end;
    End;
  SetErrorMode(Error);
end;

Muchas gracias a todos los interesados, casi me sabe mal por cuanto me habeis ayudado.