Como Saber si una Dirección de Correo es Válida????

[S.M.S.]

Yo utilizo la siguiente función que no recuerdo de donde la saqué, pero que funciona perfectamente con los ejemplos de jachguate y de roman

Código Delphi [-]
function ValidEmail(email: string): boolean;
   // Devuelve True si la dirección de email es válida
   const
     // Caracteres válidos en un "átomo"
     atom_chars = [#33..#255] - ['(', ')', '<', '>', '@', ',', ';', 
     ':', '\', '/', '"', '.', '[', ']', #127];
     // Caracteres válidos en una "cadena-entrecomillada"
     quoted_string_chars = [#0..#255] - ['"', #13, '\'];
     // Caracteres válidos en un subdominio
     letters = ['A'..'Z', 'a'..'z'];
     letters_digits = ['0'..'9', 'A'..'Z', 'a'..'z'];
     subdomain_chars = ['-', '0'..'9', 'A'..'Z', 'a'..'z'];
   type
     States = (STATE_BEGIN, STATE_ATOM, STATE_QTEXT,
     STATE_QCHAR, STATE_QUOTE, STATE_LOCAL_PERIOD,
     STATE_EXPECTING_SUBDOMAIN, STATE_SUBDOMAIN, STATE_HYPHEN);
   var
     State: States;
     i, n, subdomains: integer;
     c: char;
begin 
  State := STATE_BEGIN;
  n := Length(email); 
  i := 1;
  subdomains := 1; 
  while (i <= n) do 
    begin
      c := email[i];
      case State of 
         STATE_BEGIN: 
                  if c in atom_chars then
                  State := STATE_ATOM 
                  else if c = '"' then 
                  State := STATE_QTEXT
                  else break;
         STATE_ATOM:
                  if c = '@' then
                  State := STATE_EXPECTING_SUBDOMAIN
                  else if c = '.' then 
                  State := STATE_LOCAL_PERIOD
                  else if not (c in atom_chars) then 
                  break; 
         STATE_QTEXT:
                  if c = '\' then
                  State := STATE_QCHAR 
                  else if c = '"' then
                  State := STATE_QUOTE 
                  else if not (c in quoted_string_chars) then 
                  break; 
         STATE_QCHAR:   
                  State := STATE_QTEXT; 
         STATE_QUOTE:
                  if c = '@' then 
                  State := STATE_EXPECTING_SUBDOMAIN
                  else if c = '.' then
                  State := STATE_LOCAL_PERIOD 
                  else break; 
         STATE_LOCAL_PERIOD:
                  if c in atom_chars then
                  State := STATE_ATOM 
                  else if c = '"' then 
                  State := STATE_QTEXT
                              else break; 
         STATE_EXPECTING_SUBDOMAIN: 
                  if c in letters then
                  State := STATE_SUBDOMAIN 
                  else break;
         STATE_SUBDOMAIN:
                  if c = '.' then
                  begin 
                      inc(subdomains);
                      State := STATE_EXPECTING_SUBDOMAIN
                  end
                  else if c = '-' then 
                  State := STATE_HYPHEN
                  else if not (c in letters_digits) then 
                  break;
         STATE_HYPHEN:
                  if c in letters_digits then
                  State := STATE_SUBDOMAIN
                  else if c <> '-' then break;
      end;
      inc(i);
    end;
  if i <= n then
  Result := False
  else
  Result := (State = STATE_SUBDOMAIN) and (subdomains >= 2);
end;

Saludos.

[johncook]

Muchachos, muchachos... Tanto lío para validar un mail...
Porque mejor no valernos de expresiones regulares, no? En C# no hay q instalar ninguna libreria de terceros para el uso de éstas expresiones... En delphi yo utilizo RegExpr, porque desconozco si existe alguna función nativa del lenguaje...

Código Delphi [-]
 uses RegExpr;
 
procedure TForm1.Button1Click(Sender: TObject);
// Valida la dirección de email en Edit1
begin
  if not ExecRegExpr('[\w\d\-\.]+@[\w\d\-]+(\.[\w\d\-]+)+',
      Edit1.Text) then begin
    ShowMessage('La dirección de email no es válida');
    Edit1.SetFocus;
  end else
    ShowMessage('La dirección de email es válida');
end;

Les dejo el enlace

[[__hector]]

Puedes conectarte al servidor smtp del dominio al que quieres mandar el mail, y con un par de comandos, puedes saber si esa cuenta existe en dicho servidor. Digo, si te refieres a validar que existe, y no exactamente a validar la sintaxis de la direccion.

[AGAG4]

Muchas Gracias por sus respuestas, estoy tomando en cuenta todas sus opiniones, Que Tengan Buen Día....!!!!

[JXJ]

johncook

Una busqueda rapida, me llevo a sitios

http://anso.da.ru/
http://anso.virtualave.net/

Pero ya estan muertos.

¿¿Cual es el enlace. ??

gracias.

[jachguate]

Con la ayuda de algunos trucos, he llegado al nuevo sitio oficial de TRegExpr para delphi

Hasta luego.

[johncook]

Sorry, se me olvidó el enlace.... Pero es el que puso el amigo jachguate.. Gracias. Saludos.