Imprimir la imagen de un PaintBox en Rave report

[marcelocarazas]

Estimados amigos, tengo un problema necesito imprimir la imagen de un PaintBox en un reporte de RAVE REPORT
espero su ayuda.

Código Delphi [-]
Bitmap.LoadFromFile('imagenes/final.bmp'); // tenemos la direccion de la imagen, pero yo quiero cargar la imagen de un PaintBox
PrintBitmap(0.4, 0.3, 1, 1, Bitmap);

gracias y saludos

[marcelocarazas]

Estimados necesito su ayuda tengo un Paint Box y necesito imprimir el contenido del PaintBox en un reporte de rave report

Espero su ayuda

Saludos Marcel Carazas

[Casimiro Notevi]

No crees hilos nuevos para seguir con lo mismo, gracias

[marcelocarazas]

Esta bien, ahora me pueden ayudar necesito solucionar este tema urgente
Gracias

[Casimiro Notevi]

necesito solucionar este tema urgente

[[nlsgarcia]]

marcelocarazas,

Empezado por marcelocarazas

...necesito imprimir la imagen de un PaintBox en un reporte de RAVE REPORT...

Revisa esta información:

Introduction to Rave Reports - Part I: Code Based Reports

Introduction to Rave Reports - Part II: Visual Designer

Introduction to Rave Reports - Part III: Data Aware Reports

Introduction to Rave Reports - Part IV: More Data Aware Reports

Creando informes con Rave Reports (I)

Creando informes con Rave Reports (II)

Creando informes con Rave Reports (III)

Creando informes con Rave Reports (IV)

Creando informes con Rave Reports (y V)

Espero sea útil

Nelson.

[marcelocarazas]

Gracias por responder Nelson, pero lo que necesito es poder imprimir la imagen de un PaintBox en mi reporte de Rave Report.
Para cargar la imagen al reporte de utiliza la siguiente instruccion

Código Delphi [-]

Bitmap.LoadFromFile('delphi.bmp');
PrintBitmap(3.5,0.3,1,1, Bitmap);

quiero imprimir un codigo QR la cual se genera en un paintBox

Saludos, y perdon por escribir de esa manera pero necesito solucionar el tema.

Gracias

[Casimiro Notevi]

goto 5


.

.

[[nlsgarcia]]

marcelocarazas,

Empezado por marcelocarazas

...lo que necesito es poder imprimir la imagen de un PaintBox en mi reporte de Rave Report...

Revisa el link : Introduction to Rave Reports - Part I: Code Based Reports, alli hay un ejemplo de impresión de un Bitmap en Rave Report, quizás te sea útil

Saludos,

Nelson.

[marcelocarazas]

Ya rebice ese link pero lo que busco es imprimir El componente PaintBox que la imagen se genera dinamicamente y imprimirlo en mi reporte

[ecfisa]

Hola marcelocarazas.

No había usado Rave Reports, pero basándome en la muy buena documentación que te ha facilitado nlsgarcia, te hice este ejemplo:

Código Delphi [-]
...
implementation

var
  Bitmap: TBitmap = nil;

// Hacer un dibujo
procedure TForm1.PaintBox1Paint(Sender: TObject);
begin
  with PaintBox1 do
  begin
    Canvas.Brush.Style:= bsClear;
    Canvas.Brush.Color:= clYellow;
    Canvas.Ellipse((Width div 2)-30,(Height div 2)-30,
                   (Width div 2)+30,(Height div 2)+30);
                   Canvas.Pen.Color:= clRed;
    Canvas.Pen.Width:= 2;
    Canvas.Pen.Style:= psSolid;
    Canvas.MoveTo(0,0);
    Canvas.LineTo(Width,Height);
  end;
end;

// PaintBox -> Bitmap -> Rave
procedure TForm1.btnPrintClick(Sender: TObject);
begin
  if not Assigned(Bitmap) then
  begin
    Bitmap:= TBitmap.Create;
    Bitmap.Width:= PaintBox1.Canvas.ClipRect.Right;
    Bitmap.Height:= PaintBox1.Canvas.ClipRect.Bottom;
    BitBlt(Bitmap.Canvas.Handle,
           0,
           0,
           Bitmap.Width,
           Bitmap.Height,
           PaintBox1.Canvas.Handle,
           0,
           0,
           SRCCOPY);
     RvSystem1.Execute;
  end;
end;

// TRvSystem OnPrint
procedure TForm1.RvSystem1Print(Sender: TObject);
begin
  with TBaseReport(Sender) do
    PrintBitmap(1,1,1,1, Bitmap);
  Bitmap.Free;
  Bitmap:= nil;
end;

Resultado:


Saludos

[[nlsgarcia]]

Daniel,

Empezado por ecfisa

...No había usado Rave Reports...hice este ejemplo...

Nelson.

[marcelocarazas]

Muchas gracias ecfisa, voy a probarlo pero parece que es lo que necesito.

[Casimiro Notevi]

No se podrán quejar, además, gratis

[marcelocarazas]

funciona, pero como haria si el objeto paintbox esta con la propiedad visible esta en false ya que imprime cuando el objeto esta visible

Gracias y saludos

[ecfisa]

Hola marcelocarazas

Empezado por marcelocarazas

funciona, pero como haria si el objeto paintbox esta con la propiedad visible esta en false ya que imprime cuando el objeto esta visible

Bueno... Pero supongo que en algún momento estará visible, si no ¿ Como sabría el usuario que es lo que va a imprimir ?

Entonces basta con pasar previamente el contenido del PaintBox al Bitmap (luego da igual si el PaintBox está visible u oculto, lo limpias o lo destruyes).

Código Delphi [-]
var
  Bitmap: TBitmap;

// Pasa el contenido del PaintBox al Bitmap
procedure PaintBoxToBitmap(PB: TPaintBox; BM: TBitmap);
begin
  BM.Width := PB.Canvas.ClipRect.Right;
  BM.Height:= PB.Canvas.ClipRect.Bottom;
  BitBlt(BM.Canvas.Handle,
         0,
         0,
         BM.Width,
         BM.Height,
         PB.Canvas.Handle,
         0,
         0,
         SRCCOPY);
end;

// OnCreate Form1
procedure TForm1.FormCreate(Sender: TObject);
begin
  Bitmap:= TBitmap.Create;
end;

// Hacer un dibujo
procedure TForm1.PaintBox1Paint(Sender: TObject);
begin
  with PaintBox1 do
  begin
    Canvas.Brush.Style:= bsClear;
    Canvas.Brush.Color:= clYellow;
    Canvas.Ellipse((Width div 2)-30,(Height div 2)-30,
                   (Width div 2)+30,(Height div 2)+30);
                   Canvas.Pen.Color:= clRed;
    Canvas.Pen.Width:= 2;
    Canvas.Pen.Style:= psSolid;
    Canvas.MoveTo(0,0);
    Canvas.LineTo(Width,Height);
  end;
end;

// Pasar PaintBox a Bitmap cuando esté visible,
// luego puedes hacer lo que desees con el primero
procedure TForm1.btnPBoxToBmpClick(Sender: TObject);
begin
  PaintBoxToBitmap(PaintBox1, Bitmap);
end;

// Bitmap -> Rave
procedure TForm1.btnPrintClick(Sender: TObject);
begin
  if not Bitmap.Empty then
    RvSystem1.Execute;
end;

// TRvSystem OnPrint
procedure TForm1.RvSystem1Print(Sender: TObject);
begin
  with TBaseReport(Sender) do
    PrintBitmap(1,1,1,1, Bitmap);
end;

// Liberar memoria
procedure TForm1.FormDestroy(Sender: TObject);
begin
  Bitmap.Free;
end;

Saludos