Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Varios
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 20-05-2007
JXJ JXJ is offline
Miembro
 
Registrado: Apr 2005
Posts: 2.473
Poder: 16
JXJ Va por buen camino
¿¿Aplicacion no GUI. que no se cierre sola???

Hola. estoy viendo como hacer una aplicacion, que no
muestre una interfaz grafica. pensando en hacer un
para un servidor FTP , para la pc donde vivo poder subir
mis archivos de trabajo..

tengo este esqueleto basico,

Código Delphi [-]
program miprograma;
uses
SysUtils;

//Inicia el programa
begin

end.

Entonces, les pregunto,
¿ como puedo hacer que
mi programa no se cierre, o finalize hasta que se le ordene
finalizar.?

el programa no se comparta como si fuese
una aplicacion delphi normal
esperando algo a que explicitamente se le ordene cerrarse.

quiero que el ftp se quede escuchando en un puerto
y si recibe el comando de cerrar, finalize la aplicación.

gracias por su atención
Responder Con Cita
  #2  
Antiguo 20-05-2007
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: Feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 18
seoane Va por buen camino
¿Que tal con un bucle?
Código Delphi [-]
program miprograma;
uses 
SysUtils;

//Inicia el programa
begin
  while TRUE do
  begin

  end;
end.

Aunque puede que necesitemos que la CPU respire:
Código Delphi [-]
program miprograma;
uses 
SysUtils;

//Inicia el programa
begin
  while TRUE do
  begin
    

    Sleep(10);
  end;
end.
Responder Con Cita
  #3  
Antiguo 20-05-2007
JXJ JXJ is offline
Miembro
 
Registrado: Apr 2005
Posts: 2.473
Poder: 16
JXJ Va por buen camino
Hola
Seoane
gracias por tu atención

este... como que no entiendo bien, como funciona eso de
Mientras sea verdad ¿¿que ???
Esta criptico para mi.

Código Delphi [-]
while TRUE do //True o verdad que ??:S:S:S
  begin
    

    Sleep(10);//<- Este si se que detiene en milisegundos.
  end;

//--Asi probe el codigo y funciona.

Código Delphi [-]
{$SetPEFlags 1} //<-Directiva reduce tamaño del exe, solo disponible desde delphi 2005 hasta D2007 win32 
program GServerc;

uses
SysUtils, Dialogs;

var
contador: Integer;
Cerrar : Boolean;

//Inicia el programa
begin
    Contador := 1;
    Cerrar := False;
    //Bucle que mantendrá el programa vivo
  while True do
  begin
      Sleep(10);//<- Descansamos el CPU 
      if Cerrar = False then
      begin
        Contador := Contador +1;
        if contador = 100 then
      begin
      Cerrar := True;
        showmessage(intToStr(Contador));
     end

      end
      else
        //Si deseamos hacer algo al salir ponerlo aquí
        Break;
    end;


end.
Responder Con Cita
  #4  
Antiguo 20-05-2007
Avatar de MAXIUM
MAXIUM MAXIUM is offline
Miembro
 
Registrado: May 2005
Posts: 1.340
Poder: 15
MAXIUM Va por buen camino
en mis tiempos de Turbo Pascal usaba un keypressed con un
While, lo que resultaba que al presionar una tecla o una determinada tecla (ESC) finalizaba la instrucción.

Alternativas sencillas: usar un readkey o un comando SHELL (pause) al final.

Código Delphi [-]
if Cerrar = False then

Cerra es un boleano entonces:

Código Delphi [-]
if not Cerrar then
Responder Con Cita
  #5  
Antiguo 20-05-2007
JXJ JXJ is offline
Miembro
 
Registrado: Apr 2005
Posts: 2.473
Poder: 16
JXJ Va por buen camino
MAXIUM

voy a probar lo que mencionas.
Responder Con Cita
  #6  
Antiguo 20-05-2007
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: Feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 18
seoane Va por buen camino
Bien, si un bucle no es suficiente vamos a hacer las cosas a lo grande. Primero necesitamos crear una función para manejar las señales que son enviadas a la aplicación. Una como esta:
Código Delphi [-]
function HandlerRoutine(dwCtrlType: DWORD): BOOL; stdcall;
begin
  Result:= TRUE;
  case dwCtrlType of
    CTRL_C_EVENT:
      Terminar:= TRUE;
    CTRL_CLOSE_EVENT:
      Terminar:= TRUE;
    CTRL_LOGOFF_EVENT:
      Terminar:= TRUE;
    CTRL_SHUTDOWN_EVENT:
      Terminar:= TRUE;
    else
      Result:= FALSE;
  end;
end;
Aquí yo pongo una variable global (Terminar) a false como respuesta a todos los eventos. Tu puedes manejar esos eventos como prefieras, solo tienes que tener en cuenta que si la función devuelve FALSE la señal se pasa al siguiente manejador.

Ahora que ya manejamos los eventos Ctrl+C, Close, Logoff y Shutdown, no estaría mal disponer de un bucle de mensajes en nuestra aplicación. Si vas a usar algún timer, o algún componente que maneje internamente mensajes, este bucle sera imprescindible. Lo primero vamos a crear una función similar al famoso "Application.ProcessMessages", algo así:
Código Delphi [-]
procedure ProcessMessages;
var
  Msg: TMsg;
begin
  while PeekMessage(Msg,0,0,0,PM_REMOVE) do
  begin
    if Msg.Message = WM_QUIT then
    begin
      Terminar:= TRUE;
      break;
    end else
    begin
      TranslateMessage(Msg);
      DispatchMessage(Msg);
    end;
  end;
end;

Ahora solo nos falta encajar todo esto en nuestra aplicacion la cosa quedaria mas o menos asi:
Código Delphi [-]
program Ejemplo;

{$APPTYPE CONSOLE}

uses Windows, Messages, SysUtils;

var
  Terminar: Boolean;

procedure ProcessMessages;
var
  Msg: TMsg;
begin
  while PeekMessage(Msg,0,0,0,PM_REMOVE) do
  begin
    if Msg.Message = WM_QUIT then
    begin
      Terminar:= TRUE;
      break;
    end else
    begin
      TranslateMessage(Msg);
      DispatchMessage(Msg);
    end;
  end;
end;

function HandlerRoutine(dwCtrlType: DWORD): BOOL; stdcall;
begin
  Result:= TRUE;
  case dwCtrlType of
    CTRL_C_EVENT:
      Terminar:= TRUE;
    CTRL_CLOSE_EVENT:
      Terminar:= TRUE;
    CTRL_LOGOFF_EVENT:
      Terminar:= TRUE;
    CTRL_SHUTDOWN_EVENT:
      Terminar:= TRUE;
    else
      Result:= FALSE;
  end;
end;

begin
  Terminar:= FALSE;
  if SetConsoleCtrlHandler(@HandlerRoutine,TRUE) then
    while not Terminar do
    begin
      // Aqui haz lo que quieras

      ProcessMessages;
      if not Terminar then
        Sleep(10);
    end;
end.
Donde pone "Aquí haz lo que quieras" coloca tu código, solo recuerda, que si vas a colocar un bucle dentro de tu código, deberás tener en cuenta la variable Terminar y llamar de vez en cuando a la función "ProcessMessages" para vaciar la cola de mensajes.

Por cierto, para cerrar la aplicación puedes usar Ctrl+C o la X de la ventana con la consola, da igual, la aplicación se cerrara limpiamente poniendo la variable Terminar a true y saliendo del bucle.

Última edición por seoane fecha: 20-05-2007 a las 10:27:30.
Responder Con Cita
  #7  
Antiguo 20-05-2007
JXJ JXJ is offline
Miembro
 
Registrado: Apr 2005
Posts: 2.473
Poder: 16
JXJ Va por buen camino
Muy interesante, gracias Seoane
Responder Con Cita
  #8  
Antiguo 20-05-2007
Avatar de dec
dec dec is offline
Moderador
 
Registrado: Dec 2004
Ubicación: Alcobendas, Madrid, España
Posts: 12.617
Poder: 27
dec Va camino a la famadec Va camino a la fama
Hola,

Me sumo a lo dicho por JXJ, Seoane, muy interesante. Muchas gracias.
__________________
David Esperalta
www.davidesperalta.com
Responder Con Cita
  #9  
Antiguo 10-07-2008
JXJ JXJ is offline
Miembro
 
Registrado: Apr 2005
Posts: 2.473
Poder: 16
JXJ Va por buen camino
una dudas mas

¿para cerrarlo, via codigo, digamos con sin ser una aplicacion tipo cosola?


Código Delphi [-]
program Ejemplo;


uses Windows, Messages, SysUtils;

var
  Terminar: Boolean;

procedure ProcessMessages;
var
  Msg: TMsg;
begin
  while PeekMessage(Msg,0,0,0,PM_REMOVE) do
  begin
    if Msg.Message = WM_QUIT then
    begin
      Terminar:= TRUE;
      break;
    end else
    begin
      TranslateMessage(Msg);
      DispatchMessage(Msg);
    end;
  end;
end;

function HandlerRoutine(dwCtrlType: DWORD): BOOL; stdcall;
begin
  Result:= TRUE;
  case dwCtrlType of
    CTRL_C_EVENT:
      Terminar:= TRUE;
    CTRL_CLOSE_EVENT:
      Terminar:= TRUE;
    CTRL_LOGOFF_EVENT:
      Terminar:= TRUE;
    CTRL_SHUTDOWN_EVENT:
      Terminar:= TRUE;
    else
      Result:= FALSE;
  end;
end;

begin
  Terminar:= FALSE;
  if SetConsoleCtrlHandler(@HandlerRoutine,TRUE) then
    while not Terminar do
    begin
      // Aqui haz lo que quieras


      ProcessMessages;
      if not Terminar then
        Sleep(10);
    end;
end.


ya me perdi. en esto :S

gracias..
Responder Con Cita
  #10  
Antiguo 10-07-2008
Avatar de seoane
[seoane] seoane is offline
Miembro Premium
 
Registrado: Feb 2004
Ubicación: A Coruña, España
Posts: 3.717
Poder: 18
seoane Va por buen camino
Cita:
Empezado por JXJ Ver Mensaje
¿para cerrarlo, via codigo, digamos con sin ser una aplicacion tipo cosola?
Lo adecuado, si no quieres una aplicación de consola, es crear una ventana (aunque permanezca oculta) y utilizar su bucle de mensajes. Cuando quieras cerrar la aplicación solo tendrás que mandar el mensaje WM_CLOSE. Por otro lado si tu aplicación no es de consola, por que no creas una aplicación normal de delphi y ocultas el formulario principal
Responder Con Cita
  #11  
Antiguo 10-07-2008
JXJ JXJ is offline
Miembro
 
Registrado: Apr 2005
Posts: 2.473
Poder: 16
JXJ Va por buen camino
por creerme bien picudo..

estoy re-revisando tu servidor web pico..
y en creer que puedo hacer un servidor tcpip. con indy. usando el dpr.
y darle la opcion de desconectarse y cerrarse a si mismo usando un comando
desde el cliente..
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
una sola instancia de la aplicacion morfeo21 Varios 6 24-10-2014 03:40:50
Guardar antes de que mi aplicacion se cierre Gelmin Varios 4 24-09-2008 09:20:23
Verificar el cierre de una aplicacion remota JAI_ME Varios 1 07-05-2007 00:06:35
Ejecutar algo antes de que se cierre la aplicación Jan_polero API de Windows 3 28-02-2005 10:45:47
Impedir cierre de aplicacion Ezecool Varios 1 04-08-2003 23:29:47


La franja horaria es GMT +2. Ahora son las 17:29:47.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi