¿Como detectar si el servidor de bases de datos está lanzado?

[ErnestoCarrera]

Hola buenas,

Les cuento mi problema: resulta que tengo una aplicación desarrollada con Delphi6 y que necesita conectarse al arrancar con una base de datos. El servidor de base de datos es el firebird 1.5.2.4731. La susodicha aplicación se lanza al inicio de windows y hay veces (no muchas, la verdad), que al arrancar el PC me da un mensaje de error del estilo : "unavailable database".

Sospecho que es porque el programa se lanza antes de que el servicio de Firebird esté lanzado, así que me gustaría saber cómo se puede detectar si el servicio está o no lanzado para que mi programa espere por él.

He usado la opción buscar pero la verdad es que no he encontrado nada que me solucione la vida, así que si algún alma caritativa se apiada de mí y me ayuda le estaré eternamente agradecido

[Neftali [Germán.Estévez]]

Supongo que ese error te da al intentar activar la conexión con la Base de Datos (al abrir tablas o ejecutar consultas); Puedes probar a activar la conexión al principio y capturar (try..except) los errores que te de.
En ese punto deberías poder hacer varios reintentos con un breve lapso de tiempo entre medio, para "esperar" a que el servidor se arranque.


Otra cosa que puedes hacer es, al principio preguntar si el Servicio del servidor de FireBird está activo, sino es así esperar y volver a preguntar (repetir esto unas cuantas veces) antes de generar el error.

[[egostar]]

Yo sugiero que tu aplicación la generes como un servicio y le asignes en la propiedad Dependencies el servicio de Firebird, con eso tu programa no va a iniciar hasta que el servicio Firebird este iniciado.

Saludos.

[[seoane]]

Solo añadir un poco de codigo:

Código Delphi [-]
uses WinSvc;

// Para comprobar si un servicio esta corriendo
function isRunning(Nombre: String): Boolean;
var
 ServiceControlManager: SC_HANDLE;
 Service: SC_HANDLE;
 ServiceStatus: SERVICE_STATUS;
begin
  Result:= FALSE;
  ServiceControlManager:= OpenSCManager(nil, nil, SC_MANAGER_CONNECT);
  if ServiceControlManager <> 0 then
  begin
    Service:= OpenService(ServiceControlManager,PChar(Nombre),GENERIC_READ);
    if Service <> 0 then
    begin
      if QueryServiceStatus(Service, ServiceStatus) then
        Result:= ServiceStatus.dwCurrentState = SERVICE_RUNNING;
      CloseServiceHandle(Service);
    end;
    CloseServiceHandle(ServiceControlManager);
  end;
end;


function Esperar(Nombre: String; TimeOut: Cardinal): Boolean;
var
  Ticks: Cardinal;
begin
  Result:= TRUE;
  Ticks:= GetTickCount;
  while not isRunning(Nombre) do
  begin
    Sleep(10);
    if GetTickCount - Ticks > TimeOut then
    begin
      Result:= FALSE;
      Exit;
    end;
  end;
end;

La primera función nos dice si un servicio esta iniciado, y la segunda espera hasta que el servicio se inicia o se cumple el tiempo de espera. Si el servicio no esta iniciado cuando se cumple el tiempo de espera la función devuelve FALSE. Un ejemplo de como usar lo anterior:

Código Delphi [-]
// Le damos 15 segundos de margen
if Esperar('NombreDelServicio',15000) then
begin
  // El servicio esta iniciado
end else
begin
  // Pasaron los 15 segundos y el servicio sigue inactivo
end;

[Neftali [Germán.Estévez]]

¡¡Qué grande Seoane!!!

Uno pide...

Empezado por Neftali

...Otra cosa que puedes hacer es, al principio preguntar si el Servicio del servidor de FireBird está activo, sino es así esperar y volver a preguntar (repetir esto unas cuantas veces) antes de generar el error.

Y tú contestas...

Empezado por seoane

La primera función nos dice si un servicio esta iniciado, y la segunda espera hasta que el servicio se inicia o se cumple el tiempo de espera.

P.D: Se podría añadir como truco.

[Casimiro Notevi]

seoane, y en los ratos libres, ¿qué haces?

Muy bueno ese código.

[[seoane]]

Empezado por Casimiro Notevi

seoane, y en los ratos libres, ¿qué haces?

En mis ratos libres busco trabajo e intento estudiar una oposición, pero es mas divertido estar por aquí todo el día, que pena que no me paguen por eso

Empezado por Neftali

P.D: Se podría añadir como truco.

PD: Ahora mismo lo coloco en la seccion de trucos, aunque ya es muy similar a otro que puse sobre iniciar y detener servicios.

[Casimiro Notevi]

Empezado por seoane

En mis ratos libres busco trabajo e intento estudiar una oposición, pero es mas divertido estar por aquí todo el día, que pena que no me paguen por eso

PD: Ahora mismo lo coloco en la seccion de trucos, aunque ya es muy similar a otro que puse sobre iniciar y detener servicios.

Pensando en esa frase, ¿os habéis dado cuenta la cantidad tan enorme de trabajo, tiempo y dinero que le estamos ahorrando a muchas empresas cuyos programadores acuden a clubdelphi?

Me incluyo, también, porque más de una vez me habéis ayudado y al final, la beneficiada ha sido la empresa donde trabajo.