Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Varios
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 28-10-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Facturas electrónicas [España]

[Movido desde esta otra conversación]

Bueno, voy a aportar lo que tengo por ahora, que es la parte que crea el .XML (o .XSIG para la Admón. Pública) y lo firma con certificado digital o DNIe. Pero esto no puede quedarse ahí, hay que seguir con la tercera parte (que es la finalidad de este post), que es enviar la factura al webservice de face, a ver si entre todos lo conseguimos.

Con este código se puede crear un .XML (manualmente) y firmarlo para que sea válido y aceptado en la web de facturae. La web de facturae tiene un "validador online" aquí...
http://sedeaplicaciones2.minetur.gob.es/FacturaE/
...que nos servirá para comprobar si las facturas creadas son correctas, están bien firmadas, etc.

Componentes necesarios de SecureBlackBox: TEIWinCertStorage y TEIX509Certificate.
Otros componentes: TXMLDocument

(los componentes SecureBlackBox vienen con un montón de proyectos de ejemplo, entre ellos uno para firmar archivos PDF o XML).

Primera parte: crear el .XML

Yo he decidido crearlo "a mano". Un XML no es más que un archivo de texto con una estructura concreta, así que utilizo un Memo y le voy añadiendo las líneas con cuidado...
No voy a ponerlo todo porque es muy largo. Quizás más tarde subiré el código completo. El XML requiere un montón de valores variables que debemos rellenar (datos del emisor, receptor, factura, artículos, totales, impuestos...). Esta parte es algo tediosa, pero muy sencilla.

Antes de nada, cargamos los certificados digitales instalados en el sistema, por ejemplo en el OnCreate del Form1, en un ComboBox.
Esto hará que en el combobox veamos los certificados digitales instalados en Windows, ya sean certificados de empresa, el del DNIe, etc.
Nos harán falta más tarde para la firma del XML.

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
var i:integer;
begin
    for i := 0 to WinCertStorage.Count - 1 do
    begin
      Cert := WinCertStorage.Certificates[i];
      ComboCertificate.Items.Add('Título: ' + Cert.SubjectName.CommonName + ', Emisor: ' + Cert.IssuerName.CommonName);
    end;
end;

Empezamos a crear el XML a mano...

Código Delphi [-]
      memo1.Lines.Clear;
      memo1.lines.append('');
      memo1.lines.append(' xmlns:fe="http://www.facturae.es/Facturae/2009/v3.2/Facturae" xmlns:ds="http://www.w3.org/2000/09/xmldsig#"');
      memo1.lines.append('');
      memo1.lines.append('3.2');
      {.....}

Cuando tengamos todo el texto del XML, guardamos el memo en un archivo con extensión xml.

Código Delphi [-]
    memo1.Lines.SaveToFile('c:\pruebas\factura.xml');

Ahora abrimos el archivo con el componente XMLDocument para tenerlo ahí cargado, y lo volvemos a guardar. ¿por qué? Porque así se guarda bien estructurado, identado, etc. y es más fácil leerlo si nos hiciera falta.

Código Delphi [-]
    XMLDocument1.LoadFromFile(archivo);
    xmldocument1.Active:=true;
    xmldocument1.SaveToFile(archivo);

Y ahora a firmar...

Segunda parte: Firmar el XML

Este código no es mío. Tiene partes extraídas de clubdelphi, de los ejemplos de secureblackbox y de otros ejemplos de firma digital.
En el código le decimos qué certificado utilizar para la firma, de entre los cargados en el combobox anterior.
Probablemente el código se pueda mejorar. He dejado los comentarios del creador original porque explican bastante bien lo que se hace en él.

Código Delphi [-]
function Firma:boolean;
var XML_Doc:ElXMLDOMDocument;
    XML_Refs:TElXMLReferenceList;
    XML_RefDocu,XML_RefCert:TElXMLReference;
    XML_Signer:TElXMLSigner;
    XML_XAdES:TElXAdESSigner;
    XML_KeyData:TElXMLKeyInfoX509Data;
    XML_Nodo:ElXMLDOMNode;
    MS:TStream;
    XML_Buf:ByteArray;

    F: {$ifndef DELPHI_NET}TFileStream{$else}FileStream{$endif};
