Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Gráficos
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 23-04-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Cool Capturar Imagen Con WebCam

Hola a todos los foreros

Se ha debatido demasiado sobre como capturar una foto desde una WebCam, y la mayoria de las respuestas coinciden con la utilizacion de un componente llamado TWain que es muy dificil de encontrar sino imposible. Otros han propuesto la utilizacion de un componente de la JVCL de la paleta JEDI denominado TJAviCapture. He tenido la posibilidad de probarlo y ver que funciona en D2009 pero resulto un poco engorrosa su aplicacion y dicho componente esta desarrollado para hacer mucho mas que capturar solo una foto WebCam, por eso lo interesante de la sencillez del codigo descripto en este hilo. Solo pocos han preguntado como hacer una captura de una foto desde una WebCam sin objeto alguno. En este hilo tratare de explicar como se puede capturar una foto desde una WebCam utilizando unos comandos de la API de Windows cuyas principales funciones y procedimientos estan descriptos en este archivo WIN32S.HLP.
Por razones de practicidad vamos a encapsular todo el codigo necesario para realizar dicha tarea en una Unit.pas que nos definira un componente propio. El siguiente codigo deben colocarlo dentro de una unit.

Código Delphi [-]
 
unit Webcam;
interface
uses
  Windows, Messages;
type
  TWebcam = class
    constructor Create(
      const WindowName: String = '';
      ParentWnd: Hwnd = 0;
      Left: Integer = 0;
      Top: Integer = 0;
      Width: Integer = 0;
      height: Integer = 0;
      Style: Cardinal = WS_CHILD or WS_VISIBLE;
      WebcamID: Integer = 0);
    public
      const
        WM_Connect     = WM_USER + 10;
        WM_Disconnect  = WM_USER + 11;
        WM_GrabFrame   = WM_USER + 60;
        WM_SaveDIB     = WM_USER + 25;
        WM_Preview     = WM_USER + 50;
        WM_PreviewRate = WM_USER + 52;
        WM_Configure   = WM_USER + 41;
    public
      procedure Connect;
      procedure Disconnect;
      procedure GrabFrame;
      procedure SaveDIB(const FileName: String = 'webcam.bmp');
      procedure Preview(&on: Boolean = True);
      procedure PreviewRate(Rate: Integer = 42);
      procedure Configure;
    private
      CaptureWnd: HWnd;
  end;
implementation
function capCreateCaptureWindowA(
  WindowName: PChar;
  dwStyle: Cardinal;
  x,y,width,height: Integer;
  ParentWin: HWnd;
  WebcamID: Integer): Hwnd; stdcall external 'AVICAP32.dll';
{ TWebcam }
procedure TWebcam.Configure;
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_Configure, 0, 0);
end;
procedure TWebcam.Connect;
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_Connect, 0, 0);
end;
constructor TWebcam.Create(const WindowName: String; ParentWnd: Hwnd; Left, Top,
  Width, height: Integer; Style: Cardinal; WebcamID: Integer);
begin
  CaptureWnd := capCreateCaptureWindowA(PChar(WindowName), Style, Left, Top, Width, Height,
    ParentWnd, WebcamID);
end;
procedure TWebcam.Disconnect;
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_Disconnect, 0, 0);
end;
procedure TWebcam.GrabFrame;
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_GrabFrame, 0, 0);
end;
procedure TWebcam.Preview(&on: Boolean);
begin
  if CaptureWnd <> 0 then
    if &on then
      SendMessage(CaptureWnd, WM_Preview, 1, 0)
    else
      SendMessage(CaptureWnd, WM_Preview, 0, 0);
end;
procedure TWebcam.PreviewRate(Rate: Integer);
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_PreviewRate, Rate, 0);
end;
procedure TWebcam.SaveDIB(const FileName: String);
begin
  if CaptureWnd <> 0 then
    SendMessage(CaptureWnd, WM_SaveDIB, 0, Cardinal(PChar(FileName)));
end;
end.

Salven la unit como WebCam

Como pueden observar el codigo esta basado puramente en la API de Win, y entendemos que se trata de enviar o recibir mensajes asi que esa parte no debe darnos problemas. La funcion especifica en cuestion es la denominada capCreateCaptureWindowA, que a continuacion veremos que dice la ayuda de la API.

The capCreateCaptureWindow function creates a capture window.
Código Delphi [-]
 
HWND VFWAPI capCreateCaptureWindow(
    LPCSTR lpszWindowName, 
    DWORD dwStyle, 
    int x, 
    int y, 
    int nWidth, 
    int nHeight, 
    HWND hWnd, 
    int nID 
   );
Parameters
lpszWindowName
Null-terminated string containing the name used for the capture window.
dwStyle
Window styles used for the capture window. Window styles are described with the CreateWindowEx function.
x and y
The x- and y-coordinates of the upper left corner of the capture window.
nWidth and nHeight
Width and height of the capture window.
hWnd
Handle of the parent window.
nID
Window identifier.

Return Values
Returns a handle of the capture window if successful or NULL otherwise.

A continuacion un ejemplo de como implementarla en una aplicacion desarrollada en Delphi.

Paso 1 - Creamos una nueva aplicacion
File -> New -> VCL Forms Applications - Delphi.

Paso 2 - Creamos nuestro objeto en una nueva unit
File -> New -> Unit - Delphi
Copiamos el codigo aqui descripto y luego salvamos esta Unit como WebCam

Paso 3 - Diseño de la Form1
En nuestra Form colocamos un TPanel, con las siguientes dimensiones with 640 heigh 480, una TImage y dos TButton, uno tendra en su caption Encender y el otro Tomar Foto.

Paso 4 - Codigo para hacer funcionar la captura
En el Uses agregaremos WebCam
Código Delphi [-]
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, ComCtrls, StdCtrls, Webcam;

En el evento OnCreate de nuestra Form pondremos lo siguiente.
Código Delphi [-]
 
.....
.....
.....
  private
    { Private declarations }
  public
    { Public declarations }
    camera: TWebcam;
  end;
var
  Form1: TForm1;
implementation
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  camera := TWebcam.Create('WebCaptured', Panel1.Handle, 0, 0,
    1000, 1000);
end;

Este codigo sera para el boton de encendido o apagado de la camara

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
const
  str_Connect = 'Encender la camara';
  str_Disconn = 'Apagar la camara';
begin
  if (Sender as TButton).Caption = str_Connect then  begin
    camera.Connect;
    camera.Preview(true);
    Camera.PreviewRate(4);
    (Sender as TButton).Caption:=str_Disconn;
  end
  else begin
    camera.Disconnect;
    (Sender as TButton).Caption:=str_Connect;
  end;
end;


Y este codigo para el boton de captura de la foto

Código Delphi [-]
 
procedure TForm1.Button2Click(Sender: TObject);
var
  PanelDC: HDC;
begin
if not Assigned(Image1.Picture.Bitmap) then
    Image1.Picture.Bitmap := TBitmap.Create
  else
  begin
    Image1.Picture.Bitmap.Free;
    Image1.picture.Bitmap := TBitmap.Create;
  end;
  Image1.Picture.Bitmap.Height := Panel1.Height;
  Image1.Picture.Bitmap.Width  := Panel1.Width;
  Image1.Stretch := True;
  PanelDC := GetDC(Panel1.Handle);
  try
    BitBlt(Image1.Picture.Bitmap.Canvas.Handle,
      0,0,Panel1.Width, Panel1.Height, PanelDC, 0,0, SRCCOPY);
  finally
    ReleaseDC(Handle, PanelDC);
  end;
end;

Aqui podemos observar que aparece una segunda funcion API de Win que hace el resto del trabajo, esta funcion es
Código Delphi [-]
BitBlt
y su explicacion es la siguiente

The BitBlt function performs a bit-block transfer of the color data corresponding to a rectangle of pixels from the specified source device context into a destination device context.
BOOL BitBlt(
HDC hdcDest, // handle to destination device context
int nXDest, // x-coordinate of destination rectangle's upper-left corner
int nYDest, // y-coordinate of destination rectangle's upper-left corner
int nWidth, // width of destination rectangle
int nHeight, // height of destination rectangle
HDC hdcSrc, // handle to source device context
int nXSrc, // x-coordinate of source rectangle's upper-left corner
int nYSrc, // y-coordinate of source rectangle's upper-left corner
DWORD dwRop // raster operation code
);

Parameters
hdcDest
Identifies the destination device context.
nXDest
Specifies the logical x-coordinate of the upper-left corner of the destination rectangle.
nYDest
Specifies the logical y-coordinate of the upper-left corner of the destination rectangle.
nWidth
Specifies the logical width of the source and destination rectangles.
nHeight
Specifies the logical height of the source and the destination rectangles.
hdcSrc
Identifies the source device context.
nXSrc
Specifies the logical x-coordinate of the upper-left corner of the source rectangle.
nYSrc
Specifies the logical y-coordinate of the upper-left corner of the source rectangle.
dwRop
Specifies a raster-operation code. These codes define how the color data for the source rectangle is to be combined with the color data for the destination rectangle to achieve the final color.
The following list shows some common raster operation codes:
Value Description
BLACKNESS Fills the destination rectangle using the color associated with index 0 in the physical palette. (This color is black for the default physical palette.)
DSTINVERT Inverts the destination rectangle.
MERGECOPY Merges the colors of the source rectangle with the specified pattern by using the Boolean AND operator.
MERGEPAINT Merges the colors of the inverted source rectangle with the colors of the destination rectangle by using the Boolean OR operator.
NOTSRCCOPY Copies the inverted source rectangle to the destination.
NOTSRCERASE Combines the colors of the source and destination rectangles by using the Boolean OR operator and then inverts the resultant color.
PATCOPY Copies the specified pattern into the destination bitmap.
PATINVERT Combines the colors of the specified pattern with the colors of the destination rectangle by using the Boolean XOR operator.
PATPAINT Combines the colors of the pattern with the colors of the inverted source rectangle by using the Boolean OR operator. The result of this operation is combined with the colors of the destination rectangle by using the Boolean OR operator.
SRCAND Combines the colors of the source and destination rectangles by using the Boolean AND operator.
SRCCOPY Copies the source rectangle directly to the destination rectangle.
SRCERASE Combines the inverted colors of the destination rectangle with the colors of the source rectangle by using the Boolean AND operator.
SRCINVERT Combines the colors of the source and destination rectangles by using the Boolean XOR operator.
SRCPAINT Combines the colors of the source and destination rectangles by using the Boolean OR operator.
WHITENESS Fills the destination rectangle using the color associated with index 1 in the physical palette. (This color is white for the default physical palette.)

Return Values
If the function succeeds, the return value is nonzero.
If the function fails, the return value is zero. To get extended error information, call GetLastError.
Remarks
If a rotation or shear transformation is in effect in the source device context, BitBlt returns an error. If other transformations exist in the source device context (and a matching transformation is not in effect in the destination device context), the rectangle in the destination device context is stretched, compressed, or rotated as necessary.
If the color formats of the source and destination device contexts do not match, the BitBlt function converts the source color format to match the destination format.
When an enhanced metafile is being recorded, an error occurs if the source device context identifies an enhanced-metafile device context.
Not all devices support the BitBlt function. For more information, see the RC_BITBLT raster capability entry in GetDeviceCaps.
BitBlt returns an error if the source and destination device contexts represent different devices.
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto
Responder Con Cita
  #2  
Antiguo 23-04-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Cool Espero comentarios

Espero que este codigo les haya sido de utilidad y voy a estar esperando por correcciones, sugerencias y todo aquello que pueda ayudar a ampliar la info en este hilo para aquellos que realizan futuras busquedas sobre este tema.
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto
Responder Con Cita
  #3  
Antiguo 23-04-2010
Avatar de Lord Delfos
Lord Delfos Lord Delfos is offline
Miembro
 
Registrado: ene 2008
Ubicación: Tandil, Argentina
Posts: 558
Poder: 17
Lord Delfos Va por buen camino
Cita:
Empezado por casacham Ver Mensaje
Espero que este codigo les haya sido de utilidad y voy a estar esperando por correcciones, sugerencias y todo aquello que pueda ayudar a ampliar la info en este hilo para aquellos que realizan futuras busquedas sobre este tema.
Pues como corrección no tengo ninguna, porque no lo puedo probar por no tener WebCam... (sí, ya sé que estamos en el siglo XXI, pero bueno ).

Lo que sí te quería comentar es que quizás esto etaría bueno ponerlo en la sección "trucos" o quizás hacerce un ejemplito y subirlo al FTP.
Responder Con Cita
  #4  
Antiguo 23-04-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Va a estar en Trucos

Este codigo puede ser descargado desde Directorio raíz » Delphi » Ejemplos, deben buscar con el nombre WebCamCapture - API.zip
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto

Última edición por casacham fecha: 23-04-2010 a las 23:32:08.
Responder Con Cita
  #5  
Antiguo 23-04-2010
Avatar de Caral
[Caral] Caral is offline
Miembro Premium
 
Registrado: ago 2006
Posts: 7.659
Poder: 25
Caral Va por buen camino
Hola
No tengo en este momento la cámara pero lo voy a probar.
Lo mas importante es el aporte, gracias.
Saludos
__________________
Siempre Novato
Responder Con Cita
  #6  
Antiguo 24-04-2010
Avatar de radenf
radenf radenf is offline
Miembro
 
Registrado: oct 2007
Ubicación: Viña del Mar,Chile
Posts: 608
Poder: 17
radenf Va por buen camino
Estimado casacham :

He probado múltiples componentes para captura de video desde una webcam y el mejor resultado lo obtuve con BasicVideo. Siempre he querido independizarme de este componente y utilizar las Api de windows. Había probado con el codigo que se encuentra publicado en Delphimagic.blogspot.com, sin embargo con mi webcam Microsoft NX-6000 siempre obtengo una ventana de captura vacía en negro. La cámara se enciende y no genera tampoco el preview. Los mismos resultados obtengo con el código que aquí has publicado, que es similar al que mencioné anteriormente, aunque el tuyo es más comprensible y separa en dos Unit los códigos, lo que me parece más ordenado.
¿Este código debiera funcionar con cualquier cámara?
¿Se requiere alguna instrucción especial dependiendo del tipo de cámara?
Agradezco enormemente tu aporte, aunque no me haya servido, porque me hizo revisar este tema, que a la fecha no he logrado solucionar.

Salu2 y muchas gracias

Última edición por radenf fecha: 24-04-2010 a las 14:23:08.
Responder Con Cita
  #7  
Antiguo 01-05-2010
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Cool En algun punto esta la clave

Hola radenf, la verdad es que el codigo lo he probado solo con las camaras incorporadas a las notebooks, y en todas las maquinas que he probado el codigo ha funcionado muy bien, no tengo experiencia con camaras accesorias o externas, en teoria deberia funcionar de la misma manera siempre y cuando sea una sola la camara activa. Espero que resuelvas tu problema y lo comentes aqui con nosotros para ayudar a quien busque esta informacion.
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto
Responder Con Cita
  #8  
Antiguo 11-06-2011
luiayllon luiayllon is offline
Registrado
NULL
 
Registrado: jun 2011
Posts: 5
Poder: 0
luiayllon Va por buen camino
Una Gran Ayuda

Cita:
Empezado por casacham Ver Mensaje
Espero que este codigo les haya sido de utilidad y voy a estar esperando por correcciones, sugerencias y todo aquello que pueda ayudar a ampliar la info en este hilo para aquellos que realizan futuras busquedas sobre este tema.
Bueno esto es para capturar la imagen desde una camara ewb, ahora sera similar las instrucciones para capturar la imagen desde un escaner y depositarla en una carpeta.

GRACIAS ADELANTADO POR LA AYUDA
Responder Con Cita
  #9  
Antiguo 29-07-2011
Avatar de casacham
casacham casacham is offline
Miembro
 
Registrado: abr 2006
Ubicación: Cordoba->Argentina. Arboleas->Almeria->España
Posts: 184
Poder: 18
casacham Va por buen camino
Cool Podria Servir

El codigo podria ser de utilidad, no lo he probado. Pero en teoria si uno especifica la fuente de donde proviene la imagen, esta se puede capturar. Analiza mas el contenido del codigo a ver si te es de utilidad. Si lo logras, por favor publicalo en este hilo.

Gracias a todos.
__________________
La vida no trata de encontrarse a uno mismo, sino de crearse a uno mismo.
Tanto si piensas que puedes como si no, estarás en lo cierto
Responder Con Cita
  #10  
Antiguo 16-09-2011
socger socger is offline
Miembro
 
Registrado: jun 2004
Posts: 89
Poder: 20
socger Va por buen camino
Alguno de ustedes al final pudo averiguar como pasarle la fuente de la procedencia a esta API?

Muchas gracias de antemano

Última edición por socger fecha: 16-09-2011 a las 11:08:47. Razón: Necesito respuestas
Responder Con Cita
  #11  
Antiguo 13-10-2011
luigysiete luigysiete is offline
Registrado
NULL
 
Registrado: oct 2011
Posts: 1
Poder: 0
luigysiete Va por buen camino
Acabo de terminar una pequeña aplicacion utilizando los componentes dspack, esto es porque al igual que un usuario menciono, el codigo de este post solo me mostraba un cuadro negro al darle "Play" usando una webcam microsoft nx6000, investigando un poco mas encontre estos componentes gratuitos y muy faciles de usar, el pack original esta actualizado hasta Delphi7, yo hice una version para DelphiXE que es el que estoy usando, mi aplicacion permite seleccionar la fuente del video, y despues tomar una foto y guardarla en un archivo jpg, si a alguien le intereresa con gusto comparto el codigo asi como la actualizacion del dspack, intente compartir 2 enlaces pero como esta es mi primer colaboracion en el foro no me lo permitio, contacteme a quien le interesen, saludos desde Mexico!
Responder Con Cita
  #12  
Antiguo 31-07-2015
Avatar de benjaminao
benjaminao benjaminao is offline
Miembro
 
Registrado: mar 2008
Ubicación: Venezuela-Isla de Margarita
Posts: 16
Poder: 0
benjaminao Va por buen camino
Unhappy Error al recapturar con WebCam

Hola buenos días amigos, muchas gracias a todos por sus aportes a la comunidad. En esta oportunidad les escribo para solicitar su ayuda, ya que he implementado el código funciona todo ok utilizo delphi 7 con windows 7 en una SONY VAIO VPCSE core I5 8 Gb de ram con su webcam integrada. El problema que tengo es que solo puedo capturar imagen una vez, luego cuando vuelvo a ejecutar la aplicación la webcam no se activa, me aparece una ventana de dialogo que dice Origen de Video y debo seleccionar un dispositivo de vídeo, al aceptar la webcam no se enciende y ya no captura imagen alguna y para que funcione debo reiniciar la computadora y todo funcina bien otra vez, cabe destacar que he probado con otras aplicaciones como webCam Monitor 6 y sin necesidad de reiniciar si enciende la webcam y funciona sin problema, también he probado con otras computadoras y presenta el mismo problema. Me parece como que se quedara en ejecución algún proceso que no deja reconectar o encender la webcam desde mi aplicación, por que al reiniciar si vuelve a funcionar, he monitoreado desde el administrador de tareas y no veo nada.
Mucho les sabría agradecer su colaboración.
Responder Con Cita
  #13  
Antiguo 08-08-2015
Avatar de TiammatMX
TiammatMX TiammatMX is offline
Miembro
 
Registrado: jun 2006
Ubicación: Universo Curvo\Vía Láctea\Sistema Solar\Planeta Tierra\América\México\Puebla\Heróica Puebla de Zaragoza\Jardines de San Manuel\Home
Posts: 746
Poder: 18
TiammatMX Va camino a la fama
Talking ¡Felicidades!

Éste código es ESTUPENDO..., casi logra lo que necesito, excepto que cuando intento tomar una SEGUNDA "fotografía", me arroja éste error..., y lo peor, si después del error deseo cerrar (comando Close; de ObjectPASCAL) me envía el mismo error...

Código Delphi [-]
procedure TfrmPrincV2.btnCapturarClick(Sender: TObject);
var
   PanelDC: HDC;
begin
   if not Assigned(imgVideo.Picture.Bitmap) then
      imgVideo.Picture.Bitmap := TBitmap.Create
   else begin
      imgVideo.Picture.Bitmap.Free;
      imgVideo.picture.Bitmap := TBitmap.Create;
   end;

   with imgVideo do
   begin
      Picture.Bitmap.Height := pnlVisual.Height;
      Picture.Bitmap.Width  := pnlVisual.Width;
      Stretch := True;
   end;

   PanelDC := GetDC(pnlVisual.Handle);
   try
      BitBlt(imgVideo.Picture.Bitmap.Canvas.Handle, 0,0,pnlVisual.Width, pnlVisual.Height, PanelDC, 0, 0, SRCCOPY);
   finally
      ReleaseDC(Handle, PanelDC);
   end;
   
   Camara.SaveAsJPG(imgVideo);
end;

Por cierto, felicidades a CasaCham...
Imágenes Adjuntas
Tipo de Archivo: jpg Error.jpg (15,4 KB, 12 visitas)
__________________
Felipe Eduardo Ortiz López. Delphi programmers does it recursively...

"Un programador, es un creador de universos en donde sólo él es responsable. Universos de complejidad prácticamente ilimitada que se puede crear en forma de programas de ordenador." - Joseph Weizenbaum.

Témele a los profetas... y a aquellos que están listos para morir por "la verdad", ya que como regla general hacen morir a muchos otros con ellos, frecuentemente antes que ellos, y a veces en lugar de ellos. — Umberto Eco
Responder Con Cita
  #14  
Antiguo 17-12-2017
quini quini is offline
Registrado
NULL
 
Registrado: dic 2017
Posts: 2
Poder: 0
quini Va por buen camino
Yo tenía el mismo problema en Delphi 7 para Windows 7, lo solucioné dejando sólo la sentencia
Image1.picture.Bitmap := TBitmap.Create;

en el primer if del procedimiento Button2Click

Saludos

Última edición por Casimiro Notevi fecha: 17-12-2017 a las 02:30:06.
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
Webcam capturar imagen y adaptada ronald_tro Gráficos 18 14-12-2017 20:48:42
Capturar Fotografia desde Webcam ? martita Gráficos 11 13-12-2012 19:24:04
Capturar imagen webcam fmtidona Gráficos 4 25-11-2005 19:04:31
Capturar imagen de webcam en Monocromo fmtidona Gráficos 1 15-09-2005 23:18:49
Capturar imagen desde webcam wogshit Gráficos 1 03-06-2004 11:14:50


La franja horaria es GMT +2. Ahora son las 17:44:46.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi