abrir cajon de dinero serial

[Citlalli]

Hola,

tengo una aplicacion de punto de venta, al cual quiero conectar un cajon de dinero, dicho cajon se conecta al puerto serial y necesito enviarle una secuencia para abrirlo, pero nunca he trabajado con puertos, alguien me puede ayudar?

Gracias y saludos

[jachguate]

si, aqui encontraras varias formas de hacerlo.

Hasta luego.

[Citlalli]

gracias jachguate por tu buena intencion de ayudarme pero tu link me lleva a la busqueda avanzada, no entiendo !!

saludos

[jachguate]

El tema se ha tratado varias veces aqui. Dado que los foros del club no son un servicio de soporte técnico, se recomienda siempre buscar en la base de datos de conocimiento formada con todas las preguntas y respuestas que al cabo de los años se han acumulado aqui, y abrir un nuevo hilo solamente si no se ha encontrado lo que se buscaba.

Hasta luego.

[Citlalli]

ok, ok, tienes razon, estuve buscando en los foros viejos a traves de la ayuda avanzada y no he encontrado lo que necesito, lo mas cerca es el ejemplo de una balanza y en dicho ejemplo hablan de un componente, el cual ya bajé, pero no se como utilizarlo, y la verdad es que me estoy volviendo loca, que me recomiendas?

saludos

[Citlalli]

mira, estuve nuevamente viendo los foros viejos y hablan del cajon de dinero conectado a impresora de tickets, yo no ocupo impresora, yo tengo el cajon conectado directamente al com1, y lo unico que me dieron fueron estos codigos:

inicializacion 27,33,1
acceso a puerto 27,61,1
apertura cajon 27,112,48
finalizacion 27,33,0

pero de verdad no se como utilizarlos, se que tienes razon en que esto no es un servicio de soporte tecnico, pero quien mas me puede ayudar si no es ClubDelphi, ojala puedas hacer esta unica excepción, muchisimas gracias.

Saludos

[manuweb]

Este me funciona a mi.

Está conectado en COM1 y la secuencia de apertura está en la variable cadena

Código Delphi [-]
unit Cajon;
interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;
type
TForm1 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
const
NombrePuerto = 'COM1'; // Por decir algo
var
Form1: TForm1;
HandlePuerto: THandle; // Manejador para el puerto
Cadena: String; // Para leer del puerto
dwValor: DWORD; // Tamaño de la lectura
Sta: COMSTAT; // Estado o tamaño del buffer de lectura
bResult: Boolean; // Parámetro de resultado
implementation
{$R *.dfm}
procedure TForm1.Button1Click(Sender: TObject);
begin
// ~~~~~~~~~~~~~~~~~~~
// Apertura del puerto
// ~~~~~~~~~~~~~~~~~~~
//
// El puerto ha de abrirse con acceso exclusivo. Es una de las razones de que haya
// un sólo "Acceso telefónico a redes" que actúa de servidor del puerto. Generalmente
// también se abre con acceso de lectura y escritura ya que es extraño tener que leer
// o escribir sólo en él. Pero, claro, esto depende de lo que vayas a hacer con el
// mismo. El "solapamiento" se produce sólo si hay varios procesos que pueden acceder
// al puerto a la vez y se utiliza cuando la aplicación tiene, por ejemplo, un hilo
// para leer y otro para escribir. Presupongo que no es el caso y que sólo hay un hilo.
// El último parámetro ('hTemplate') no tiene efecto para los puertos de comunicaciones.
//
HandlePuerto := Windows.CreateFile(
PChar(NombrePuerto), { Nombre del puerto }
GENERIC_READ or
GENERIC_WRITE, { Modo de apertura: Lectura/Escritura }
0, { Acceso exclusivo }
nil, { Sin atributos de seguridad }
OPEN_EXISTING, { El puerto debe existir }
0, { Sin solapamiento de Lectura/Escritura }
0); { No hay "hTemplate" }
// Comprobar que la apertura ha sido correcta
if (INVALID_HANDLE_VALUE <> HandlePuerto) then
begin
Cadena := #27#112#0#60#240#13#10;
if (Windows.WriteFile(
HandlePuerto, { Handle del puerto }
PChar(Cadena)^, { Datos a escribir }
Length(Cadena), { Longitud de los datos }
dwValor, { Número de caracteres escritos }
nil) { Sin solapamiento de lecturas/escrituras }
)
then
begin
Button1.Caption:='ok' ;
// Aquí nos damos con un canto en los dientes:
// la 'Cadena' se ha escrito en el puerto. Podemos comprobarlo si
// miramos 'dwValor' ya que debe ser igual a 'Length(Cadena)'.
// Si no lo es, algo ha ido mal.
end;
end;
// ~~~~~~~~~~~~~~~~
// Cerrar el puerto
// ~~~~~~~~~~~~~~~~
Windows.CloseHandle(HandlePuerto);
 
end;
end.

Espero que te sirva.

Suerte.

Manuweb