begin
    result:=false;
    with form1 do
    begin

          // ************************
          // ** Firmar fichero XML **
          // ************************

          XML_Doc:=     ElXMLDOMDocument.create;         //Documento XML a ser firmado
          XML_Refs:=    TElXMLReferenceList.create;          //Lista de nodos a ser firmados
          XML_RefDocu:= TElXMLReference.create;            //Nodo que representa al XML completo
          XML_RefCert:= TElXMLReference.create;             //Nodo del certificado utilizado
          XML_Signer:=  TElXMLSigner.Create(nil);            //Objeto firmante en XML...
          XML_XAdES:=   TElXAdESSigner.Create(nil);       //Sujeto firmante con info adicional XAdES
          XML_KeyData:= TElXMLKeyInfoX509Data.create(false); //Certificado a utilizar...

          try
            //Leo el fichero XML
            //==================
            // Por defecto en UTF-8 y normalizando los finales de linea (si llegan
            // CR+LF entonces la firma no se validará luego pues los digest no
            // deberían incluir estos CR+LF).

            {$ifndef DELPHI_NET}
            F := TFileStream.Create(archivo, fmOpenRead or fmShareDenyWrite);
            {$else}
            F := FileStream.Create(archivo, FileMode.Open, FileAccess.Read);
            {$endif}
            try
              XML_Doc.LoadFromStream(F, '', true);
            except
              on E : Exception do
              begin
                MessageDlg('Error: ' + E.Message, mtError, [mbOk], 0);
              end;
            end;

            FreeAndNil(F);

            if not XML_Doc.Loaded then
              raise Exception.create('Firma XML: No se pudo cargar el documento XML.');

            //Configuro el objeto firmador de XML
            //===================================
            // Se han de firmar la lista de nodos referenciados en XML_Refs
            XML_Signer.References:= XML_Refs;
            XML_Signer.SignatureMethodType:= xmtSig;
            // Se firma en formato "enveloped"
            XML_Signer.SignatureType:= xstEnveloped;
            // Se canoniza -ver ejemplos de la web facturae- el XML
            XML_Signer.CanonicalizationMethod:= xcmCanon;
            // La firma con el metodo mas estandar posible
            XML_Signer.SignatureMethod:= xsmRSA_SHA1;
            // La parte publica del certificado se debe incluir
            XML_Signer.IncludeKey:= true;
            // Necesito incrustar info adicional "XAdES" (XML Advanced Electronic Signatures )...
            XML_XAdES:= TElXAdESSigner.Create(nil);
            XML_Signer.XAdESProcessor:= XML_XAdES;

            //Configuro la parte XAdES del objeto firmador
            //============================================
            //
            // Se pide usar XAdES V1.2.2 o superior pero ha de ser "compatible" (?)
            // Algunos ejemplos usando V1.3.2 validan, asi que lo uso.
            XML_Signer.XAdESProcessor.XAdESVersion:= XAdES_v1_3_2;
            //SignerRole (en calidad de qué firmamos): supplier, customer o third_party
            //  Firmamos facturas emitidas por nosotros (supplier) en este caso.
            //  Si recibimos una factura firmada por el supplier, la podemos volver
            //  a firmar como que la damos por recibida usando "customer".
            //NOTA: El validador de www.facturae.es no comprueba este dato (2-2010)
            XML_Signer.XAdESProcessor.Included := [xipSignerRole];
            XML_Signer.XAdESProcessor.SignerRole.ClaimedRoles.AddText(
              XML_Signer.XAdESProcessor.XAdESVersion, XML_Doc, 'supplier');
            // La politica de firmado es la definida en el PDF V3.1 sobre firmado Facturae
            XML_Signer.XAdESProcessor.PolicyId.SigPolicyId.Identifier:= 'http://www.facturae.es/politica_de_firma_formato_facturae/politica_de_firma_formato_facturae_v3_1.pdf';
            //NOTA: Si vas a la web, este PDF esta en otro link diferente (WTF):
            //'http://www.facturae.es/es-ES/Documentacion/Politicas/Politicas/Versi%C3%B3n%203_1/Politica_Firma_formato_facturae_v3_1.pdf';
            XML_Signer.XAdESProcessor.PolicyId.SigPolicyId.Description:= 'Política de firma electrónica para facturación electrónica con formato Facturae';
            //Ahora el hash del propio PDF en SHA1 (en la web esta debajo del PDF)...
            XML_Signer.XAdESProcessor.PolicyId.SigPolicyHash.DigestMethod:= 'http://www.w3.org/2000/09/xmldsig#sha1';
            //El digest en SHA-1 de la web (en formato hex), esta MAL, no corresponde
            //con ese PDF, y ademas, en su ejemplo de la V3.0 el digest es correcto
            //y NO se corresponde con el digest que dan!
            // '613c46e7bac7df5b266e6be0349b5fe8bb4944e2' ESTA MAL EN LA WEB
            //Uso el digest SHA1 correcto generado a partir del PDF:
            SetLength(XML_Buf,0); //Evito un warning tonto
            if not HexStr2ByteArray('3A18B197ABA90FA6AFF0DEE912F0C006110BEA13', XML_Buf) then
              raise Exception.Create('Firma XML: Error convirtiendo digest de política de firmado a Base64.');
            {NOTA: Sustituido por  HexStr2ByteArray()
            XML_Digest:= LowerCase('3A18B197ABA90FA6AFF0DEE912F0C006110BEA13');
            SetLength(XML_Buf, Length(XML_Digest) div 2);
            //En delphi 7 HexToBin va bien, en Delphis mas moderno, no vale porque
            //WideChar y pChar se tratan de forma diferente, asi que se hace a mano.
              //HexToBin(PChar(XML_Digest), PChar(XML_Buf), Length(XML_Digest) div 2);
            for j:= 0 to Length(XML_Buf)-1 do begin
              k1:= SBMath.HexToDecDigit(XML_Digest[j*2 + 1]);
              k2:= SBMath.HexToDecDigit(XML_Digest[j*2 + 2]);
              if (k1<0) or (k2<0) then
                raise Exception.Create('Firma XML: Error convirtiendo digest de política de firmado a Base64.');
              XML_Buf[j]:= k1 shl 4 + k2;
            end;}

            XML_Signer.XAdESProcessor.PolicyId.SigPolicyHash.DigestValue:= XML_Buf;

            //-----------------------
            // FECHA/HORA DE LA FIRMA
            //-----------------------
            //Anoto la fecha y hora del firmado (del PC no es legalmente valida)

            XML_Signer.XAdESProcessor.SigningTime := LocalTimeToUTCTime(Now);

            //Pre-Genero los nodos de firmado necesarios
            //==========================================
            // Esta es la parte mas "confusa": He de firmar partes del XML que no
            // existen hasta que este firmado ¿Como? El objeto Signer, junto con el
            // prepocesador XAdES, crean esos nuevos nodos para que podamos
            // referenciarlos -decirle al firmador que son unas referecnias a ser
            // firmadas- y al final, al firmar, unira el XML original con estos
            // nuevos nodos -formato de firma "enveloped"- y se graba el XML final.
            //
            // Primero genero la zona de informacion XAdES:
            XML_Signer.XAdESProcessor.Generate;
            // Ahora, al objeto firmador "generico" le pido lo mismo, con lo que
            // tambien se crea el nodo "KeyInfo" con el certificado a utilizar.
            XML_Signer.UpdateReferencesDigest;
            //Cargo certificado para firmar
            //=============================
            // Cargo el certificado a usarse en la firma en el objeto firmador
            // NOTA: Se incluira la parte publica del certificado en base64.
            // De los certificados que me pases, elijo el primero con parte privada,
            // ya que no quiero incluir el certificado raiz del emisor (no se
            // menciona en la politica de firmado y no aparece en los ejemplos):

            XML_KeyData.IncludeKeyValue:= true;
           Cert := WinCertStorage.Certificates[comboCertificate.ItemIndex];
           if Cert.PrivateKeyExists then
               XML_KeyData.certificate:= Cert;

            //Compruebo que ha quedado algún certificado válido...
            if not Assigned(XML_KeyData.certificate) then
              raise Exception.create('FirmaXML: No se cargó un certificado válido para firmar, no contiene clave privada.');
            XML_Signer.KeyData:= XML_KeyData;
            //Añado a la lista de nodos a firmar
            //==================================
            //NOTA: El metodo SHA1 no es el mas seguro, pero el SHA256 no se usa mucho
            //y puede dar problemas (WinXP SP2 no lo admite) por eso el DNIe tampoco
            //lo usa aun, asi que mejor dejo el valor por defecto.
            //
            // NODO 1: Se ha de firmar el documento original XML completo...
            //
            XML_RefDocu.DigestMethod:= xdmSHA1; //El mas estandard/compatible de todos
            XML_RefDocu.URINode:= XML_Doc.DocumentElement; //El XML completo
            XML_RefDocu.URI:= ''; //No hay nombre especifico para este nodo
            // En los ejemplos aparece la transformacion "Enveloped-Signature"
            // aunque en el PDF de la firma V3.1 no lo menciona.
            XML_RefDocu.TransformChain.Add(TElXMLEnvelopedSignatureTransform.Create);
            XML_Refs.Add(XML_RefDocu); //Lo sumo a las cosas a ser firmadas
            // Actualizo digest con este nuevo nodo.
            XML_Signer.UpdateReferencesDigest;
            // NODO 2: Se han de firmar las propiedades de firmado (XAdES)....
            //
            // El nodo SignedProperties es parte de la informacion XAdES que se
            // creo en XML_Signer.XAdESProcessor.Generate y se firma siempre en
            // el standard XAdES. Dejo el codigo abajo como referencia solo, pero
            // no funcionaría si se activa porque ya esta siendo firmado una vez.
            //XML_Signer.XAdESProcessor.QualifyingProperties.SignedProperties.ID:= 'SignedPropertiesID';
            //XML_RefProp.DigestMethod:= xdmSHA1;
            //XML_RefProp.URI:= '#SignedPropertiesID';
            //XML_Refs.Add(XML_RefProp);
            //XML_Signer.UpdateReferencesDigest;
            //
            // NODO 3: Se ha de firmar el propio certificado utilizado
            //
            // El nodo KeyInfo ha de ir identificado por 'Certificate1' -segun los
            // ejemplos, el PDF no da ningun nombre concreto-
            // si se firma dos veces un mismo XML no chocan aunque el
            // nombre coincida por estar dentro de diferentes nodos "Signature".

            XML_RefCert.URI:= '#Certificate1';
            XML_RefCert.DigestMethod:= xdmSHA1;
            XML_Refs.Add(XML_RefCert); //Lo sumo a las cosas a ser firmadas
            //Como ya tengo todos los nodos, ahora genero la firma y consigo que
            //exista el nodo KeyInfo, de forma que pueda darle el nombre que le toca
            //antes de unir el XML original con el nuevo nodo de la firma.
            XML_Signer.Sign;
            XML_Signer.Signature.KeyInfo.ID:= 'Certificate1';
            //Añado la firma al XML
            //=====================
            XML_Nodo:= ElXMLDOMNode(XML_Doc.DocumentElement);
            XML_Signer.Save(XML_Nodo);
            //Actualizo el stream MS con el XML final firmado.

            {$ifndef DELPHI_NET}
            F := TFileStream.Create(archivo, fmCreate or fmOpenWrite);
            {$else}
            F := System.IO.FileStream.Create(archivo, FileMode.Create, FileAccess.ReadWrite);
            {$endif}
            try
              XML_Doc.SaveToStream(F, xcmNone, '');
            except
              on E : Exception do
              begin
                MessageDlg('Error: ' + E.Message, mtError, [mbOk], 0);
              end;
            end;
            FreeAndNil(F);

            result:= true;
          finally
            //NOTA: Los XML_Ref se destruyen solos junto al XML_Refs
            XML_Doc.free;
            XML_Refs.free;
            XML_Signer.free;
            XML_XAdES.free;
            XML_KeyData.Free;
          end;
    end;
end;

Y ya tenemos firmado nuestro XML. Y si el certificado es válido, la fecha/hora es válida, etc. entonces la factura electrónica es perfectamente legal. Podremos comprobarlo en la web de validación de facturae, que además nos dirá donde está el error, si lo hubiera.

IMPORTANTE:
Cuando la factura es para una Administración Pública, el .XML debe tener unas secciones obligatorias (Oficina contable, órgano gestor, etc.) y el archivo, en vez de tener extensión XML, lo guardaremos al final como .xsig. Y eso es todo.

Y ahora, lo difícil...

Enviar la factura al webservice...

Importamos el WSDL del webservice del face desde Delphi. Hay dos versiones, la de producción y la de desarrollo para pruebas. El de pruebas es este: https://se-face-webservice.redsara.es/sspp?wsdl

En el IDE, vamos a Component -> Import WSDL e indicamos la url anterior. Siguiente -> Siguiente y Finish.
Esto creará una unit llamada 'sspp.pas', que guardaremos en la misma carpeta de nuestro proyecto, y añadiremos al uses de nuestro form.

Y hasta aquí puedo leer. Y no porque no quiera seguir, sino porque no tengo ni idea.

Este es el código, supuestamente, para enviar la factura al webservice, pero antes hay que hacerle varias cosas que desconozco. Creo que incluso puede hacerse sin los SecureBlackBox, pero de verdad que estoy atascado.

Código Delphi [-]
var facturasspp : SSPPFactura;
    fichero_fac : SSPPFicheroFactura;
    answ : SSPPResultadoEnviarFactura;
    PO:SSPPWebServiceProxyPort;
begin
          PO := GetSSPPWebServiceProxyPort(FALSE, '', nil);
          facturasspp := ssppfactura.Create;
          facturasspp.correo := 'correo@micorreo.com';
          fichero_fac := ssppficherofactura.Create;
          fichero_fac.nombre := 'c:\pruebas\factura.xml';
          fichero_fac.factura := '12345';
          fichero_fac.mime := 'application/xml';
          facturasspp.fichero_factura := fichero_fac;

          try
            answ:=PO.enviarFactura(facturasspp);
          except
            on e:exception do showmessage(e.Message);
          end;
end;

Última edición por Ñuño Martínez fecha: 29-10-2015 a las 11:53:21. Razón: Movido desde otro hilo.
Responder Con Cita
  #2  
Antiguo 28-10-2015
Avatar de newtron
[newtron] newtron is offline
Membrillo Premium
 
Registrado: Apr 2007
Ubicación: Motril, Granada
Posts: 2.968
Poder: 14
newtron Va camino a la fama
Cita:
Empezado por espinete Ver Mensaje
Bueno, voy a aportar lo que tengo por ahora
Espinete, gracias por aportar tu código pero no es eso lo que te quería decir. Yo en particular no tengo las SBB y no podría usar ese código para firmar el fichero, y la verdad es que no me apetece comprar los componentes solo para eso. Lo que te decía es si puedes preparar un .exe que dándole el fichero de entrada y el de salida te firme el fichero de entrada y genere el de salida firmado para poder usarlo como programa externo.

Luego ya vendrá el tema del webservice (que yo en particular tampoco tengo ni idea).

Saludos
__________________
Be water my friend.
Responder Con Cita
  #3  
Antiguo 28-10-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Si le vas a dar uso a los componentes, porque los necesitas, no te quedará más remedio que comprarlos. De nada te sirve que te haga yo un ejecutable "puente", sin su código fuente, y que dentro de un mes pueda fallar, o requerir más parámetros, o requerir una nueva versión del SecureBlackBox, quedándote obsoleto. Lo de "no me apetece comprar los componentes solo para eso"... no sé, depende de a qué te refieras exactamente con "solo para eso". Yo creo que es bastante.

Tengo entendido que hay otras formas de firmar el XML sin usar los SecureBlackBox, pero lo desconozco. Este post es para intentar averiguar entre todos cómo enviar las facturas al webservice.
Responder Con Cita
  #4  
Antiguo 29-10-2015
Avatar de Neftali [Germán.Estévez]
Neftali [Germán.Estévez] Neftali [Germán.Estévez] is offline
[becario]
 
Registrado: Jul 2004
Ubicación: Barcelona - España
Posts: 15.657
Poder: 10
Neftali [Germán.Estévez] Tiene un aura espectacularNeftali [Germán.Estévez] Tiene un aura espectacular
Cita:
Empezado por espinete Ver Mensaje
Este es el código, supuestamente, para enviar la factura al webservice, pero antes hay que hacerle varias cosas que desconozco. Creo que incluso puede hacerse sin los SecureBlackBox, pero de verdad que estoy atascado.
Pues yo creo que ya tienes lo más complicado.
Para el tema del envío no hacen falta los BlackBox.

Un código similar al que pones debería funcionar:

Código Delphi [-]
var
  resultado:SSPPResultadoEnviarFactura;
  facturaWS:SSPPFactura;
begin

  facturaWS := SSPPFactura.Create();
  facturaWS.correo := ...
  ...

  // Según el rellenado llamamos a uno u otro
  resultado := (HTTPRIO1 as SSPPWebServiceProxyPort).enviarFactura(facturaWS);

La configuración del componente supongo que es la que toca:



A partir de ese punto, ¿obtienes algún error? ¿Alguna respuesta?
__________________
Germán Estévez => Web/Blog
Guía de estilo, Guía alternativa
Utiliza TAG's en tus mensajes.
Contactar con el Clubdelphi

