Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > API de Windows
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 20-08-2005
rfernandez rfernandez is offline
Miembro
 
Registrado: ago 2003
Posts: 64
Poder: 21
rfernandez Va por buen camino
Localización real de una unidad mapeada.

Buenas compañeros.
Necesito saber si una unidad de disco es local o esta mapeada de otra maquina en red y en el caso de que este mapeada el valor real de la ruta de acceso.
Es decir si tengo la unidad F:\ que realmente es una unidad de la maquina llamada SERVIDOR i apunta a c:\documentos de dicha maquina saber por un lado que la maquina se llama SERVIDOR, o en su defecte su IP, i por otra la ruta c:\documentos.

Gracias.
Responder Con Cita
  #2  
Antiguo 20-08-2005
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Te pongo una rutinas para manejar mapeos que usé hace algún tiempo. Espero te sean de utilidad.


Código Delphi [-]
{
  Determina si una unidad lógica está disponible o no
}
function DriveAvailable(Drive: Char): Boolean;
var
  DriveType: Cardinal;

begin
  DriveType := GetDriveType(PChar(String(Drive) + ':'));
  Result := DriveType in [DRIVE_NO_ROOT_DIR, DRIVE_REMOTE];
end;

{
  Devuelve la ruta de red asignada a una unidad lógica
}
function GetConnection(Drive: Char): String;
var
  Buffer: PChar;
  BufferLen: Cardinal;
  Code: Cardinal;

begin
  Buffer := nil;
  BufferLen := 0;

  Code := WNetGetConnection(PChar(String(Drive) + ':'), Buffer, BufferLen);
  if Code = ERROR_MORE_DATA then
  begin
    GetMem(Buffer, BufferLen);
    Code := WNetGetConnection(PChar(String(Drive) + ':'), Buffer, BufferLen);
  end;

  case Code of
    NO_ERROR: Result := Buffer;
    ERROR_NOT_CONNECTED: Result := '';
    ERROR_CONNECTION_UNAVAIL: Result := 'Connection is unavailable';
  else
    raise Exception.CreateFmt('Error reading information for drive %s:', [Drive]);
  end;

  if BufferLen <> 0 then FreeMem(Buffer);
end;

{
  Devuelve si una unidad lógica está redirigida o no
}
function IsMapped(Drive: Char): Boolean;
begin
  Result := GetConnection(Drive) <> '';
end;

{
  Devuelve si una ruta de red puede asignarse
  a una unidad lógica o no.
}
function IsMappable(Path: String): Boolean;
var
  ShFileInfo: TShFileInfo;

begin
  ShGetFileInfo(PChar(Path), 0, ShFileInfo, SizeOf(ShFileInfo), SHGFI_ATTRIBUTES);
  Result := ShFileInfo.dwAttributes and SFGAO_FILESYSTEM <> 0;
end;

{
  Redirige una unidad lógica a una ruta de red
}
procedure MapDrive(Drive: Char; NetPath: String; MakePermanent: Boolean);
var
  NetResource: TNetResource;
  Flags: Cardinal;
  Code: Cardinal;

begin
  NetResource.dwType := RESOURCETYPE_DISK;
  NetResource.lpLocalName := PChar(String(Drive) + ':');
  NetResource.lpRemoteName := PChar(NetPath);
  NetResource.lpProvider := nil;

  if MakePermanent
    then Flags := CONNECT_UPDATE_PROFILE
    else Flags := 0;

  Code := WNetAddConnection2(NetResource, nil, nil, Flags);
  if Code <> NO_ERROR then
    RaiseLastOSError;
end;

// Saludos
Responder Con Cita
  #3  
Antiguo 20-08-2005
rfernandez rfernandez is offline
Miembro
 
Registrado: ago 2003
Posts: 64
Poder: 21
rfernandez Va por buen camino
Casi.
Super interesante lo que me has enviado, seguro que lo reutilizaré para alguna cosa.

Pero lo que necesito es que la funcion que me envias GetConnection(drive) en lugar de enviarme la ruta mapeada, por ejemplo, \\servidor\documentos, me enviase seria la ruta fisica real de 'documentos' por ejemplo c:\datos\documentos del ordenador 'servidor'.

Gracias de todas todas.
Responder Con Cita
  #4  
Antiguo 21-08-2005
Avatar de Crandel
[Crandel] Crandel is offline
Miembro Premium
 
Registrado: may 2003
Ubicación: Parana, Argentina
Posts: 1.475
Poder: 22
Crandel Va por buen camino
usa esta función

Código Delphi [-]
Function GetDrivePath(DriveLetter:String):String;
var Buffer: array[0..255] of char;
begin
    DriveLetter := Copy(DriveLetter,1,1)+':';
    FillChar(Buffer,SizeOf(Buffer),#0);
    QueryDosDevice(PChar(DriveLetter),Buffer,SizeOf(Buffer));
    Result := StrPas(Buffer);
End;
__________________
[Crandel]
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro


La franja horaria es GMT +2. Ahora son las 10:56:49.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi