Formato de Salida de una Imagen

[Drake]

Buenas de nuevo tengo un problemilla (como de costumbre xD), al guardar las imagenes de un componente TImage en un archivo al guardarlos con extension PNG JPG o BMP el archivo de salida no se guarda con el formato indicado es decir por ejemplo si escribo el siguiente codigo:

Código Delphi [-]
Image1.Picture.SavetoFile('C:\prueba.jpg');

La imagen se guarda con extension JPG pero el formato de esta no es el mismo ¿que deberia de poner para solucionar este problema?

[[seoane]]

Timage no convierte entre formatos gráficos, le da igual la extensión que le pongas al archivo, si tienes cargado un bitmap lo guardara como bitmap, si es un jpeg se guardara como un jpeg. Si quieres guardar en un formato distinto tienes que hacer la conversión tu mismo. Si haces una búsqueda por el foro, o en los trucos, encontraras varias formas de hacer lo que tu quieres.

Yo te voy a dejar un par de métodos, uno que guarda la imagen como Jpeg y otro que cambia el tipo de imagen cargada en el TImage. Puedes usar el que mas te guste.

Código Delphi [-]
uses JPEG;

procedure GuardarComoJpeg(Imagen: TPicture; Filename: string);
var
  Bitmap: TBitmap;
  Jpeg: TJPEGImage;
begin
  Jpeg:= TJpegImage.Create;
  try
    if not (Imagen.Graphic is TBitmap) then
    begin
      Bitmap:= TBitmap.Create;
      try
        Bitmap.Width:= Imagen.Width;
        Bitmap.Height:= Imagen.Height;
        Bitmap.Canvas.Draw(0,0,Imagen.Graphic);
        Jpeg.Assign(Bitmap);
      finally
        Bitmap.Free;
      end;
    end else Jpeg.Assign(Imagen.Bitmap);
    Jpeg.SaveToFile(Filename);
  finally
    Jpeg.Free;
  end;
end;

Ejemplo de uso:

Código Delphi [-]
GuardarComoJpeg(Image1.Picture,'c:\imagen.jpg');

La otra forma es la siguiente:

Código Delphi [-]
uses JPEG;

procedure ABitmap(Imagen: TPicture);
var
  Bitmap: TBitmap;
begin
  if not (Imagen.Graphic is TBitmap) then
  begin
    Bitmap:= TBitmap.Create;
    try
      Bitmap.Width:= Imagen.Width;
      Bitmap.Height:= Imagen.Height;
      Bitmap.Canvas.Draw(0,0,Imagen.Graphic);
      Imagen.Assign(Bitmap);
    finally
      Bitmap.Free;
    end;
  end;
end;

procedure AJpeg(Imagen: TPicture);
var
  Jpeg: TJPEGImage;
begin
  if not (Imagen.Graphic is TJPEGImage) then
  begin
    ABitmap(Imagen);
    Jpeg:= TJPEGImage.Create;
    try
      Jpeg.Assign(Imagen.Bitmap);
      Imagen.Assign(Jpeg);
    finally
      Jpeg.Free;
    end;
  end;
end;

Ejemplo de uso:

Código Delphi [-]
  AJpeg(Image1.Picture);
  image1.Repaint;
  // Una vez convertida la imagen al guardarla lo hara como Jpeg

[Drake]

Va perfect para el JPG, pero podrias echarme una mano con el formato BMP y PNG sobre todo el PNG que es el k mas manejo.

[[seoane]]

Delphi no puede manejar imágenes PNG, por lo menos en la versión 7 que es la que yo uso. Así que hay que recurrir a librerías de terceros, en este caso yo he utilizado pngdelphi. Aquí te dejo un ejemplo, abre una imagen y te permite guardarla en los tres formatos bmp, jpg y png.

Como el ejemplo tiene un tamaño de 89Kb he tenido que subirlo aqui
http://rapidshare.de/files/27372118/Ejemplo24.zip.html

Tambien he subido el archivo ya compilado
http://rapidshare.de/files/27372207/...4_exe.zip.html

[Drake]

Gracias de nuevo seoane me fueron muy utiles tus ejemplos para el programa aki te dejo una imagen del programa por si kieres colaborar.
http://darkent.mundoserver.org/debug4.PNG