P.D: Más tiempo dedicado a la pregunta=Mejores respuestas.
Responder Con Cita
  #5  
Antiguo 29-10-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Hola, Netfali

El error que obtengo es el mismo que utilizando la otra forma de hacer el envío:

La petición SOAP no está bien construida: No se encuentra el SOAP Header

El componente HTTPRIO está bien configurado (igual que en tu imagen).

Así ha quedado el código por ahora:

Código Delphi [-]
var facturasspp : SSPPFactura;
    fichero_fac : SSPPFicheroFactura;
    answ : SSPPResultadoEnviarFactura;
    PO:SSPPWebServiceProxyPort;
begin
    if opendialog1.Execute then   //Para elegir el .XML que queremos enviar al webservice
    begin
          PO := GetSSPPWebServiceProxyPort(FALSE, '', nil);
          facturasspp := ssppfactura.Create;
          facturasspp.correo := 'XXXXXXXXXX';

          fichero_fac := ssppficherofactura.Create;
          fichero_fac.nombre := extractfilename(opendialog1.FileName);
          fichero_fac.factura := '72345';
          fichero_fac.mime := 'application/xml';

          facturasspp.fichero_factura := fichero_fac;

          try
              answ := (HTTPRIO1 as SSPPWebServiceProxyPort).enviarFactura(facturasspp);
          except
              on e:exception do showmessage(e.Message);
          end;
    end;

end;
Responder Con Cita
  #6  
Antiguo 30-10-2015
Avatar de Neftali [Germán.Estévez]
Neftali [Germán.Estévez] Neftali [Germán.Estévez] is offline
[becario]
 
Registrado: Jul 2004
Ubicación: Barcelona - España
Posts: 15.657
Poder: 10
Neftali [Germán.Estévez] Tiene un aura espectacularNeftali [Germán.Estévez] Tiene un aura espectacular
No se si lo has puesto, no me ha parecido leerlo.
¿Con qué versión de delphi estás trabajando?
__________________
Germán Estévez => Web/Blog
Guía de estilo, Guía alternativa
Utiliza TAG's en tus mensajes.
Contactar con el Clubdelphi

P.D: Más tiempo dedicado a la pregunta=Mejores respuestas.
Responder Con Cita
  #7  
Antiguo 30-10-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Hola...

Con Delphi XE7 o con Delphi Seattle.

Un saludo
Responder Con Cita
  #8  
Antiguo 30-10-2015
Avatar de Neftali [Germán.Estévez]
Neftali [Germán.Estévez] Neftali [Germán.Estévez] is offline
[becario]
 
Registrado: Jul 2004
Ubicación: Barcelona - España
Posts: 15.657
Poder: 10
Neftali [Germán.Estévez] Tiene un aura espectacularNeftali [Germán.Estévez] Tiene un aura espectacular
Vale.
Es porque con los antiguos D6/D7 había un problema con las cabeceras de las Indy.
En algunos casos había que añadir algo manualmente.
__________________
Germán Estévez => Web/Blog
Guía de estilo, Guía alternativa
Utiliza TAG's en tus mensajes.
Contactar con el Clubdelphi

P.D: Más tiempo dedicado a la pregunta=Mejores respuestas.
Responder Con Cita
  #9  
Antiguo 30-10-2015
Avatar de Neftali [Germán.Estévez]
Neftali [Germán.Estévez] Neftali [Germán.Estévez] is offline
[becario]
 
Registrado: Jul 2004
Ubicación: Barcelona - España
Posts: 15.657
Poder: 10
Neftali [Germán.Estévez] Tiene un aura espectacularNeftali [Germán.Estévez] Tiene un aura espectacular
¿Puedes hacer algún envío envío de pruebas desde algún otro sitio? ¿Aplicación de ejemplo? ¿web?

Lo digo para intentar hacer un envío de ejemplo que funcione, y utilizando algún debugger (tipo Fiddler) intertar ver la cabecera completa que se está enviando.
Una vez que tengas la cabecera completa que se envía cuando el envío es correcto, intentar ver qué estás enviando cuanto utilizas la Indy y ver si hay diferencias.

No se si me explico...
__________________
Germán Estévez => Web/Blog
Guía de estilo, Guía alternativa
Utiliza TAG's en tus mensajes.
Contactar con el Clubdelphi

P.D: Más tiempo dedicado a la pregunta=Mejores respuestas.
Responder Con Cita
  #10  
Antiguo 30-10-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Hola

He hecho la prueba con el Fiddler 4 "escuchando". Tengo un montón de información, pero no sé cómo interpretarla o donde debo mirar.

Request Header:
Código:
POST /sspp HTTP/1.1
SOAPAction: "https://webservice.face.gob.es#enviarFactura"
Content-Type: text/xml; charset=utf-8
User-Agent: CodeGear SOAP 1.3
Host: se-face-webservice.redsara.es
Content-Length: 960
Connection: Keep-Alive
Cache-Control: no-cache
Request TextView:
Código:
<?xml version="1.0"?>
<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:SOAP-ENC="http://schemas.xmlsoap.org/soap/encoding/"><SOAP-ENV:Body xmlns:NS1="https://webservice.face.gob.es" SOAP-ENV:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/"><NS1:enviarFactura><facturaWS href="#1"/></NS1:enviarFactura><NS1:SSPPFactura id="1" xsi:type="NS1:SSPPFactura"><correo xsi:type="xsd:string">prueba@miemail.com</correo><fichero_factura href="#2"/><ficheros_anexos xsi:type="SOAP-ENC:Array" SOAP-ENC:arrayType="NS1:SSPPFicheroAnexo[0]"/></NS1:SSPPFactura><NS1:fichero_factura id="2" xsi:type="NS1:SSPPFicheroFactura"><factura xsi:type="xsd:string">72345</factura><nombre xsi:type="xsd:string">Factura 177.xml</nombre><mime xsi:type="xsd:string">application/xml</mime></NS1:fichero_factura></SOAP-ENV:Body></SOAP-ENV:Envelope>
Responder Con Cita
  #11  
Antiguo 30-10-2015
Avatar de Neftali [Germán.Estévez]
Neftali [Germán.Estévez] Neftali [Germán.Estévez] is offline
[becario]
 
Registrado: Jul 2004
Ubicación: Barcelona - España
Posts: 15.657
Poder: 10
Neftali [Germán.Estévez] Tiene un aura espectacularNeftali [Germán.Estévez] Tiene un aura espectacular
Dentro de "Inspectors" tienes los "Headers", la sección "Auth" y "Raw", que por ahora parece que es lo que nos debe interesar.

El siguiente paso sería comparar eso, con un envío correcto.
__________________
Germán Estévez => Web/Blog
Guía de estilo, Guía alternativa
Utiliza TAG's en tus mensajes.
Contactar con el Clubdelphi

P.D: Más tiempo dedicado a la pregunta=Mejores respuestas.
Responder Con Cita
  #12  
Antiguo 30-10-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Hola

En Fiddler tengo 4 procesos. Supongo que 2 envíos y dos respuestas. No sé muy bien cómo funciona fiddler y si debo mirar en la parte superior derecha o inferior derecha de cada evento:
1.jpg

En los envíos, la pestaña Auth dice lo siguiente:
Código:
No Proxy-Authorization Header is present.

No Authorization Header is present.
De todas formas, es demasiada información para poner aquí. La he exportado y subido aquí fiddler.zip
Responder Con Cita
  #13  
Antiguo 02-11-2015
Avatar de Ñuño Martínez
Ñuño Martínez Ñuño Martínez is offline
Moderador
 
Registrado: Jul 2006
Ubicación: Ciudad Catedral, Españistán
Posts: 5.721
Poder: 19
Ñuño Martínez Va camino a la famaÑuño Martínez Va camino a la fama
Veo un problema en esto: ¿Es imperativo usar SOAP? Lo digo por los que no usamos (o usamos poco) el Windows. La verdad es que no sé si ese protocolo está disponible para otros sistemas operativos (no sólo Linux, también UNIX, MacOS, Solaris, BSD, OS/400, eComStation...), pero teniendo en cuenta la deriva de la administración española en lo referente a nuevas tecnologías que en realidad no son tan nuevas, no sería la primera vez que hacen algo que únicamente puede usarse desde Windows (¡Hola, DNI electrónico!).
__________________
Proyectos actuales --> Allegro 5 Pascal ¡y Delphi!|MinGRo Game Engine
Responder Con Cita
  #14  
Antiguo 02-11-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Pues no lo sé, pero ya bastante tengo con que no lo consiga hacer desde Windows. Supongo que habilitarán más protocolos en el futuro.
Responder Con Cita
  #15  
Antiguo 02-11-2015
Avatar de Casimiro Notevi
Casimiro Notevi Casimiro Notevi is offline
Moderador
 
Registrado: Sep 2004
Ubicación: En algún lugar.
Posts: 28.391
Poder: 10
Casimiro Notevi Tiene un aura espectacularCasimiro Notevi Tiene un aura espectacular
Cita:
Empezado por espinete Ver Mensaje
.... Supongo que habilitarán más protocolos en el futuro.
Responder Con Cita
  #16  
Antiguo 02-11-2015
iMia iMia is offline
Miembro
 
Registrado: Jul 2010
Posts: 60
Poder: 9
iMia Va por buen camino
SOAP (Simple Object Access Protocol) no es exclusivo de windows... es un protocolo de comunicaciones, para el intercambio de información... Inicialmente en xml...

Espinete... seguramente el problema lo tienes que al importar el WSDL, hay que hacer un cambio por que el server Tomcat, requiere SOAP 1.1 y no 1.2...
¿donde? os preguntareis...

Al registrar las opciones de invocación, hay que cambiar el TypeInfo, del tipo ioDocument por ioDefault
con eso queda arreglado...

Código:
//  InvRegistry.RegisterInvokeOptions(TypeInfo(xxxx), ioDocument);
  InvRegistry.RegisterInvokeOptions(TypeInfo(xxxx), ioDefault);

Saludos
Responder Con Cita
  #17  
Antiguo 03-11-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Hola, iMia...

Gracias por tu aportación... pero tras importar el WSDL, en la unit resultante (sspp.pas), no hay ninguna referencia a InvRegistry.RegisterInvokeOptions(), por lo que no puedo sustituirlo (Delphi XE7 y Delphi Seattle).

Lo más parecido está en la parte initialization de esa unit:

Código Delphi [-]
initialization
  { SSPPWebServiceProxyPort }
  InvRegistry.RegisterInterface(TypeInfo(SSPPWebServiceProxyPort), 'https://webservice.face.gob.es', 'UTF-8');
  InvRegistry.RegisterDefaultSOAPAction(TypeInfo(SSPPWebServiceProxyPort), 'https://webservice.face.gob.es#%operationName%');
  {...}
  {...}

¿Dónde exactamente debo hacer el cambio que sugieres?
Responder Con Cita
  #18  
Antiguo 03-11-2015
iMia iMia is offline
Miembro
 
Registrado: Jul 2010
Posts: 60
Poder: 9
iMia Va por buen camino
Si correcto, lo acabo de importar para verlo...
y no aparece esa linea....
prueba de añadirla tal que...

Código:
 InvRegistry.RegisterInvokeOptions(TypeInfo(SSPPWebServiceProxyPort), ioDefault);
justo debajo de las dos que muestras...

Saludos...

Yo tambien en XE7...
Responder Con Cita
  #19  
Antiguo 03-11-2015
espinete espinete is offline
Miembro
 
Registrado: Mar 2009
Posts: 53
Poder: 10
espinete Va por buen camino
Hecho.

Pero sigue igual:

La petición SOAP no está bien construida: no se encuentra el SOAP Header.
Imágenes Adjuntas
Tipo de Archivo: png Sin título.png (3,1 KB, 8 visitas)
Responder Con Cita
  #20  
Antiguo 03-11-2015
iMia iMia is offline
Miembro
 
Registrado: Jul 2010
Posts: 60
Poder: 9
iMia Va por buen camino
Uffff...

Voy a probar..
pero al importar el wsdl, el codigo me da un error...
En la funcion "consultarListadoFacturas" el parámetro pone que es de tipo Array... pero no de que es ese array...

Código:
function consultarListadoFacturas(const listadoFacturas: Array): ArrayOfSSPPResultadoConsultarFactura; stdcall;
¿como lo has arreglado tu?
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
Facturas Electronicas Argentina Chaja Varios 3 10-07-2015 19:15:05
Agregar Adendas a Facturas electronicas mexico reypcs Varios 0 20-01-2011 16:26:10
Tabla de Facturas vs Detalles de Facturas magnu9 Conexión con bases de datos 9 27-07-2007 17:27:37
Comunicaciones electronicas EDI Toni Conexión con bases de datos 0 18-04-2006 13:06:34
Campos calculados, facturas y detalles de facturas. Letty Conexión con bases de datos 7 07-11-2003 11:19:44


La franja horaria es GMT +2. Ahora son las 12:56:23.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi