Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Impresión
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 22-11-2018
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Epson TM900 Parametros dll

Hola, estoy luchando con una Dll de una impresora Epson Fiscal (TM900), la que viene en la definición

DLL_EXPORT_IMPORT int DLL_STD_CALL
ConsultarVersionDll( char *respuesta_descripcion, int respuesta_descripcion_largo_maximo, int *respuesta_mayor, int *respuesta_menor );

En un ejemplo que trae la misma librería esta definida :

Código Delphi [-]
type
  TConsultarVersionDll = function ( descripcion : PChar; descripcion_largo_maximo: LongInt; var mayor : LongInt; var menor : LongInt) : LongInt; StdCall;
  
var
  dll  : THandle;
  error : LongInt;
  str : Array[0..100] of Char;
  mayor : LongInt;
  menor : LongInt;

  ConsultarVersionDll: TConsultarVersionDll;

begin
  dll := 0;

  // instanciar dll - recordar que se require "uses Windows"
  // for production -- dll := LoadLibrary('EpsonFiscalInterface.dll');
  dll := LoadLibrary('EpsonFiscalInterface.dll');

  // check error
  if dll = 0 then
  begin
    ShowMessage('Error al instanciar DLL');
    Exit;
  end;

  // obtener las referencias a funciones:  "ConsultarVersionDll"
  @ConsultarVersionDll := GetProcAddress(dll, 'ConsultarVersionDll');
  if not Assigned(ConsultarVersionDll) then
  begin
    ShowMessage('Error al asignar funcion: ConsultarVersionDll');
    Exit;
  end;
  
  // execute ConsultarVersionDll
  mayor := 0;
  menor := 0;
  str := StringOfChar (' ', 100);

  error := ConsultarVersionDll( str, 100, mayor, menor );

  ShowMessage( str );
  ShowMessage( IntToStr(mayor) );
  ShowMessage( IntToStr(menor) );
  ShowMessage( IntToStr(error) );

  // desalocar dll
  FreeLibrary(dll);
end;

Esto siempre da error y he probado cambiar los tipo de datos pero nada funciona
Responder Con Cita
  #2  
Antiguo 22-11-2018
cloayza cloayza is offline
Miembro
 
Registrado: may 2003
Ubicación: San Pedro de la Paz, Chile
Posts: 910
Poder: 22
cloayza Tiene un aura espectacularcloayza Tiene un aura espectacular
Veamos si esto soluciona el problema...
Código Delphi [-]
var
...
  str : string;
 ...
begin
      ...
      SetLength(str, 100);

     error := ConsultarVersionDll( PChar(str), Length(str), mayor, menor );
     ....
end;
Saludos cordiales
Responder Con Cita
  #3  
Antiguo 22-11-2018
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Cita:
Empezado por cloayza Ver Mensaje
Veamos si esto soluciona el problema...
Código Delphi [-]
var
...
  str : string;
 ...
begin
      ...
      SetLength(str, 100);

     error := ConsultarVersionDll( PChar(str), Length(str), mayor, menor );
     ....
end;
Saludos cordiales
Muchas gracias por tu respuesta.
El problema sigue igual. Mi duda es si el problema esta en el PChar o los tipos enteros. Segun la definicion de la dll cuando tiene un * delante es un puntero. Si es asi deberia definir los Longint como pint o pint64 o algo asi... ya lo probe tambien y sin solucion.
Saludos!
Responder Con Cita
  #4  
Antiguo 23-11-2018
Avatar de escafandra
[escafandra] escafandra is offline
Miembro Premium
 
Registrado: nov 2007
Posts: 2.195
Poder: 20
escafandra Tiene un aura espectacularescafandra Tiene un aura espectacular
¿Donde falla el código?



La dll debe estar en la carpeta del ejecutable o estar registrada en la ruta Windows\System32. El ejemplo que pones se basa en localizar el puntero a la función exportada por la dll de forma dinámica con GetProcAddress. Lo primero que hay que ver es donde está fallando, si es en la importación dinámica o en la ejecución.



Cuando una función exportada estilo C espera un puntero, desde delphi puede declararse como paso por referencia sin problemas que es como está en el ejemplo que muestras.
Las cadenas pueden ser estilo clasico o unicode, no sebemos que estilo dtiene esa dll, al menos no lo sabemos en el foro. puedes forsar la declaración con PAnsiChar que funcionará si tu delphi usa Unicode por defecto y la dll usa Char clasico (AnsiChar)



Prueva a declararla así:
Código Delphi [-]
TConsultarVersionDll = function (descripcion: PAnsiChar; descripcion_largo_maximo: integer; var mayor: integer; var menor: integer): integer; stdcall;

Saludos.
Responder Con Cita
  #5  
Antiguo 23-11-2018
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Cita:
Empezado por escafandra Ver Mensaje
¿Donde falla el código?

La dll debe estar en la carpeta del ejecutable o estar registrada en la ruta Windows\System32. El ejemplo que pones se basa en localizar el puntero a la función exportada por la dll de forma dinámica con GetProcAddress. Lo primero que hay que ver es donde está fallando, si es en la importación dinámica o en la ejecución.

Cuando una función exportada estilo C espera un puntero, desde delphi puede declararse como paso por referencia sin problemas que es como está en el ejemplo que muestras.
Las cadenas pueden ser estilo clasico o unicode, no sebemos que estilo dtiene esa dll, al menos no lo sabemos en el foro. puedes forsar la declaración con PAnsiChar que funcionará si tu delphi usa Unicode por defecto y la dll usa Char clasico (AnsiChar)



Prueva a declararla así:
Código Delphi [-]
TConsultarVersionDll = function (descripcion: PAnsiChar; descripcion_largo_maximo: integer; var mayor: integer; var menor: integer): integer; stdcall;

Saludos.
Hola escafandra, gracias por tu respuesta.
La dll se carga y funciona. Las funciones que no llevan parametros son bien aceptados por la impresora. El tema son los parametros.
Probe de la forma que me has indicado, no se cual de los parametros sera el problema. Tendria que comenzar con alguna funcion que tenga un solo parametro a ver que pasa.
La documentacion de la dll es la que puse al comienzo del post.
He probado usando punteros en los parametros Integer, he usado "var" para el 1e parametro, He usado widestring, pchar, string, pstring, ansistring....ya no que poner.
El codigo de error que me devuelve en todos los casos es 83886082 que no hay referencia en los documentos de epson.

Saludos
Responder Con Cita
  #6  
Antiguo 23-11-2018
Avatar de escafandra
[escafandra] escafandra is offline
Miembro Premium
 
Registrado: nov 2007
Posts: 2.195
Poder: 20
escafandra Tiene un aura espectacularescafandra Tiene un aura espectacular
Quizás pueda ayudarte mejor si subes esa dll.

Saludos.
Responder Con Cita
  #7  
Antiguo 24-11-2018
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Cita:
Empezado por escafandra Ver Mensaje
Quizás pueda ayudarte mejor si subes esa dll.

Saludos.
Te agradezco enormemente, no pude subirlo por el tamaño pero te dejo el link de Epson para bajarlo.

https://ftp.epson.com/drivers/EpsonF...e.02.06.00.zip

Creo que la única función que podrías probar es la de la versión de la dll, las otras necesitaran estar conectadas a la impresora.

Yo sigo intentando e investigando. Mil gracias Escafandra!!
Responder Con Cita
  #8  
Antiguo 24-11-2018
Avatar de escafandra
[escafandra] escafandra is offline
Miembro Premium
 
Registrado: nov 2007
Posts: 2.195
Poder: 20
escafandra Tiene un aura espectacularescafandra Tiene un aura espectacular
El problema está en el tamaño de la cadena. Prueba de esta forma:


Código Delphi [-]
type
  TConsultarVersionDll = function ( descripcion : PAnsiChar; descripcion_largo_maximo: LongInt; var mayor : LongInt; var menor : LongInt) : LongInt; StdCall;


var
  dll  : THandle;
  error : LongInt;
  str : Array[0..200] of AnsiChar;
  mayor : LongInt;
  menor : LongInt;
  ConsultarVersionDll: TConsultarVersionDll;
begin
  dll := 0;

  // instanciar dll - recordar que se require "uses Windows"
  // for production -- dll := LoadLibrary('EpsonFiscalInterface.dll');
  dll := LoadLibrary('EpsonFiscalInterface.dll');

  // check error
  if dll = 0 then
  begin
    ShowMessage('Error al instanciar DLL');
    Exit;
  end;

  // obtener las referencias a funciones:  "ConsultarVersionDll"
  @ConsultarVersionDll := GetProcAddress(dll, 'ConsultarVersionDll');
  if not Assigned(ConsultarVersionDll) then
  begin
    ShowMessage('Error al asignar funcion: ConsultarVersionDll');
    Exit;
  end;
  
  // execute ConsultarVersionDll
  mayor:= 0;
  menor:= 0;
  error := ConsultarVersionDll(@str[0], 200, mayor, menor );

  ShowMessage( str );
  ShowMessage( IntToStr(mayor) );
  ShowMessage( IntToStr(menor) );
  ShowMessage( IntToStr(error) );

  // desalocar dll
  FreeLibrary(dll);
