La discreción de los archivos Jpeg

[jorge1987]

Empezado por seoane

Para todos aquellos que estéis preocupados por vuestra intimidad, o simplemente queréis eliminar toda esa basura para dejar vuestros archivos jpeg mas livianos, podéis usar el truco 34, donde pongo el código necesario para eliminar los "segmentos de aplicación" (este es el nombre que reciben) de los archivos jpeg. Si alguien se anima puede meter esto dentro de un bucle que limpie todo un directorio ... ahi dejo la idea

OK, con ese truco, borra dicha info?

Y como puedo hacer para revisar y poder ver en el caso de que exista, dicha informacion??

Saludos

[[seoane]]

Empezado por jorge1987

Y como puedo hacer para revisar y poder ver en el caso de que exista, dicha informacion??

Te recomiendo para eso que utilices algún programa como photoshop, gimp, photostudio, etc.

Aunque para seguir experimentando podemos jugar un poco con el formato Exif e intentar sacarlo con el siguiente código. Básicamente busca dentro del jpeg el segmento que contiene la información Exif, una vez lo tiene busca la marca $FFD8 que indica el inicio de una imagen jpeg. Esto no es la forma mas correcta de hacerlo, ya que nos saltamos toda la estructura de datos Exif, pero el caso es que funciona y para jugar un rato nos sirve.

El codigo:

Código Delphi [-]
function ReadThumb(Source, Dest: TStream): Boolean;
var
  Buffer: array[0..$FFFF] of Char;
  Header: array[1..4] of byte;
  Size: Integer;
  i: Integer;
begin
  Result:= FALSE;
  Source.Seek(0,soFromBeginning);
  Source.ReadBuffer(Header,2);
  if (Header[1] <> $FF) or (Header[2] <> $D8) then
    raise Exception.Create('Identificador incorrecto');
  repeat
    Source.ReadBuffer(Header,4);
    Size:= ((Header[3] shl 8) + Header[4]) - 2;
    case Header[2] of
      $E1: begin
        Source.ReadBuffer(Buffer,Size);
        i:= 0;
        while i < Size - 1 do
        begin
          if CompareMem(@Buffer[i],PChar(#$FF#$D8),2) then
          begin
            Dest.WriteBuffer((@Buffer[i])^, Size - i);
            Result:= TRUE;
            break;
          end;
          inc(i);
        end;
        break;
      end;
      $01,$D0..$D9: Source.Seek(-2,soFromCurrent);
      else Source.Seek(Size,soFromCurrent);
    end;
  until (Header[2] = $DA);
end;

procedure ExtractThumb(Filename: string);
var
  Source: TFileStream;
  Thumb: TMemoryStream;
begin
  Source:= TFileStream.Create(Filename, fmOpenRead);
  try
    Thumb:= TMemoryStream.Create;
    try
      if ReadThumb(Source,Thumb) then
        Thumb.SaveToFile(ChangeFileExt(Filename,'_thumb.jpg'));
    finally
      Thumb.Free;
    end;
  finally
    Source.Free;
  end;
end;

// Por ejemplo
  ExtractThumb('D:\1.jpg');

En el ejemplo anterior si "d:\1.jpg" contiene un imagen en miniatura, se guardara en el archivo "d:\1_thumb.jpg", y si no contienen ninguna no se crea ningún fichero. Ahora solo tenemos que buscar un directorio con un buen numero de jpegs y hacerlo con todas las imágenes para ver si descubrimos algo