Type of expression must be BOOLEAN

[chuli17]

Hola buenas, aber si alguien me echa una mano, en la primera linea de ese codigo me da error "Type of expression must be BOOLEAN" y con mas vueltas que le doy nose porque... lo agradeceria muchisimo si me echais una mano

Código Delphi [-]
if Buscar(Lista,s + 'Nueva carpeta',Mascaras)then
      Form2.Show;
      Form2.RichEdit1.Lines.Add(Lista.Text);
      else
      ShowMessage('Nada Encontrado');

[[oscarac]]

puedes colocar el código de la función buscar?

[[ElKurgan]]

¿Y como está definida la función "Buscar"?

Saludos

[cloayza]

Creo que el código que escribiste tiene algunos problemillas..

Código Delphi [-]
if Buscar(Lista,s + 'Nueva carpeta',Mascaras)then
begin
      Form2.Show;
      Form2.RichEdit1.Lines.Add(Lista.Text);
end
else
      ShowMessage('Nada Encontrado');

Saludos

[[oscarac]]

Empezado por cloayza

Creo que el código que escribiste tiene algunos problemillas..

Código Delphi [-]
if Buscar(Lista,s + 'Nueva carpeta',Mascaras)then
begin
      Form2.Show;
      Form2.RichEdit1.Lines.Add(Lista.Text);
end
else
      ShowMessage('Nada Encontrado');

Saludos

eso iba a indicarle, te me adelantaste

[chuli17]

Hola buenas aqui esta la funcion buscar, y gracias a todos por responder.

Código Delphi [-]
procedure Buscar(Lista: TStringList; Path, Mascara: String); overload;
var
  SR: TSearchRec;
begin
  Path:= IncludeTrailingPathDelimiter(Path);
  if FindFirst(Path + '*.*', faAnyfile, SR) = 0 then
  repeat
    if (SR.Name <>  '.') and (SR.Name <> '..') then
      if (SR.Attr and faDirectory) = faDirectory then
        Buscar(Lista,Path+SR.Name,Mascara);
  until FindNext(SR) <> 0;
  FindClose(SR);
  if FindFirst(Path + Mascara, faAnyfile, SR) = 0 then
  repeat
    if (SR.Name <>  '.') and (SR.Name <> '..') then
      if (SR.Attr and faDirectory) <> faDirectory then
        Lista.Add(Path + SR.Name);
  until FindNext(SR) <> 0;
  FindClose(SR);
end;

procedure Buscar(Lista: TStringList; Path: String; Mascaras: TStringList); overload;
var
  i: Integer;
begin
  for i:= 0 to Mascaras.Count - 1 do
    Buscar(Lista,Path,Mascaras[i]);
end;


procedure TForm1.FormCreate(Sender: TObject);

var
   drive : Char;
   tipo : Integer;
begin
   for drive:= 'A' to 'Z' do
   begin
      tipo := GetDriveType(PChar(drive+':\'));
      if tipo <> 0 then
       case tipo of
         DRIVE_REMOVABLE: Combobox1.Items.Add(drive + ':\' + '   (Disco Extraible)');
         DRIVE_FIXED: Combobox1.Items.Add(drive + ':\' + '   (Disco Duro)');
         DRIVE_RAMDISK: Combobox1.Items.Add(drive + ':\' + '   (Ram Disk)');
       end;//Case
   end;
   end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Lista: TStringList;
  Mascaras: TStringList;
  s: string;
begin
  Lista:= TStringList.Create;
  try
    Mascaras:= TStringList.Create;
    try
      Mascaras.Add('1.DAT');
      Mascaras.Add('2.DAT');
      Mascaras.Add('3.DAT');
      s:= Copy(Combobox1.Text,1,3);
      if Buscar(Lista,s + 'Nueva carpeta',Mascaras)then // Aqui en esta linea da el error
      begin
      Form2.Show;
      Form2.RichEdit1.Lines.Add(Lista.Text);
      end
else
      ShowMessage('Nada Encontrado');
    finally
      Mascaras.Free;
    end;

  finally
    Lista.Free;
  end;
end;

[TiammatMX]

Pues es claro..., Buscar primeramente debe ser una FUNCIÓN (no un procedimiento) y ésta función debe regresar un valor booleano o lógico para que la condición que la llama sea correcta.

[ecfisa]

Hola chuli17.

Tal como te indica tiammat un procedimiento no devuelve valor alguno.

Lo que podrías hacer es:

Código Delphi [-]
...
  Buscar(Lista, s + 'Nueva carpeta', Mascaras);
  if Lista.Count > 0 then // Si encontro alguna coincidencia...
  begin
     ...

Saludos