TListview y añadir elementos...

[MaMu]

Empezado por roman

¿Intentaste lo del modo virtual? Aquí tengo un par de ejemplos de ListView para mostrar archivos de una carpeta. Uno en modo normal y el otro en modo virtual. Pruébalos abriendo una carpeta con muchos archivos como c:\windows\system32 y ve la diferencia.

// Saludos

roman, hay forma de generar una vista de thubnails como el explorador de windows, en estos dos metodos de agregado de items del ListView?

Saludos

[lag_0]

Empezado por MaMu

roman, hay forma de generar una vista de thubnails como el explorador de windows, en estos dos metodos de agregado de items del ListView?

Saludos

Claro, solo has de manejar la imagen que pinta, apartir de ese codigo (muy bueno por cierto) no es demasiado complicado, o siempre puedes dibujar en on draw item...

[lag_0]

Me acabo de dar cuenta que el problema está en las comparaciones....
Uf... esto es lo peor... Solo son cadenas de texto qeu se comparan, además 4 cadenas con otras 4 por cada item que añado y tarda..... UF COMO TARDA!!! no entiendo qeu peude estar pasando, incluso dejando un simple if de las length se demora el additem un segundo por cada item... lo cual no es normal T________T....

Tiene alguna explicación? Pego el codigo...

Código Delphi [-]
function TfP.TraduceSMtoDB(Tipo:string;TextoA:string;TextoB:string):bool;
var
 TempI : integer;
 UCAa, UCAb:string;
begin
  TextoA := UpperCase(TextoA);
  TextoB := UpperCase(TextoB);
  Result := False;
  if ReplaceText(TextoA,' ','_') = ReplaceText(TextoB,' ','_') then begin
    Result := True;
    Exit;
  end;
  for TempI := 0 to ruleslist.Items.Count-1 do begin
     UCAa := UpperCase(ruleslist.Items.Item[TempI].SubItems.Strings[0]);
     UCAb := UpperCase(ruleslist.Items.Item[TempI].SubItems.Strings[1]);
     if ((TextoA = UCAa) or (TextoA = UCAb)) and ((TextoB = UCAa) or (TextoB = UCAb)) then begin
       if ((Tipo = 'n') and (ruleslist.Items.Item[TempI].Caption = 'Nombre')) or ((Tipo = 'i') and (ruleslist.Items.Item[TempI].Caption = 'IP')) or ((Tipo = 'd') and (ruleslist.Items.Item[TempI].Caption = 'Display Name')) or ((Tipo = 'm') and (ruleslist.Items.Item[TempI].Caption = 'Modelo')) then begin
         Result := true;
         Exit;
       end;
     end;
  end;
end;

Alguna idea? T_T muchas gracias...

[MaMu]

Empezado por lag_0

Claro, solo has de manejar la imagen que pinta, apartir de ese codigo (muy bueno por cierto) no es demasiado complicado, o siempre puedes dibujar en on draw item...

Lo que pasa es que con GetSystemImage lo que obtengo es el ícono asociado a la extensión del archivo:

Código Delphi [-]
procedure TMainForm.GetSystemImages;
const
 shgfiLarge = SHGFI_SYSICONINDEX or SHGFI_LARGEICON;
  shgfiSmall = SHGFI_SYSICONINDEX or SHGFI_SMALLICON;
var
 ShFileInfo: TShFileInfo;
 iLarge: Cardinal;
  iSmall: Cardinal;
begin
 iLarge := ShGetFileInfo('', 0, ShFileInfo, SizeOf(ShFileInfo), shgfiLarge);
  iSmall := ShGetFileInfo('', 0, ShFileInfo, SizeOf(ShFileInfo), shgfiSmall);
 ListView_SetImageList(lvwFiles.Handle, iLarge, LVSIL_NORMAL);
 ListView_SetImageList(lvwFiles.Handle, iSmall, LVSIL_SMALL);
end;

Modo Virtual (OwnerData:=True)

Ahora bien, según interpreto el código expuesto por roman, el dato importante para trabajar con el ListView es el Item.Index, es el principal, en base a la lista creada con los elementos (la cantidad la muestro con AllocBy)
en el evento OnData, cargo los nombres de cada elemento (Item.Caption).
Para dibujar un thumbnail de cada elemento tendría mi código en:

Código Delphi [-]
 
procedure TMainForm.lvwFilesDrawItem(Sender: TCustomListView;
  Item: TListItem; Rect: TRect; State: TOwnerDrawState);
begin
end;

Pero que pasa con la propiedad OwnerDraw?.
En el evento OnDrawItem tendría que:

1. Generar el thumbnail del elemento
2. Dibujar el thumbnail del elemento
3. OwnerDraw True

es correcto?

Como sería un ejemplo de generar un thumbnail de un elemento de la lista y agregarlo al ListView?

PD: me resulta muy interesante todo este tema ya que, me gustaria generar un componente derivado del TShellListView, por el solo hecho de añadirle la propiedad ViewStyle [vsThumbs] + [ vsIcon, vsList, vsReport, vsSmallIcon]
y poder visualizar como Thumbnails, estilo Explorardor de Windows

Saludos y gracias

[lag_0]

Mi idea para eso:
-añade un timagelist....
-Cuando exploren un directorio haces una búsqueda de todos los JPG y bmp y demás cargando cada imagen en el objeto que has creado antes... asegurate de hacerlo por orden alfabetica y de vaciar el timagelist antes de cargar...
-Cargas el listview con los ficheros del directorio ordenas por orden alfabetica el listview.
-Te aseguras de que el imagelist esté asociado al listview...
-pones el image index el indice de cada elemento y como son alfabeticos encajarán... Si quieres que la propiedad con la que se vea no sea icons solo tendrás que pintar la imagen asociada al elemento por imageindex al tamaño que tu quieras y como quieras... no es muy dificil prueba primero cambiar el font, color de texto etc del elemento y verás como sabiendo hacer eso llegas a cualquier sitio.
y listo.

[MaMu]

Empezado por lag_0

Mi idea para eso:
-añade un timagelist....
-Cuando exploren un directorio haces una búsqueda de todos los JPG y bmp y demás cargando cada imagen en el objeto que has creado antes... asegurate de hacerlo por orden alfabetica y de vaciar el timagelist antes de cargar...
-Cargas el listview con los ficheros del directorio ordenas por orden alfabetica el listview.
-Te aseguras de que el imagelist esté asociado al listview...
-pones el image index el indice de cada elemento y como son alfabeticos encajarán... Si quieres que la propiedad con la que se vea no sea icons solo tendrás que pintar la imagen asociada al elemento por imageindex al tamaño que tu quieras y como quieras... no es muy dificil prueba primero cambiar el font, color de texto etc del elemento y verás como sabiendo hacer eso llegas a cualquier sitio.
y listo.

buenísima explicación, me voy a poner a jugar con el Listview y ver que sale!!!.

Saludos

[MaMu]

La verdad es que no entiendo como pasarlo a modo virtual, ya que quiciera probarlo puesto a que quiero trabajaron con centenares de imagenes.

Con un Form, un Button, un ImageList, un ListView y un Image, les dejo mi codigo para visualizar como thumbnails las imagenes jpg contenidas en una carpeta.

Alguien me ayuda a como pasarlo a modo virtual??? quizas asi me de cuenta.
Les agradezco de antemano. Me baje los ejemplos, y aun asi no he conseguido pararlo a virtual, me resulto interesante el comentario de "KeyBoy"

Aqui les va mi codigo, a ver si me ayudan a modificarlo:

Código Delphi [-]
unit Unit1;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, ExtCtrls, ImgList;
type
  TForm1 = class(TForm)
    ListView1: TListView;
    Button1: TButton;
    Image1: TImage;
    ImageList1: TImageList;
    procedure Button1Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
var
  Form1: TForm1;
  lista: TStrings;
  
implementation
{$R *.dfm}
uses ActiveX, ShlObj, ComObj;
type
 IExtractImage = interface ['{BB2E617C-0920-11d1-9A0B-00C04FC2D6C1}']
   function GetLocation(pszPathBuffer: LPWSTR; cchMax: DWORD; 
var pdwPriority: DWORD; const prgSize: SIZE; dwRecClrDepth: DWORD; 
var pdwFlags: DWORD): HRESULT; stdcall;
  function Extract(var phBmpImage: HBITMAP): HRESULT; stdcall;
 end;
function GetThumbnail(lpPathName, lpFileName: PWideChar; Width, Height: Integer): TBitmap;
var
 Desktop, Folder: IShellFolder;
 ItemIDList: PItemIDList;
 Flags, Priority: Cardinal;
 ExtractImage: IExtractImage;
 Res: HRESULT;
 hBitmap: Windows.HBITMAP;
 Buffer: array[0..MAX_PATH-1] of WideChar;
 Size: TSize;
begin
 Result := nil;
 SHGetDesktopFolder(Desktop);
 if LongBool(Desktop.ParseDisplayName(0, nil, lpPathName, PDWORD(0)^, ItemIDList, PDWORD(0)^)) then Exit;
 Desktop.BindToObject(ItemIDList, nil, IShellFolder, Folder);
 CoTaskMemFree(ItemIDList);
 if LongBool(Folder.ParseDisplayName(0, nil, lpFileName, PDWORD(0)^, ItemIDList, PDWORD(0)^)) then Exit;
 Folder.GetUIObjectOf(0, 1, ItemIDList, IExtractImage, nil, ExtractImage);
 CoTaskMemFree(ItemIDList);
 if not Assigned(ExtractImage) then Exit; // TODO
 Size.cx := Width; Size.cy := Height; Priority := 0;
 Flags := $28{IEIFLAG_SCREEN+IEIFLAG_OFFLINE};
 Res := ExtractImage.GetLocation(Buffer, SizeOf(Buffer), Priority, Size, 24{pf32bit}, Flags);
 if (Res = NOERROR) or (Res = E_PENDING{IEIFLAG_ASYNC}) then
  begin
   if not LongBool(ExtractImage.Extract(hBitmap)) then
    begin
     Result := TBitmap.Create;
     Result.Handle := hBitmap;
    end;
  end;
end;

procedure BuscarArchivos(const directorio, mascara: string;
  atributos: Integer; var listado: TStrings);
  // Procedimiento anidado
  //
  procedure Buscar(const subdirectorio: string);
  var
    regBusqueda: TSearchRec;
  begin
    // Buscar en el directorio
    if FindFirst(subdirectorio + mascara,atributos,regBusqueda) = 0 then
    begin
      try
        repeat
          Application.ProcessMessages;
          if (regBusqueda.Attr and faDirectory = 0)
            or (regBusqueda.Name <> '.')
              and (regBusqueda.Name <> '..') then
                listado.Add(subdirectorio + regBusqueda.Name);
        until FindNext(regBusqueda) <> 0;
      except
        FindClose(regBusqueda);
      end;
      FindClose(regBusqueda);
    end;
    // Buscar en los subdirectorios
    if FindFirst(subdirectorio + '*', atributos
      or faDirectory, regBusqueda) = 0 then
    begin
      try
        repeat
          Application.ProcessMessages;
          if ((regBusqueda.Attr and faDirectory) <> 0)
            and (regBusqueda.Name <> '.')
              and (regBusqueda.Name <> '..') then
                Buscar(subdirectorio + regBusqueda.Name + '\');
        until FindNext(regBusqueda) <> 0;
      except
        FindClose(regBusqueda);
      end;
      FindClose(regBusqueda);
    end;
  end;
begin
  Buscar(IncludeTrailingPathDelimiter(directorio));
end;

procedure TForm1.Button1Click(Sender: TObject);
var AItem: TListItem;
    i,w:integer;
    directorio,archivo:array[0..255] of WideChar;
    a,d:string;
    ar,di:PWideChar;
begin
  ListView1.Clear;
  ImageList1.Clear;
  lista := TStringList.Create;
  lista.Clear;
  BuscarArchivos('C:\Documents and Settings\Admin\Mis documentos\Mis imágenes', '*.jpg', faAnyFile, lista);
  for w:=0 to Lista.Count-1 do
    begin
      a:=ExtractFileName(Lista.Strings[w]);
      ar:=StringToWideChar((a),archivo,255);
      d:=ExtractFilePath(Lista.Strings[w]);
      di:=StringToWideChar(d,directorio,255);
      try
        Image1.Picture.Assign(GetThumbnail(di,ar, 96, 96));
        ImageList1.Add(Image1.Picture.Bitmap,nil);
      except
        on E: Exception do
          begin
            ShowMessage('Error: '+E.Message);
            EXIT;
          end;
       end;
    end;
  ListView1.Items.BeginUpdate;
  for i:=0 to Lista.Count-1 do
    begin
      AItem := ListView1.Items.Add;
      AItem.Caption := ExtractFileName(Lista.Strings[i]);
      AItem.SubItems.Add(Lista.Strings[i]);
      AItem.ImageIndex:=i;
    end;
  ListView1.Items.EndUpdate;   
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Lista.Free;
end;
end.

Muchas Gracias y Saludos