Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > OOP
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Grupo de Teaming del ClubDelphi

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 08-11-2016
Jose Roman Jose Roman is offline
Miembro
 
Registrado: jul 2006
Ubicación: Colombia
Posts: 361
Poder: 18
Jose Roman Va por buen camino
TGrpButtonItem con propiedad Enabled

Cordial saludo,

Estoy trabajando con XE8, y tengo un proyecto que tiene un componente TButtonGroup y a su vez este tiene dos TGrpButtonItem, como se sabe este ultimo no posee la propiedad Enabled, me gustaria crear una clase derivada para tal fin como lo hace en marteens.com, esto es avanzado para mi y no se implementarlo bien.

Gracias por la ayuda
Responder Con Cita
  #2  
Antiguo 08-11-2016
Avatar de AgustinOrtu
[AgustinOrtu] AgustinOrtu is offline
Miembro Premium
NULL
 
Registrado: ago 2013
Ubicación: Argentina
Posts: 1.858
Poder: 15
AgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en bruto
Aca se hablo de ese tema

Aunque el codigo que publique cumple su cometido, lo que resta por implementar es el comportamiento visual (no permitir clickear el boton, sombrearlo o algo para se note que esta desactivado, mouseover, entre otros)

Código Delphi [-]
unit Unit1;
 
interface
 
uses
  System.Classes,
  Vcl.Forms,
  Vcl.Dialogs,
  Vcl.Controls,
  Vcl.ButtonGroup;
 
type
  TButtonGroup = class(Vcl.ButtonGroup.TButtonGroup)
  protected
    procedure DoItemClicked(const Index: Integer); override;
    function GetButtonClass: TGrpButtonItemClass; override;
  end;
 
  TGrpButtonItemEx = class(TGrpButtonItem)
  private
    FEnabled: Boolean;
    procedure SetEnabled(const Value: Boolean);
  public
    constructor Create(Collection: TCollection); override;
    property Enabled: Boolean read FEnabled write SetEnabled;
  end;
 
  TForm1 = class(TForm)
    ButtonGroup1: TButtonGroup;
    procedure FormCreate(Sender: TObject);
    procedure ItemClick(Sender: TObject);
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.ItemClick(Sender: TObject);
begin
  ShowMessage('ItemClick');
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  ButtonGroup1.ButtonOptions := [gboFullSize, gboShowCaptions];
  ButtonGroup1.Items[0].OnClick := ItemClick;
  ButtonGroup1.Items[1].OnClick := ItemClick;
  TGrpButtonItemEx(ButtonGroup1.Items[0]).Enabled := False;
end;
 
{ TGrpButtonItemEx }
 
constructor TGrpButtonItemEx.Create(Collection: TCollection);
begin
  inherited Create(Collection);
  Enabled := True;
end;
 
procedure TGrpButtonItemEx.SetEnabled(const Value: Boolean);
begin
  FEnabled := Value;
end;
 
{ TButtonGroup }
 
procedure TButtonGroup.DoItemClicked(const Index: Integer);
var
  ButtonItem: TGrpButtonItem;
begin
  ButtonItem := Items[index];
  if Assigned(ButtonItem) and (ButtonItem is TGrpButtonItemEx) then
  begin
    if not TGrpButtonItemEx(ButtonItem).Enabled then Exit;
  end;
 
  inherited DoItemClicked(index);
end;
 
function TButtonGroup.GetButtonClass: TGrpButtonItemClass;
begin
  Result := TGrpButtonItemEx;
end;
 
end.

Lo mas sencillo es utilizar TActionList y conectar los botones con los respectivos Actions. Luego, te manejas con las propiedad TAction.Enabled. Aunque esta solucion tiene la misma "pega" que la anterior, visualmente los botones parecen activos, pero es mucho mas sencilla de implementar
Responder Con Cita
  #3  
Antiguo 09-11-2016
Jose Roman Jose Roman is offline
Miembro
 
Registrado: jul 2006
Ubicación: Colombia
Posts: 361
Poder: 18
Jose Roman Va por buen camino
Gracias por tu ayuda, utilizare el ejemplo y te comentare como me fue.
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
Crear propiedad Enabled Jose Roman OOP 0 07-04-2015 16:01:27
Implementar la propiedad ENABLED a un TGrpButtonItem Jose Roman OOP 0 11-03-2015 00:01:48
Cambiar el estilo de un EDIT con Propiedad ENABLED := False lpedrazzi Varios 3 10-03-2008 21:23:17
TComponets no tiene propiedad enabled lucasarts_18 Varios 8 16-01-2006 17:01:18
Cachedupdate not enabled!! ElCherchu Conexión con bases de datos 0 17-09-2003 17:32:38


La franja horaria es GMT +2. Ahora son las 04:03:05.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi