Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Varios
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Grupo de Teaming del ClubDelphi

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 16-11-2006
Ricardo Alfredo Ricardo Alfredo is offline
Miembro
 
Registrado: may 2003
Ubicación: Santiago - Chile
Posts: 65
Poder: 21
Ricardo Alfredo Va por buen camino
bring to top de la aplicacion

Hola he busca sin éxito por el momento de como hacer que mi aplicación no se ejecute dos veces , si no que cuando ya se esta ejecutando "lanzarla" hacia a delante.

Lo que sucede que tengo varias aplicaciones y se pueden llamar entre ellas , pero sucede que si la invocas mas de una vez , te la abrirá y lo que quiero es que te la muestre para que sigas trabajando en lo que estabas.

Por ejemplo si uds. abren varias veces el Excel, este lo que hace es ejecutar varias veces las aplicación yo quiero lo contrario que solo se ejecute una vez hasta que le des cerrar.


gracias por la ayuda
Responder Con Cita
  #2  
Antiguo 16-11-2006
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 24
seoane Va por buen camino
Permiteme que te recomiende esta excelente unit del compañero roman

http://romansg.net/index.php?pg=uiapp
Responder Con Cita
  #3  
Antiguo 16-11-2006
Ricardo Alfredo Ricardo Alfredo is offline
Miembro
 
Registrado: may 2003
Ubicación: Santiago - Chile
Posts: 65
Poder: 21
Ricardo Alfredo Va por buen camino
gracias , la prove y funciona en forma estupenda.

Ahora otra preguntilla, es como puedo terminar un grupo de aplicaciones , estas por ejemplo yo tengo mi aplicacion principal que me llama a todas las demas , la idea es si el usuario se sale de esta yo termine con todas las que tenga abierta y esten relacionadas con la principal.



gracias
Responder Con Cita
  #4  
Antiguo 16-11-2006
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 24
seoane Va por buen camino
Bueno, en la unit de roman tienes un buen ejemplo de como usar la funciones RegisterWindowMessage y SendMessage para enviar mensajes de tipo BroadCast. En tu caso, solo tendrías que enviar un mensaje a todas las ventanas (usando HWND_BROADCAST), de esta manera cuando una de las otras aplicaciones reciba el mensaje sabrán que tienen que cerrarse y actuaran en consecuencia.

Si echándole un vistazo al código de roman, no te aclaras con el funcionamiento de RegisterWindowmessage y SendMessage, pasate otra vez por aquí e intentaremos echarte una mano.
Responder Con Cita
  #5  
Antiguo 17-11-2006
Ricardo Alfredo Ricardo Alfredo is offline
Miembro
 
Registrado: may 2003
Ubicación: Santiago - Chile
Posts: 65
Poder: 21
Ricardo Alfredo Va por buen camino
sabes , tuve un pequeño inconveniente con la unit de roman, sucede que yo tengo un sistema el cual contiene 6 aplicaciones, pues bien, debo cambiar los parametros sMutex y sActivar para generar la compilacion de la aplicacion, esto lo debo hacer tantas veces como apliaciones tenga, pero no habra alguna otra forma , por ejemplo dejar esas constantes en el dpr de cada aplicacion, lo trate de hacer de varias formas y no he logrado solucionar ese pequeño inconveniente, si tienen alguna idea me la pueden decir por favor.
Responder Con Cita
  #6  
Antiguo 17-11-2006
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 24
seoane Va por buen camino
No entiendo el problema. Es verdad que para cada aplicación tienes que utilizar un valor de sMutex y sActivar diferente porque precisamente se trata de diferencia unas aplicaciones de otras. Pero en el caso que mencionabas después, cerrar todas tus aplicaciones a la vez, debes de utilizar la misma cadena en todas de esta forma la orden de cerrar llegara a todas tus aplicaciones.

Lo dicho, puede que no este entendiendo cual es problema.
Responder Con Cita
  #7  
Antiguo 17-11-2006
Ricardo Alfredo Ricardo Alfredo is offline
Miembro
 
