problemas al agregar texto a un bitmap

[cl2raul]

ya lo probe y no se puede pq TFillTextFlag.RightToLeft es la unica opcion q da delphi xe7, alguien sabe algo...

[[Delphius]]

Es algo raro que existiera esa única opción en el enumerativo. Por lo que estuve viendo, en la versión Sattle sigue igual.
Quisiera pensar que todavía está en desarrollo... aunque es muy curioso.

Prueba con escribir de forma inversa las palabras. Es decir, si quieres que aparezca "100 días" pasa el texto como "días 100".

Saludos,

[roman]

Yo probaría dejando en blanco el parámetro:

Código Delphi [-]
Image1.Bitmap.Canvas.FillText(MyRect, '100 dias', false, 100, [], TTextAlign.Center, TTextAlign.Center);

LineComment Saludos

[[Delphius]]

La doc no dice nada sobre si puede dejarse en blanco.
No es muy clara al respecto.

Lo que si es bastante raro que al día de hoy ese enumerativo cuente con "Derecha a izquierda" y no el inverso. ¡Alguna razón o motivo deberían tener!

Saludos,

[Casimiro Notevi]

Porque lo normal es de izquierda a derecha.

[roman]

Empezado por Casimiro Notevi

Porque lo normal es de izquierda a derecha.

Así es. Realmente, lo raro en esta función es que el parámetro se especificque como un conjunto de banderas en lugar de un booleano, a menos que esperen que en el futuro haya otras direcciones del texto (¿de arriba a abajo, de abajo a arriba, diagonal ), y aún así, no debería ser un conjunto de banderas.

LineComment Saludos

[Casimiro Notevi]

Son esas cosas en las que se dice: "Ya lo dejamos preparado para más adelante". Luego nadie se acuerda porque no les habrá hecho falta.

[jhonny]

Empezado por roman

Yo probaría dejando en blanco el parámetro:

Código Delphi [-]
Image1.Bitmap.Canvas.FillText(MyRect, '100 dias', false, 100, [], TTextAlign.Center, TTextAlign.Center);

He probado el asunto desde el principio y definitivamente me ha sucedido en un principio lo expuesto acá por cl2raul, pero probando con la solución expuesta por Roman en el apartado que he citado anteriormente funciona correctamente, quedando así finalmente:

Código Delphi [-]
  Image1.Bitmap.Canvas.BeginScene;
  Image1.Bitmap.Canvas.FillText(TRectF.Create(50, 40, 200, 270), '100 dias', false, 1, [], TTextAlign.Leading,
    TTextAlign.Center);
  Image1.Bitmap.Canvas.EndScene;

Hice un par de cambios a lo original, pero no han de ser representativos para solucionar el problema del hilo.

[jhonny]

Metiéndose uno sólo un poco en el código de la FMX, ve uno que dicho parámetro llamado Flags es asignado a la propiedad boolean del TTextLayout creado en RunTime, llamada RightToLeft, de la siguiente manera:

Código Delphi [-]
Layout.RightToLeft := TFillTextFlag.RightToLeft in Flags;

O sea que si enviamos como valor del parámetro Flags... TFillTextFlag.RightToLeft, simplemente el Layout escribirá de derecha a izquierda, pero si lo enviamos vacío, escribirá de izquierda a derecha.

Mejor dicho, mirando la FMX, nos damos cuenta que aquí todos ya tenían razón en lo que hablaban. Y pongo esto acá, sólo para confirmarlo .

[cl2raul]

Gracias a todos los involucrador, ya solucione el problema, segui el prosedimiento con el objetivo de eliminar [TFillTextFlag.RightToLeft] que era el responsable de priorizar las letras a los números causando la no esperada respuesta, como en la unidad FMX.Graphics esla que contienes el procedimiento TCanvas.FillText(), cree mi version del procedimiento para ver resultado esperado (100 dias)=(100 dias), a continuacion la unidad, ojo hay q agregar al uses FMX.TextLayout;

Código Delphi [-]
unit main;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.Objects,
  FMX.StdCtrls, FMX.Controls.Presentation, FMX.Edit, FMX.Layouts;

type
  TTextInImage = class(TForm)
    Image1: TImage;
    Layout1: TLayout;
    Edit1: TEdit;
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  TextInImage: TTextInImage;

implementation

{$R *.fmx}

uses FMX.TextLayout;

procedure TextInImg(const ARect: TRectF; const AText: string; LaImagen: TCanvas;
  const WordWrap: Boolean; const AOpacity: Single; const ATextAlign, AVTextAlign: TTextAlign);
var
  Layout: TTextLayout;
begin
  Layout := TTextLayoutManager.TextLayoutByCanvas(LaImagen.ClassType).Create(LaImagen);
  try
    Layout.BeginUpdate;
    Layout.TopLeft:=ARect.TopLeft;
    Layout.MaxSize:=PointF(ARect.Width, ARect.Height);
    Layout.Text:=AText;
    Layout.WordWrap:=WordWrap;
    Layout.Opacity:=AOpacity;
    Layout.HorizontalAlign:=ATextAlign;
    Layout.VerticalAlign:=AVTextAlign;
    Layout.Font:=LaImagen.Font;
    Layout.Color:=LaImagen.Fill.Color;
    //Layout.RightToLeft := TFillTextFlag.RightToLeft in Flags;
    Layout.EndUpdate;
    Layout.RenderLayout(LaImagen);
  finally
    FreeAndNil(Layout);
  end;
end;

procedure TTextInImage.Button1Click(Sender: TObject);
var
  MyRect: TRectF;
  x1, y1, x2, y2, I: integer;
begin
  x1 := 60;
  y1 := 60;
  x2 := Image1.Bitmap.Canvas.Width - 60;
  y2 := Image1.Bitmap.Canvas.Height - 60;

  MyRect := TRectF.Create(x1, y1, x2, y2);

  Image1.Bitmap.Canvas.BeginScene;
  Image1.Bitmap.Canvas.Font.Family:='Arial';
  Image1.Bitmap.Canvas.Font.Size:=48;

  TextInImg(MyRect,Edit1.Text,Image1.Bitmap.Canvas,True,100,TTextAlign.Center,TTextAlign.Center);

  Image1.Bitmap.Canvas.EndScene;
end;

procedure TTextInImage.FormCreate(Sender: TObject);
begin
  Image1.Bitmap.LoadFromFile(GetCurrentDir+'\p10.png');
end;

end.

[Casimiro Notevi]

Empezado por cl2raul

ya lo probe y no se puede pq TFillTextFlag.RightToLeft es la unica opcion q da delphi xe7, alguien sabe algo...

Lo mismo no debes poner nada para que aparezca normal de left to right