end;

También puedes hacerlo de forma estática de esta forma:
Código Delphi [-]
function ConsultarVersionDll(descripcion: PAnsiChar; descripcion_largo_maximo: LongInt; var mayor : LongInt; var menor : LongInt): LongInt; stdcall; external 'EpsonFiscalInterface.dll';

var
  error : LongInt;
  str : Array[0..200] of AnsiChar;
  mayor : LongInt;
  menor : LongInt;
begin
  ConsultarVersionDll(str, 200, mayor, menor);
  ShowMessage(Str +#13 + 'Mayor: '+ IntToStr(mayor) + #13 + 'Menor: ' + IntToStr(menor));
end;



Saludos.

Última edición por escafandra fecha: 24-11-2018 a las 02:22:26.
Responder Con Cita
  #9  
Antiguo 24-11-2018
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Escafandra, me has mostrado que tengo tanto por aprender, ni siquiera puedo intuir como lo has sabido.
La forma estática es mas sencilla y clara. Y el @str[0] que has puesto creo que nunca lo entenderé.
Ahora voy por el resto de la dll. Espero me trate mejor. Quizás me tome el atrevimiento de preguntarte por alguna regla sobre las dll, pero quiero intentar y sobre todo entender.
Enormemente agradecido.

Saludos
Responder Con Cita
  #10  
Antiguo 24-11-2018
Avatar de escafandra
[escafandra] escafandra is offline
Miembro Premium
 
Registrado: nov 2007
Posts: 2.195
Poder: 20
escafandra Tiene un aura espectacularescafandra Tiene un aura espectacular
Cita:
Empezado por omarperez.qui Ver Mensaje
Escafandra, me has mostrado que tengo tanto por aprender, ni siquiera puedo intuir como lo has sabido.
Cuando el paso de parametros es correcto hay que buscar los puntos que pueden generar errores. El tamaño de una cadena cuando se pasa su puntero es uno de ellos. Hay que seguir el humo para encontrar el incendio.

Cita:
Empezado por omarperez.qui Ver Mensaje
Escafandra, me has mostrado que tengo tanto por aprender, ni siquiera puedo intuir como lo has sabido.
La forma estática es mas sencilla y clara.
Pero en tiempo de ejecución no puedes controlar la asignación de la función importada y el programa dará un error al inicio y se abortará si la dll no se encuentra o tiene un error

Cita:
Empezado por omarperez.qui Ver Mensaje
Y el @str[0] que has puesto creo que nunca lo entenderé.
@str[0] es para pasar un puntero al primer elemento del array. La dll está pidiendo una cadena estilo C, y en C una cadena es un array; y un array se representa por un puntero a su primer elemento. En este caso también vale poniendo el nombre del array estático como te puse en el otro ejemplo.

Saludos.
Responder Con Cita
  #11  
Antiguo 24-11-2018
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Cita:
La dll está pidiendo una cadena estilo C, y en C una cadena es un array; y un array se representa por un puntero a su primer elemento. En este caso también vale poniendo el nombre del array estático como te puse en el otro ejemplo.
Esto significa que en una funcion, por ej. CargarDatosCliente() las cadenas debo definirlas como Array igual que el anterior? Pueden ser dinamicas, sin tamaño?

Código Delphi [-]
type
  TCargarDatosCliente  = function ( nombre_o_razon_social1 :PansiChar;  nombre_o_razon_social2 :PansiChar;
                                   domicilio1 :PansiChar; domicilio2:PansiChar;  domicilio3:PansiChar;
                                 id_tipo_documento :LongInt; numero_documento:PansiChar; id_responsabilidad_iva :LongInt): LongInt; StdCall;

var
  Nombre1 : Array of char[];
  Nombre2 : Array of char[];
  Direccion1 : Array of char[];
  Direccion2 : Array of char[];
  TipoDoc:LongInt;
  NroDoc:LongInt;
  idIVA:LongInt;
Begin
  @CargarDatosCliente := GetProcAddress(dll, 'CargarDatosCliente');

  Nombre1:=' JUAN PEREZ';
  Nombre2:='';
  Direccion1:='Calle Nº';
  Direccion2:='Localidad..';
  TipoDoc := 1; //DNI
  NroDoc := 10000000;
  idIVA := 1; //IVA Insc
  error := CargarDatosCliente( @CargarDatosCliente,  @Nombre1[0],@Nombre2[0],@Direccion1[0],@Direccion2[0], TipoDoc , NroDoc, IdIVA );
  ShowMessage( IntToStr(error) );

End;
Responder Con Cita
  #12  
Antiguo 25-11-2018
Avatar de escafandra
[escafandra] escafandra is offline
Miembro Premium
 
Registrado: nov 2007
Posts: 2.195
Poder: 20
escafandra Tiene un aura espectacularescafandra Tiene un aura espectacular
En primer lugar Nombre1: Array of char[] es un error sintáctico en delphi. en todo caso sería Nombre1: Array of char
En segundo lugar, un array no es un String por lo que no puedes asignarle uno.

Para encontrar el puntero tipo CHAR de un String delphi basta con hacer el cast PAnsiCHAR(Nombre1) Eso convierte el String a Cadena estilo C
Si usas PAnsiCHAR la conversión será a un CHAR clásico de tamaño 1 BYTE.
En el caso de versiones de delphi UNICODE PCHAR es lo mismo que PWCHAR por lo que lo mejor es usar explicitamente PAnsiCHAR si queremos que la cadena no se interprete como UNICODE. Este bonito galimatías se lo debemos a Embarcadero y trae numerosas confusiones a la hora de usar código antiguo en versiones modernas de delphi.

Ahora, para esa función que propones, tu código quedaría así:

Código Delphi [-]
type
  TCargarDatosCliente  = function ( nombre_o_razon_social1 :PansiChar;  nombre_o_razon_social2 :PansiChar;
                                   domicilio1 :PansiChar; domicilio2:PansiChar;  domicilio3:PansiChar;
                                 id_tipo_documento :LongInt; numero_documento:PansiChar; id_responsabilidad_iva :LongInt): LongInt; StdCall;

var
  Nombre1: String;
  Nombre2: String;
  Direccion1: String;
  Direccion2: String;
  Direccion3: String;
  TipoDoc: LongInt;
  NroDoc: String;
  idIVA: LongInt;
  error: LongInt;
  CargarDatosCliente: TCargarDatosCliente;
Begin
  @CargarDatosCliente := GetProcAddress(dll, 'CargarDatosCliente');

  Nombre1:= ' JUAN PEREZ';
  Nombre2:= '';
  Direccion1:= 'Calle Nº';
  Direccion2:= 'Localidad..';
  TipoDoc := 1; //DNI
  NroDoc := '10000000';
  idIVA := 1; //IVA Insc
  error := CargarDatosCliente(PAnsiChar(Nombre1), PAnsiChar(Nombre2), PAnsiChar(Direccion1), PAnsiChar(Direccion2), PAnsiChar(Direccion3), TipoDoc , PAnsiChar(NroDoc), IdIVA);
  ShowMessage( IntToStr(error) );
End;


Saludos.

Última edición por escafandra fecha: 25-11-2018 a las 01:37:53.
Responder Con Cita
  #13  
Antiguo 25-11-2018
Avatar de escafandra
[escafandra] escafandra is offline
Miembro Premium
 
Registrado: nov 2007
Posts: 2.195
Poder: 20
escafandra Tiene un aura espectacularescafandra Tiene un aura espectacular
Una cosa más. Si vamos a usar PAnsiCHAR lo mejor es declarar las cadenas de texto como AnsiString en lugar de String.

Saludos.
Responder Con Cita
  #14  
Antiguo 26-11-2018
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Bien, esto empieza a tomar color.
Enormemente agradecido Escafandra!!
Saludos
Responder Con Cita
  #15  
Antiguo 06-09-2019
zuncopop zuncopop is offline
Registrado
 
Registrado: feb 2008
Posts: 6
Poder: 0
zuncopop Va por buen camino
Ayuda Para obtener el Ultimo Numero de Comprobante Tm900 fa

Buenas tardes, estoy desarrollando una aplicación para esta impresora fiscal y no logro obtener el ultimo numero de comprobante fiscal (tique-factura A o B) alguien tiene algún ejemplo que me pudiera facilitar. se los voy a agradecer muchísimo ya que me estoy volviendo Loco. gracias Slds
Responder Con Cita
  #16  
Antiguo 06-09-2019
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Cita:
Empezado por zuncopop Ver Mensaje
Buenas tardes, estoy desarrollando una aplicación para esta impresora fiscal y no logro obtener el ultimo numero de comprobante fiscal (tique-factura A o B) alguien tiene algún ejemplo que me pudiera facilitar. se los voy a agradecer muchísimo ya que me estoy volviendo Loco. gracias Slds
Hola Zuncopop, seria bueno saber si estas usando la dll EpsonFiscalInterface.dll, con los metodos que explica Escafandra mas arriba o cual.
Responder Con Cita
  #17  
Antiguo 16-04-2020
zuncopop zuncopop is offline
Registrado
 
Registrado: feb 2008
Posts: 6
Poder: 0
zuncopop Va por buen camino
Epson fiscal tm900

buen dia , Omar te agradezco la atencion. si estoy usando la libreria fiscal tal como lo describe escafandra y me funciona todo perfecto, excepto cuando quiero recuperar el ultimo numero de comprobante emitido. el comando que utilizo es el siguiente

TConsultarNumeroComprobanteUltimo = Function (tipo_de_comprobante : String; respuesta : String; respuesta_largo_maximo : LongInt): LongInt; StdCall;
Responder Con Cita
  #18  
Antiguo 16-04-2020
Avatar de escafandra
[escafandra] escafandra is offline
Miembro Premium
 
Registrado: nov 2007
Posts: 2.195
Poder: 20
escafandra Tiene un aura espectacularescafandra Tiene un aura espectacular
String no es un tipo válido en AnsiC, por lo que la declaración que haces de la función es errónea. Por otro lado la declaracion en C la hacen de esta forma:

Código PHP:
  DLL_EXPORT_IMPORT int DLL_STD_CALL ConsultarNumeroComprobanteUltimo( const char *tipo_de_comprobantechar *respuestaint respuesta_largo_maximo ); 
Yo probaría de esta forma:
Código Delphi [-]
  TConsultarNumeroComprobanteUltimo = function (tipo_de_comprobante, respuesta: PAnsiChar; respuesta_largo_maximo: LongInt): LongInt; StdCall;


Saludos.
Responder Con Cita
  #19  
Antiguo 17-04-2020
zuncopop zuncopop is offline
Registrado
 
Registrado: feb 2008
Posts: 6
Poder: 0
zuncopop Va por buen camino
Epson fiscal tm900

gracias escafandra ahora lo pruebo y comento como me fue.
Responder Con Cita
  #20  
Antiguo 17-04-2020
omarperez.qui omarperez.qui is offline
Miembro
 
Registrado: ago 2006
Posts: 26
Poder: 0
omarperez.qui Va por buen camino
Hola Zuncopop, yo estoy usando lo siguiente y me funciona bien...

---Esto lo tengo en una unidad separada---

Código Delphi [-]
TConsultarNumeroComprobanteActual = Function( respuesta :PAnsiChar; respuesta_largo_maximo :Longint): LongInt; StdCall;


  Function ConsultarTipoComprobanteActual( respuesta :PAnsiChar; respuesta_largo_maximo :Longint): LongInt;

Function ConsultarNumeroComprobanteActual( respuesta :PAnsiChar; respuesta_largo_maximo :Longint): LongInt;
var ConsultarNumeroComprobanteActual: TConsultarNumeroComprobanteActual;
  error : LongInt;
Begin
 @ConsultarNumeroComprobanteActual := GetProcAddress(T900dll, 'ConsultarNumeroComprobanteActual');
 error := ConsultarNumeroComprobanteActual( @Respuesta[0], respuesta_largo_maximo );
 Result :=  Error;
End;

-------En el modulo de facturacion---------

Código Delphi [-]
var vNroComprobante: array[0..10] of Ansichar;

  error:=Ut900.ConsultarNumeroComprobanteActual( @vNroComprobante, 10 );
  if error>0 then MostrarError900(error);


Gracias a Escafandra!!!
Espero te sirva, saludos

Última edición por Casimiro Notevi fecha: 17-04-2020 a las 11:59:11.
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
EPSON fiscal hgiacobone Varios 2 17-11-2015 18:14:01
Epson TM-L60 II BlueSteel Varios 0 03-01-2008 01:20:06
Quickreport + Epson FX-890 MasterXP Impresión 5 31-07-2007 09:52:53
Parametros Opcionales no Parametros por defecto Velia Varios 7 19-08-2006 16:18:42
Epson u210B mane Impresión 3 08-06-2005 11:06:27


La franja horaria es GMT +2. Ahora son las 21:15:11.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi