Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Varios
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Grupo de Teaming del ClubDelphi

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 18-11-2005
Walterdf Walterdf is offline
Miembro
 
Registrado: may 2003
Ubicación: Buenos Aires
Posts: 152
Poder: 21
Walterdf Va por buen camino
Problema con ShellExecute

Hola a todos!!
Necesito ejecutar un programa .exe que está en la web. Buscando en estos foros encontré esta forma:

Código:
ShellExecute(Handle, 'open', 'http://www.mipagina.com/Actualizacion.exe', nil, nil, SW_SHOW)
Agregué en el uses el ShellApi pero me aparecen los siguientes errores:

Undeclared identifier: 'Handle'
Undeclared identifier: 'SW_SHOW'

Algo me debo estar olvidando. Por favor, necesito una mano.
Gracias.

Walter
Responder Con Cita
  #2  
Antiguo 18-11-2005
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola,

Cita:
Empezado por Walterdf
Undeclared identifier: 'Handle'
Undeclared identifier: 'SW_SHOW'
"Handle", por el contesto, probablemente, se está refiriendo al "Handle" del formulario en que tratas de usar la función "ShellExecute". Acaso no estás usando ningún formulario, y, es por esto que "Handle" no es un identificador válido. "SW_SHOW" es una constante declarada en la unidad "Windows.pas".

De todos modos más que ejecutar el programa que está, como dices, en un servidor de Internet, para mí tengo que lo conseguirás con la función "ShellExecute" es que se descarge el archivo ejecutable en tu disco duro... no sé si el diálogo que te aparecerá tras la función "ShellExecute" te dará la opción de "ejecutar" ese programa, pero, desde luego, lo hará una vez descargado a tu disco duro.

Edito: para subsanar el tema del "Handle" desconocido puedes probar sustituyendo ese identificador por un "cero" (0), o con una función como "GetDesktopWindow" o como "GetActiveWindow". Más información sobre estas funciones en la ayuda de Delphi o en la del SDK de Win32 disponible desde el menú de ayuda de Delphi. Ambas funciones se declaran en la unidad "Windows.pas" también.
__________________
David Esperalta
www.decsoftutils.com

Última edición por dec fecha: 18-11-2005 a las 20:24:05.
Responder Con Cita
  #3  
Antiguo 18-11-2005
Avatar de Lepe
[Lepe] Lepe is offline
Miembro Premium
 
Registrado: may 2003
Posts: 7.424
Poder: 28
Lepe Va por buen camino
Application.Handle (por ejemplo);

SW_SHOW está en Forms.pas añadelo al uses.

saludos
__________________
Si usted entendió mi comentario, contácteme y gustosamente,
se lo volveré a explicar hasta que no lo entienda, Gracias.
Responder Con Cita
  #4  
Antiguo 18-11-2005
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola,


Cita:
Empezado por Lepe
Application.Handle (por ejemplo);

SW_SHOW está en Forms.pas añadelo al uses.
"Application", efectivamente, se declara en la unidad "Forms.pas" y puede ser otra posibilidad hacer uso de su "Handle" para el caso que nos ocupa. La constante "SW_SHOW" la encuentro en la unidad "Windows.pas" y no en "Forms.pas".
__________________
David Esperalta
www.decsoftutils.com
Responder Con Cita
  #5  
Antiguo 18-11-2005
Walterdf Walterdf is offline
Miembro
 
Registrado: may 2003
Ubicación: Buenos Aires
Posts: 152
Poder: 21
Walterdf Va por buen camino
Capo!!, me contestaste en segundos, mil gracias.
Es verdad, no hay un form y veo que cada vez ignoro mas pero ya aprenderé.
Te comento lo que quiero hacer. Hice una aplicación con un splashscreen al inicio, la carga del mismo la hice agregando el código en el .dpr y lo que hace en ese momento tambien es chequear si hay una versión nueva en la web. Si la hay quería ejecutar el instalador allí subido para actualizar, y la ejecución la quería llevar a cabo mediante el ya comentado ShellExecute.
Tal vez me combiene ponerlo en el form del splash ¿no? o ¿me aconsejas otra manera?
Mil gracias de nuevo.

Walter
Responder Con Cita
  #6  
Antiguo 18-11-2005
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola,

No me considero quién para aconsejar a nadie sobre nada, sobre todo porque la gente se guarda muy mucho y muy bien de no seguir los consejos de nadie, y, ¿quién soy yo? Nadie. Pues por eso lo digo. Lo que puedo añadir es lo que se me ocurre a bote pronto, que te sea de utilidad o no dependerá de tantas cosas que no me atrevo a imaginarlas. Ahí voy.

Se me ocurre que no compruebes la existencia de una nueva versión de tu programa sino hasta haberse este ejecutado y presentado al usuario. Cuando el usuario inicia tu programa quiere ver tu programa, justamente, y no saber antes de nada si existe una versión nueva.

Es una opinión, claro está, y que acaso no sepa expresar convenientemente. Entono un mea culpa, se suele decir, en estos casos. Yo daría al usuario la opción de comprobar la existencias de nuevas versiones del programa al iniciarse este (pero al iniciarse aquí significa una vez el programa, la interfaz del programa, están disponibles para el usuario). Y realizar dicha comprobación en segundo plano, sin que el usuario se percate de ello, avisándole únicamente si de veras existe una versión nueva del programa.

Es en ese punto, cuando el usuario conozca la existencia de una versión nueva del programa, y quiera interesarse por esta, cuando tú puedes proceder a la descarga del nuevo sistema, se componga este de los archivos que se compongan, realizando la tarea como mejor te parezca o como, en definitiva, sea menester.

El uso de la función "ShellExecute" para esto lo veo de la siguiente manera, únicamente: se comprueba que existe una versión nueva del programa; se le pregunta al usuario si quiere descargar esta nueva versión; en caso afirmativo se utiliza la función "ShellExecute" para que el sistema operativo se encarge por los cauces adecuados de descargar de Internet el archivo que le indiquemos.

¿Otras formas de actualizar el programa que no sea usando la función "ShellExecute", que no me parece la más conveniente? Pues haberlas las hay. Hasta componentes dedicados a la tarea de actualizar aplicaciones existen para Delphi. La Jedi Library incluye todo un "paquete" de componentes dedicados a esta tarea. También podrías hacerlo tú mismo, ya digo, todo dependerá de qué se tenga que llevar a cabo: no todas las aplicaciones son iguales, esto es obvio, así que no todas las "actualizaciones" serán las mismas ni seguirán los mismos pasos.
__________________
David Esperalta
www.decsoftutils.com
Responder Con Cita
  #7  
Antiguo 18-11-2005
Walterdf Walterdf is offline
Miembro
 
Registrado: may 2003
Ubicación: Buenos Aires
Posts: 152
Poder: 21
Walterdf Va por buen camino
Muy bienvenida tu respuesta y coincido plenamente con tu opinión ya que en lo personal considero muy molesto que el programa tome ciertas decisiones por mi. La posibilidad de chequear nuevas actualizaciones la doy mediante una opción en el menú de la aplicación pero además incluí una especie de configuración en donde el usuario puede personalizar ciertas opciones para su comodidad, entre ellas que chequee las actualizaciones al iniciar, que por defecto está desactivada.
Hecharé un vistazo a los componentes que mencionas. En realidad la actualización es simple, es una base de datos paradox con unos 10000 registros metida en un instalador solo para facilitar la tarea del usuario. Lo que yo subo a internet es el instalador (un .exe).
Muchísimas gracias.

Walter
Responder Con Cita
  #8  
Antiguo 18-11-2005
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola,


Cita:
Empezado por Walterdf
En realidad la actualización es simple, es una base de datos paradox con unos 10000 registros metida en un instalador solo para facilitar la tarea del usuario. Lo que yo subo a internet es el instalador (un .exe).
Bueno, pues, con todo lo equivocado que puedo estar al presumir algo así, según me parece a bote pronto, efectivamente, parece una actualización "más o menos" sencilla.

Lo que estoy haciendo yo en cierto programa sí que es verdaderamente sencillo, acaso demasiado, pero, de momento, ahí está. No utilizo ningún componente de terceros para ello, se trata de una sencilla clase que se encarga de "todo".

Cuando el usuario utiliza la opción del programa "¿Estás usando la última versión?" lo único que hago es descargar cierto archivo de texto plano de un Servidor de Internet. Ese archivo de texto plano no tiene más que tres líneas, y, si se me apura, solamente dos de ellas son útiles.

Una línea contiene la versión actual y otra línea la fecha de dicha versión, porque la distribución del programa puede ser la misma versión que una anterior, pero de distinta fecha, se entiende.

El caso es que descargar ese archivo de texto plano y comparar la versión del programa "local" con la versión disponible en Internet no lleva sino unos segundos. En caso de que, efectivamente, exista una nueva versión ni siquiera la descargo.

Únicamente le planteo al usuario la posibilidad de hacerlo mediante un cuadro de diálogo. Le pregunto, bien, existe una nueva versión del programa, ¿quieres descargarla ahora? Si el usuario responde "Sí, quiero", me limito a abrir la página Web del programa, en donde, en grandes letras, está indicado la versión y la fecha de la versión que está disponible en dicha página Web.

Como las características del programa, hasta el momento, lo permiten, el usuario, para actualizarlo, únicamente tiene que "reinstalarlo" encima de la anterior versión. Sus "opciones" no se pierden, porque, básicamente, el programa instalador se limita a copiar determinados archivos en el disco duro.

Disculpa tanto rollo. Me salió así. Supongo que esto no interesa a nadie, pero, en fin, ahí queda, como una especie de... lo que sea.
__________________
David Esperalta
www.decsoftutils.com
Responder Con Cita
  #9  
Antiguo 18-11-2005
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola de nuevo,

Porque se vea la sencillez (e incluso simpleza) de la clase que he dicho arriba que utilizo para comprobar si existe nuevas versiones del programa de que he hablado es esta misma, sin más:

Código Delphi [-]
 { *********************************************************************** }
 {                                                                         }
 { XEditor                                                                 }
 { Copyright (C) 2005 por David Esperalta Calderón                         }
 { Todos los derechos reservados.                                          }
 {                                                                         }
 { El contenido de este archivo está protegido por la                      }
 { licencia del programa XEditor que puedes encontrar                      }
 { en el archivo "licencia.txt" del subdirectorio txt                      }
 {                                                                         }
 { Correo del programa:     XEditor@Gmail.com                              }
 { Página Web del programa: http://www.XEditor.tk                          }
 { Correo del autor:        DavidEsperalta@Gmail.com                       }
 {                                                                         }
 { *********************************************************************** }
 
 unit UBuscaVersiones;
 
 interface
 
 // Delphi 7
 //
 uses
   Classes, SysUtils, DateUtils, Controls, IdHttp;
 
 // Algunos eventos utilizados.
 //
 type
   TOnNuevaVersion = procedure(Sender: TObject;
     versionWeb, fechaVersionWeb: string) of object;
   TOnNuevaFechaVersion = procedure(Sender: TObject;
     versionWeb, fechaVersionWeb: string) of object;
 
 // Mantiene al usuario al tanto de las nuevas
 // versiones del programa que se publiquen.
 //
 type
   TBuscaVersiones = class(TObject)
   private
     FDatos: TStrings;
     FUrlDatos: string;
     FFechaActual: string;
     FVersionActual: string;
     FOnError: TNotifyEvent;
     FOnSinNuevaVersion: TNotifyEvent;
     FOnNuevaVersion: TOnNuevaVersion;
     FOnNuevaFechaVersion: TOnNuevaFechaVersion;
     procedure ProcesarDatos;
     function ObtenerDatos : boolean;
   public
     constructor Create;
     destructor Destroy; override;
     procedure Comprobar(versionActual, fechaActual: string);
   public
     property UrlDatos: string read FUrlDatos write FUrlDatos;
     property OnError: TNotifyEvent read FOnError write FOnError;
     property OnSinNuevaVersion: TNotifyEvent
       read FOnSinNuevaVersion write FOnSinNuevaVersion;
     property OnNuevaVersion: TOnNuevaVersion
       read FOnNuevaVersion write FOnNuevaVersion;
     property OnNuevaFechaVersion: TOnNuevaFechaVersion
       read FOnNuevaFechaVersion write FOnNuevaFechaVersion;
   end;
 
 implementation
 
 { TBuscaVersiones }
 
 // Constructor.
 //
 constructor TBuscaVersiones.Create;
 begin
   inherited Create;
   FDatos := TStringList.Create;
 end;
 
 // Destructor.
 //
 destructor TBuscaVersiones.Destroy;
 begin
   FDatos.Free;
   inherited Destroy;
 end;
 
 // Comprueba si hay una nueva versión.
 //
 procedure TBuscaVersiones.Comprobar(versionActual,
   fechaActual: string);
 begin
   FFechaActual := fechaActual;
   FVersionActual := versionActual;
   if ObtenerDatos then ProcesarDatos;
 end;
 
 // Obtiene los datos precisos para averiguar
 // si existe una nueva versión del programa.
 //
 function TBuscaVersiones.ObtenerDatos : boolean;
 var
   http: TIdHTTP;
   temp: TStringStream;
 begin
   Result := false;
   http := TIdHTTP.Create(nil);
   temp := TStringStream.Create(EmptyStr);
   try
     try
       http.Get(FUrlDatos, temp);
       if temp.Size > 0 then
       begin
         FDatos.Clear;
         FDatos.Text := temp.DataString;
         Result := true;
       end;
     except
       if Assigned(FOnError)
        then FOnError(Self);
       Abort;
     end;
   finally
     http.Free;
     temp.Free;
   end;
 end;
 
 // Procesa los datos que determinarán si
 // existe o no una nueva versión del programa.
 //
 procedure TBuscaVersiones.ProcesarDatos;
 var
   dVersionActual, dVersionWeb: double;
   fechaVersionActual, fechaVersionWeb: TDate;
 begin
   {
     Los datos que encontraremos en la variable
     FDatos guardan una muy sencilla estructura.
 
     En realidad partimos de las tres líneas que
     guardamos en un Servidor en Internet en el
     archivo que tenemos para estos menesteres.
 
     Estas son las tres líneas:
 
     0: XEditor (última versión)
     1: 1.3
     2: 15/09/2005
 
     Como se ve la primera línea no nos sirve de
     mucho, y así nos fijamos en las líneas uno
     y dos, que contiene, respectivamente, la
     versión del programa y la fecha de la misma.
   }
   if FDatos.Text = EmptyStr then begin
     if Assigned(FOnError) then FOnError(Self);
     Exit;
   end;
   DecimalSeparator := '.';
   dVersionWeb := StrToFloat(FDatos.Strings[1]);
   dVersionActual := StrToFloat(FVersionActual);
   if dVersionActual < dVersionWeb then
   begin
     if Assigned(FOnNuevaVersion) then
       FOnNuevaVersion(Self, FDatos.Strings[1],
         FDatos.Strings[2]);
     Exit;
   end;
   if dVersionActual = dVersionWeb then
   begin
     fechaVersionActual := StrToDate(FFechaActual);
     fechaVersionWeb := StrToDate(FDatos.Strings[2]);
     if (CompareDate(fechaVersionWeb,
       fechaVersionActual) = 1) then
       begin
         if Assigned(FOnNuevaFechaVersion) then
           FOnNuevaFechaVersion(Self, FDatos.Strings[1],
             FDatos.Strings[2]);
         Exit;
      end;
   end;
   if Assigned(FOnSinNuevaVersion) then
     FOnSinNuevaVersion(Self);
 end;
 
 end.
Podrá mejorarse todo lo que se quiera, no es mi intención entrar en eso ahora. El caso es que para hacer uso de la clase anteriormente presentada bastaría con algo así:

Código Delphi [-]
 
 var
   FBuscaVersiones: TBuscaVersiones;
 
 // Prepara el objeto que se encarga de obtener
 // información sobre la última versión del pro-
 // grama disponible en Internet.
 //
 procedure TfrmPrincipal.PrepararBuscaVersiones;
 begin
   FBuscaVersiones := TBuscaVersiones.Create;
   with FBuscaVersiones do begin
     UrlDatos := rsUrlActualizar;
     OnNuevaVersion := NuevaVersion;
     OnError := ErrorComprobandoVersion;
     OnNuevaFechaVersion := NuevaVersion;
     OnSinNuevaVersion := SinNuevaVersion;
   end;
 end;
Donde "FBuscaVersiones" será una variable que guarde la referencia al objeto de la clase "TBuscaVersiones" que utilizaremos. A continuación proporcionamos una serie de datos, básicamente nos interesa la propiedad "UrlDatos", que ha de ser la URL en que se encuentre el archivo que contenga la información "a comparar", es decir, el archivo texto plano que referí más arriba.

A continuación hacemos uso de los eventos del objeto para informar al usuario o tomar las medidas necesarias en caso de encontrarse nuevas versiones, no encontrarse, etc.

En todo caso, la llamada "principal" al objeto "TBuscaVersiones" se realizaría de este modo, una vez hecho lo anterior, es decir, una vez creado el objeto e inicializado:

Código Delphi [-]
 FBuscaVersiones.Comprobar(rsVersion, rsFechaVersion);
Con esa instrucción estamos llamando al método "Comprobar" del objeto "TBuscaVersiones". A dicho método le pasamos dos parámetros, como puede verse, la versión actual (local) del programa y la fecha de esta versión. Echo eso el objeto se encargará internamente de descargar el archivo de Internet que contendrá los datos con los que podremos comparar y también el objeto se encargará de disparar los eventos oportunos, si estos están asignados.

Otra vez pido disculpas por tanto rollo. No sé, iré al médico mañana a ver si es que tengo la gripe del pollo o algo parecido...
__________________
David Esperalta
www.decsoftutils.com
Responder Con Cita
  #10  
Antiguo 18-11-2005
Walterdf Walterdf is offline
Miembro
 
Registrado: may 2003
Ubicación: Buenos Aires
Posts: 152
Poder: 21
Walterdf Va por buen camino
Sinceramente me encuentro muy agradecido por las molestias que te tomaste, voy a ver el código detenidamente y ver de adaptarlo a mi aplicación.
A propósito, muy interesante el XEditor ya me lo estoy bajando y felicitaciones por la página, muy completa.

Muchas gracias de nuevo.

Walter
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro


La franja horaria es GMT +2. Ahora son las 20:13:36.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi