Como cambiar el color de una fila del Grid de ibobjects

[fly]

¿Y si haces un TypeCast? (no se como se dice en cistiano ) ; "engañas" al compilador para que crea que la tabla es de una DBGrid y así usas sus propiedades, claro está que sólo funcionará si son compatibles.

Sería algo así:

Código Delphi [-]
procedure IB_Grid1DrawCell(Sender: TObject; ACol,
  ARow: Integer; Rect: TRect; State: TGridDrawState);
begin 

if TDBGrid(Sender).DataSource.Dataset.FieldbyName('ESTADO').AsString = 'Seguimiento' then
 if (gdFocused in State)
    then TDBGrid(Sender).canvas.brush.color := clBlack
    else TDBGrid(Sender).canvas.brush.color := $00D5FFFF;
end;

yo lo uso para obtener el valor ROW de un DBGrid :

Código Delphi [-]
indice_grid:=TStringGrid(DBGrid1).Row;

No he podido probar el ejemplo que te pongo porque no tengo ibobjects ya me contaras si es lo que buscas.

Saludos y suerte.

[kovaski]

Hola.

Te agradezco fly tu respuesta.

He probado tu sugerencia pero no son compatibles, de echo el ib_grid de ibobjecs me parece que no desciende del TDBGrid, y claro esta me da error en ejecución.

Lo cierto que estoy un poco frustrado(jeje). Porque necesito pintar las dichosas lineas ya que es una pieza clave en la claridad de mi programa. Y la razón por la que uso ib_grid de ibobjects es porque en aplicaciones cliente/servidor por internet me parece mucho más rapido y polivalente que los Grid normales, puesto que estan diseñados especificamente para estos entornos.

Seguire investigando(que remedio :-)).

Con todo os seguire agradeciendo vuestras sugerencias.

Saludos.

[fly]

Aun no lo tengo del todo pero algo va haciendo...

Código Delphi [-]
procedure TCobros_f.IB_Grid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin
 IB_Grid1.Canvas.Brush.Color := $991122;
 IB_Grid1.Canvas.Font.Color := $CC55DD;
 valor:='aqui hay que encontrar el valor del campo a mostrar';
 IB_Grid1.DefaultDrawCell(acol,arow,rect,state,VALOR,taCenter);
end;

Esto funciona, y pinta la celda de un color y el texto de otro, pero necesita que al terminar de asignar los colores y demás se llame al procedimiento DefaultDrawCell para que pinte la celda con los valores asignados anteriormente al canvas.

No se como asignar a la variable VALOR el contenido del campo actual, así que por ahora este código solo sirve para pintar el grid de colores con un valor constante.... pero ya es algo

Cuando tenga un rato sigo con el tema.

[kovaski]

Al fin he dado con la solución al problema .

Aqui la pongo para quien le pueda servir. Gracias fly por tu tiempo e interes.

En primer lugar hay que poner la propiedad "DefDrawBefore" del ib_Grid en "True"(por defecto).

En el "uses" hay que poner "IB_Components".

Tenemos que atacar el evento "OnGetCellProps" del ib_Grid y escribimos lo siguiente:

Código Delphi [-]
procedure TFichaOfertas.IB_Grid1GetCellProps(Sender: TObject; ACol,
  ARow: Integer; AState: TGridDrawState; var AColor: TColor; AFont: TFont);
var
  Datos: string;
  Columnas: TIB_Column;
begin
//Este código es para pintar solo la celda del campo "ESTADO" que tiene la palabra "Activo"
if Tablas.dsOfertas.Active then
  begin
    with Tablas.dsOfertas.Dataset do
    begin
      BufferRowNum:= ib_Grid1.DataRow[ARow];
      if BufferRowNum > 0 then
       begin
        Columnas:= ib_Grid1.GridFields[ib_Grid1.DataCol[ACol]];
         if Assigned(Columnas) and (Columnas.FieldName = 'ESTADO') then
           begin
             Datos:= BufferFieldByName('ESTADO').AsString;
             if Datos = 'Activo' then
              if Acolor = ib_Grid1.Color then
                AColor:= clLime;
           end;
       end;
    end;
  end;
//Este código es para pintar la fila completa que tiene el campo "ESTADO" la palabra "Activo"
if Tablas.dsOfertas.Active then
  begin
    with Tablas.dsOfertas.Dataset do
    begin
      BufferRowNum:= ib_Grid1.DataRow[ARow];
      if BufferRowNum > 0 then
       begin
       Datos:= BufferFieldByName('ESTADO').AsString;
       if Datos = 'Activo' then
         if Acolor = ib_Grid1.Color then
          AColor:= clRed;
       end;
    end;
  end;

end;

Gracias por vuestra ayuda. Saludos .

[fly]

Me alegro que se pudiera resolver, por mi parte seguiré "fedellando" con los ibobjets pues si que he notado demasiadas pegas en las aplicaciones cuando las corro a traves de internet.

saludos.