Insertar valores...Error

[tebre]

necesito ayuda de como insertar estos datos en un base de dato SQL Server 2005

Código Delphi [-]
 
procedure TFrmSolicitud.BtnAgregarClick(Sender: TObject);
var global : integer;
begin
   global :=0;
   boleano:=false;
        //*********Ingresar en la tabla Principal********* 
         Datos.QrySolicitud.Active:= False;
         Datos.QrySolicitud.SQL.Clear;
         Datos.QrySolicitud.SQL.Add('INSERT INTO Solicitud VALUES(');
         Datos.QrySolicitud.SQL.Add(Quotedstr(EdFolioSolicitud.Text) + ',');
         Datos.QrySolicitud.SQL.Add(Quotedstr(LblUsuarioCreador.Caption) + ',');
         Datos.QrySolicitud.SQL.Add(dateToStr(DtpFechaCreacion.Date) + ',');  //insertar dato tipo fecha
         Datos.QrySolicitud.SQL.Add(dateToStr(DtpFechaCreacion.Date) + ',');   //insertar dato tipo fecha
         Datos.QrySolicitud.SQL.Add(dateToStr(DtpFechaCreacion.Date) + ',');  //insertar dato tipo fecha
         Datos.QrySolicitud.SQL.Add(Quotedstr(Boleano) + ','); // Inserta este dato en un campo Boolan
         Datos.QrySolicitud.SQL.Add(Quotedstr(Boleano) + ','); // Inserta este dato en un campo Boolan
         Datos.QrySolicitud.SQL.Add(Quotedstr(lblUsuarioCreador.caption) + ',');
         Datos.QrySolicitud.SQL.Add(Quotedstr(lblDireccion.caption) + ')');
         Datos.QrySolicitud.ExecSQL;
end;

gracias por su ayuda

[roman]

¿Y cuál es el problema?

// Saludos

[tebre]

me marca un error que dice algo asi:


[Error] USolicitud.pas(227): E2010 Incompatible types: 'string' and 'Boolean'

pero mi compo en mi base de datos es boolean

[roman]

Quítale eso de QuotedStr al campo booleano y usa algo como BoolToStr:

Código Delphi [-]
Datos.QrySolicitud.SQL.Add(BoolToStr(Boleano, true) + ',')

// Saludos

[ContraVeneno]

tus datos son booleanos, pero la propiedad SQL de tu dataset es String... tendrías que usar la función BoolToStr para cambiar tus booleanos a cadena...

o mejor aún, podrías utilizar parámetros y no tendrías que hacer ninguna conversión de tipos de datos...





changos, me tarde... todo por bostezar antes de enviar la respuesta...jaja

[tebre]

Bueno ya esta ahora ya me ingreso los datos............lo que veo es que me guarda en formato asi "01/01/1900 00:00:00" en la base de datos..ahora se supone que la otra parte es la hora porque no me almaceno la hora correcta??

como hacerle...para que me agregue la hora correcta...


espero su respuesta gracias........

[[ElKurgan]]

Empezado por tebre

Datos.QrySolicitud.SQL.Add(dateToStr(DtpFechaCreacion.Date) + ','); //insertar dato tipo fecha

Date te devuelve la fecha en formato TDateTime pero
con el valor Time a cero. Prueba mejor con "Now"

Un saludo

[ContraVeneno]

Utilizando parámetros no tendrías que hacer ninguna conversión, ni booltostr, ni datetostr.

[tebre]

hola contraveneno..veo que me insiste en eso de envio de parametros pero apenas empiezo en delphi y todo es nuevo para mi..si me pudiera dar un ejemplo..y decirme donde radica la diferencia te lo agradeceria...

gracias a todos los del foro..muy bueno!!

[ContraVeneno]

Tu estas utilizando esta forma:

Código Delphi [-]
With UnADOQuery do begin
 If active then close;
 SQL.Clear;
 SQL.Add('Insert Into Tabla(UnCampo, OtroCampoFecha, CampoBoolean)');
 SQL.Add('Values('+QuotedStr(UnEdit.Text)+', '+DateToStr(UnaFecha.Date)+', '+BoolToStr(UnCheckBox.Checked)+')');
 ExecSQL;
end; //with

Lo que estas haciendo ahí, es cambiar el valor de la fecha a un valor de tipo cadena (String) con el formato que tengas establecido. Lo mismo se aplica para cualquier otro tipo de datos, ya sea boolean, float, currency, integer, etc. Todo lo tendrías que convertir a cadena.

El problema con cambiar todo a cadena de texto, es que tendrías que lidiar con los formatos. Por ejemplo, para las fechas, tendrías que definir si va a ser con formato yyyymmdd, o yyyy/dd/mm o dd/mm/yyyy. Para los tipos moneda, tendrías que ver si el formato esta definiendo los puntos como separador de miles, o si son las comas los separadores de miles, si es con signo o sin signo. En fin, en pocas palabras, tendrías que cuidar por medio de programación, el formato adecuado para cada tipo de dato. Y cada base de datos utiliza un formato distinto.

Si utilizas parámetros, no tienes que preocuparte por eso y no tendrías que validar formatos, ni cambiar formatos, ni codificar nada para esto. Aquí un ejemplo:

Código Delphi [-]
With UnADOQuery do begin
 If active then close;
 SQL.Clear;
 SQL.Add('Insert Into Tabla(UnCampo, OtroCampoFecha, CampoBoolean)');
 SQL.Add('Values(:UnCampo, :UnaFecha, :UnBoolean)');
 Parameters.ParamByName('UnCampo').Value := UnEdit.Text;
 Parameters.ParamByName('UnaFecha').Value := UnaFecha.Date;
 Parameters.ParamByName('UnBoolean').Value := unCheckBox.Checked;
 ExecSQL;
end; //with

En este pequeño ejemplo, si te fijas, no estoy haciendo ninguna conversión con la fecha y sistema seleccionará automáticamente el formato adecuando para guardarlo en la base de datos. Y lo mismo aplica para todos los tipos de datos, el sistema elegirá el formato correcto.

Ejemplo utilizando BDE en lugar de ADO:

Código Delphi [-]
 With UnBDEQuery do begin
  If active then close;
  SQL.Clear;
  SQL.Add('Insert Into Tabla(UnCampo, OtroCampoFecha, UnCampoBoolean)');
  SQL.Add('Values(:UnCampo, :UnaFecha, :UnBoolean)');
  ParamByName('UnCampo').AsString := UnEdit.Text;
  ParamByName('UnaFecha').AsDateTime := UnaFecha.Date;
  ParamByName('UnBoolean').AsBoolean := unCheckBox.Checked;
  ExecSQL;
 end; //with

Espero haberme explicado correctamente y haber dejado claro cuál es la ventaja de utilizar parámetros.
Saludos.

[tebre]

ahora mismo lo intentare y te cuento gracias