Registrado: may 2003
Ubicación: Santiago - Chile
Posts: 65
Poder: 21
Ricardo Alfredo Va por buen camino
si es cierto lo que dices, pero lo que ahora esta preguntando era de que modo puede cambiar los valors mutez y activar sin tener que crear una copia distinta para cada aplicacion , porque digo esto porque sabemos que esas dos constantes deben ir con valor distinto para tantas aplicaciones tenga, entoces la unica manera que he encontrado para es tener una copia de la unit de roman por tantas apliacaciones tenga, esto debido que no he encontrado la forma de pasar esas constantes a la unit de roman con valores distintos desde el dpr

lo otro que hablas tu estoy haciendo las pruebas y cambios necesario para ver si funciona, cuando lo logre te cuento
Responder Con Cita
  #8  
Antiguo 17-11-2006
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 24
seoane Va por buen camino
Se me ocurre una solución, modificamos la unit de roman de esta manera:
Código Delphi [-]
unit UIApp;

interface

uses
  Windows, SysUtils, Forms;

procedure Registrar(sActivar, sMutex: string);
procedure Activar;

implementation

var
  mActivar    : Cardinal; { Mensaje para activar la instancia anterior }
  Mutex       : Cardinal; { Mutex                                      }
  PrevWndProc : TFarProc; { Procedimiento de ventana original          }


function AppWndProc(Handle: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LongInt; stdcall;
var
  FgThreadId  : DWORD; { Hilo de la app. que tenga el foco }
  AppThreadId : DWORD; { Hilo de nuestra aplicación        }

begin
  if Msg = mActivar then
  begin
    { Si está minimizada basta restaurarla }
    if IsIconic(Handle) then
      ShowWindow(Handle, SW_RESTORE)
    else
    begin
      { Obtener los hilos }
      FgThreadId  := GetWindowThreadProcessId(GetForegroundWindow, nil);
      AppThreadId := GetWindowThreadProcessId(Handle, nil);

      { Anexar el hilo de nuestra app. al de la  que tenga el foco }
      AttachThreadInput(AppThreadId, FgThreadId, true);

      { Ahora sí, activar la applicación }
      SetForegroundWindow(Handle);

      { Separar el hilo de nuestra app de la otra }
      AttachThreadInput(AppThreadId, FgThreadId, false);
    end;

    Result := 0;
  end
  else
    { Dejar que el procedimiento original se encargue de los otros mensajes }
    Result := CallWindowProc(PrevWndProc, Handle, Msg, wParam, lParam);
end;

procedure Activar;
begin
  { Mandamos el mensaje a todas las ventanas }
  SendMessage(HWND_BROADCAST, mActivar, 0, 0);
end;

procedure Registrar(sActivar, sMutex: string);
begin
  mActivar := RegisterWindowMessage(sActivar);
  Mutex    := CreateMutex(nil, true, sMutex);

  { Si ya existe el mutex lanzamos una excepción silenciosa }
  if GetLastError = ERROR_ALREADY_EXISTS then
  begin
   Mutex := 0;
   abort;
  end
  else
  begin
    { Sustituimos el procedimiento de ventana }
    PrevWndProc := TFarProc(GetWindowLong(Application.Handle, GWL_WNDPROC));
    SetWindowLong(Application.Handle, GWL_WNDPROC, LongWord(@AppWndProc));
  end;
end;

initialization 

finalization
  if Mutex <> 0 then ReleaseMutex(Mutex);
end.

Luego en el dpr de nuestra aplicación, colocamos esto al principio:
Código Delphi [-]
 try
    Registrar(sActivar, sMutex); // SActivar, sMutex son constantes del dpr
  except
    Activar;
    Halt;
  end;

¿que te parece?
Responder Con Cita
  #9  
Antiguo 17-11-2006
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Está bien la modificación. Yo estaba pensando algo por la vía de

Código Delphi [-]
var
  {$include contantes.inc}
  // mActivar    : Cardinal; { Mensaje para activar la instancia anterior }
  // Mutex       : Cardinal; { Mutex                                      }
  PrevWndProc : TFarProc; { Procedimiento de ventana original          }

pero constantes.inc tendría que ser específico de la aplicación y no sé como inidicarle al $include una ruta que dependa de la aplicación. ¿En Delphi no hay 'magic constants'?

// Saludos
Responder Con Cita
  #10  
Antiguo 17-11-2006
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 24
seoane Va por buen camino
Roman, tanto hablar de ti ya se me hacia raro que no intervinieras.
Responder Con Cita
  #11  
Antiguo 17-11-2006
Ricardo Alfredo Ricardo Alfredo is offline
Miembro
 
Registrado: may 2003
Ubicación: Santiago - Chile
Posts: 65
Poder: 21
Ricardo Alfredo Va por buen camino
basicamente cambie lo que dice seoane, con un pequeño cambio que fue
procedure Registrar_APP(sActivar, sMutex: PAnsiChar);
ya que si lo dejo como string este es incompatible con cardinal.

y funciona correctamente por lo menos lo probe con 6 aplicaciones, ahora terminara con el resto con son 23 y vero como hacer el otro tema de si me cierran el principal cierre todos los "hijos"
Responder Con Cita
  #12  
Antiguo 17-11-2006
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Cita:
Empezado por seoane
Luego en el dpr de nuestra aplicación, colocamos esto al principio:
Todo esto está muy bien, pero se pierde la idea original de no tener que codificar nada, sólo incluir un archivo. Dándole vueltas un poco creo que he encontrado una solución.

Donde dice:

Código Delphi [-]
const
  { Cadenas para registrar el mutex y el mensaje }
  sMutex   = '10D73234-C9F7-4C2D-BC7E-39B5820AF456';
  sActivar = '3F154732-CCDE-4BC7-9439-AFCD3BCFA84D';

var
  mActivar    : Cardinal; { Mensaje para activar la instancia anterior }
  Mutex       : Cardinal; { Mutex                                      }
  PrevWndProc : TFarProc; { Procedimiento de ventana original          }

hay que cambiar a:

Código Delphi [-]
var
  { Cadenas para registrar el mutex y el mensaje }
  sMutex: String = '10D73234-C9F7-4C2D-BC7E-39B5820AF456';
  sActivar: String = '3F154732-CCDE-4BC7-9439-AFCD3BCFA84D';

  mActivar    : Cardinal; { Mensaje para activar la instancia anterior }
  Mutex       : Cardinal; { Mutex                                      }
  PrevWndProc : TFarProc; { Procedimiento de ventana original          }

es decir, promovemos las constantes a variables inicializadas.

Luego agregamos un procedimiento:

Código Delphi [-]
procedure LeerConstantes(var sActivar, sMutex: String);
var
  Archivo: TIniFile;
  sArchivo: String;

begin
  sArchivo := ExtractFilePath(Application.ExeName) + 'uiapp.ini';

  if FileExists(sArchivo) then
  begin
    Archivo := TIniFile.Create(sArchivo);

    try
      sActivar := Archivo.ReadString('constantes', 'activar', sActivar);
      sMutex := Archivo.ReadString('constantes', 'mutex', sMutex);
    finally
      Archivo.Free;
    end;
  end;
end;

Este procedimiento busca el archivo uiapp.ini en el directorio de la aplicación y sí existe, cambia los valores que se le pasan por los que tenga ese archivo.

Finalmente se introduce la llamada a LeerConstantes al principio:

Código Delphi [-]
initialization
  LeerConstantes(sActivar, sMutex);
  
  try
    Registrar;
  except
    Activar;
    Halt;
  end;

Así, el programador final sólo tiene que agregar el uiapp.pas en el uses del dpr e incluir un ini en su directorio:

Código:
[constantes]
activar=0E69F5F8-5AB5-4A31-B2DF-6A2467DEAC63
mutex=24B85122-DEEB-4939-8C34-5DF11B89D0B9
// Saludos
Responder Con Cita
  #13  
Antiguo 17-11-2006
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 24
seoane Va por buen camino
Pues a mi me se ocurre otra.

Dejar la unit tal cual esta en tu web. Y solo cambair estas dos lineas
Código Delphi [-]
  mActivar := RegisterWindowMessage(sActivar);
  Mutex    := CreateMutex(nil, true, sMutex);

Cambiarlas por:
Código Delphi [-]
  mActivar := RegisterWindowMessage(PChar(sActivar+ParamStr(0)));
  Mutex    := CreateMutex(nil, true, Pchar(sMutex+ParamStr(0)));
Responder Con Cita
  #14  
Antiguo 17-11-2006
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Sí, esta está mejor

// Saludos
Responder Con Cita
  #15  
Antiguo 17-11-2006
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Cita:
Empezado por seoane
Dejar la unit tal cual esta en tu web
Bueno sí, por el momento la unidad se queda tal cual en la web, pero eso no quita que podamos mencionar el cambio.

// Saludos
Responder Con Cita
  #16  
Antiguo 30-11-2006
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Hola,

Gracias a dec que me avisó de un pequeño problema con la modificación propuesta por seoane. Extrañamente no funciona y como no le encontraba ninguna lógica, lo mejor era irse a la documentación de CreateMutex:

Cita:
Código:
HANDLE CreateMutex(
  LPSECURITY_ATTRIBUTES lpMutexAttributes,
  BOOL bInitialOwner,
  LPCTSTR lpName
);
[...]

lpName

Points to a null-terminated string specifying the name of the mutex object. The name is limited to MAX_PATH characters and can contain any character except the backslash path-separator character (\).
y claro, ParamStr(0) contiene de esos caracteres. Al parecer se soluciona fácilmente poniendo algo como:

Código Delphi [-]
StringReplace(ParamStr(0), '\', '', [rfReplaceAll]);

// Saludos
Responder Con Cita
  #17  
Antiguo 30-11-2006
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 24
seoane Va por buen camino
Cita:
Empezado por roman
Hola,
Gracias a dec que me avisó de un pequeño problema con la modificación propuesta por seoane. Extrañamente no funciona y como no le encontraba ninguna lógica ...
Si, es MUY extraño que no funcione un código mio. Es broma, la verdad es que cuando lo dije se me ocurrió de pronto y no me paré a probarlo. De todas formas yo sustituiría '\' por '/', o por cualquier otro carácter que no pueda formar parte del nombre de un fichero para asegurarnos de que sigue siendo único.
Responder Con Cita
  #18  
Antiguo 30-11-2006
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Je, je, tienes razón, al colapsar puede perderse la unicidad:

ab\cd.exe => abcd.exe
a\bcd.exe => abcd.exe

Entonces habrá que sustituirlo por un caracter que no pueda formar parte de un nombre de archivo, como ? ó *.

// Saludos
Responder Con Cita
  #19  
Antiguo 25-02-2008
Avatar de German
German German is offline
Miembro
 
Registrado: may 2003
Ubicación: Barcelona - España
Posts: 133
Poder: 21
German Va por buen camino
Por "actualizar" un poco el hilo, hago un pequeño comentario, después de utilizar la unidad UIApp en D2007, y bajo Vista 64...

La función IsIconic(Handle) siempre devuelve False, y ShowWindow(Handle, SW_RESTORE) no restaura la aplicación. Debería utilizarse:
Código Delphi [-]
if IsIconic(Application.MainForm.Handle) then ShowWindow( Application.MainForm.Handle, SW_RESTORE)

Además, en el proc. "Registrar", la excepción silenciosa utilizada cuando ya existe el mutex, siempre es lanzada (o sea que se convierte en escandalosa), apareciendo el mensaje de diálogo, con lo que el try de initialization deja de tener sentido. Se podría solucionar de este manera...

Código Delphi [-]
(...)

procedure Registrar;
begin
  mActivar := RegisterWindowMessage(sActivar);
  Mutex    := CreateMutex(nil, true, sMutex);

  { Si ya existe , ponemos el mutex a cero }
  if GetLastError = ERROR_ALREADY_EXISTS then Mutex := 0
  else begin
    { Si no existe, sustituimos el procedimiento de ventana }
    PrevWndProc := TFarProc(GetWindowLong(Application.Handle, GWL_WNDPROC));
    SetWindowLong(Application.Handle, GWL_WNDPROC, LongWord(@AppWndProc));
  end;
end;

initialization
  Registrar;
  if Mutex = 0 then
  begin
    Activar;
    Halt;
  end;

(...)

El ejecutable resultante funciona tanto en XP como en Vista de forma correcta.

Salu2.
__________________
Tengo las manos llenas de dedos... Tengo los dedos llenos de teclas...
Tengo las teclas desordenadas... Tengo el desorden muy controlado...
Tengo el control en mis manos.

Última edición por German fecha: 25-02-2008 a las 07:06:22.
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
Diferencia entre aplicacion Clx y aplicación normal??? JorgeBec Varios 1 27-10-2004 18:30:49
aplicacion vertical? aplicacion horizontal? maruenda Varios 3 29-02-2004 00:23:20


La franja horaria es GMT +2. Ahora son las 12:06:54.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi