ControlAtPos y componentes colocados sobre un TPanel

[[gluglu]]

Saludos a tod@s l@s compañer@s !

Tengo varios elementos, tales com TLabel's y TShape's, colocados sobre un TPanel.

Cuando intento obtener el elemento que está debajo del cursor del ratón con la función ControlAtPos, siempre me devuelve el TPanel, y en ningún caso los labels o shapes colocados sobre dicho Panel. Como se podría solucionar ?

Muchas gracias por vuestra ayuda.

[roman]

ControlAtPos es un método de TWinControl que te devuelve el control hijo bajo el cursor. Si tú aplicas este método en el formulario, entonces sólo encontrará al panel porque los otros controles no son hijos del formulario sino del panel. Tendrías entonces que usar Panel.ControlAtPos.

En general tendrías que armarte una función recursiva que se vaya adentrando en los hijos de los hijos hasta que ya no haya descendencia.

// Saludos

[roman]

A ver, intenta con esta función:

Código Delphi [-]
function DeepControlAtPos(Parent: TWinControl; Pos: TPoint): TControl;
var
  Child: TControl;

begin
  Result := Parent.ControlAtPos(Parent.ScreenToClient(Pos), false, true);

  if Assigned(Result) and (Result is TWinControl) then
  begin
    Child := DeepControlAtPos(TWinControl(Result), Pos);
    if Assigned(Child) then
      Result := Child;
  end;
end;

Pordrías usarla así en el formulario:

Código Delphi [-]
var
  Control: TControl;

begin
  Control := DeepControlAtPos(Self, Mouse.CursorPos);

  if Assigned(Control) then
    Caption := Control.ClassName
  else
    Caption := 'ninguno';
end;

// Saludos

[[gluglu]]

Muchas gracias Roman,

Había llegado hasta una función recursiva ya que utilizo el ControlAtPos de manera bastante enreversada .

Pero no caí en la cuenta de preguntar por Panel.ControlAtPos

De hecho había consultado la ayuda propia de Delphi y tenía claro que el problema estaba en el Parent. Pero no encontraba como solucionarlo.

Gracias por tu ayuda. Mientras escribo esto veo que has puesta también otro ejemplo con una función. De nuevo muchas gracias.

[roman]

Creo que esta otra está mejor:

Código Delphi [-]
function DeepControlAtPos2(Parent: TWinControl; Pos: TPoint): TControl;
var
  Child: TControl;

begin
  Result := Parent.ControlAtPos(Parent.ScreenToClient(Pos), false, true);
  Child := Result;

  while Assigned(Child) and (Child is TWinControl) do
  begin
    Child := TWinControl(Child).ControlAtPos(Child.ScreenToClient(Pos), false, true);

    if Assigned(Child) then
      Result := Child;
  end;
end;

La diferencia es que ésta no es recursiva, así que hay menos llamadas a función y menos uso de la pila.

// Saludos