Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Internet
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Grupo de Teaming del ClubDelphi

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 12-11-2017
Avatar de pockelsm3
pockelsm3 pockelsm3 is offline
Miembro
 
Registrado: oct 2007
Posts: 65
Poder: 17
pockelsm3 Va por buen camino
Error con el TWebBrowser

saludos amigos delphianos

soy novato con delphi y necesito un poco de ayuda

tengo app donde el uso el componente del twebbrowser desde hace unos meses me esta presentando un problema en youtube, la pagina la carga a la perfeccion, pero cuando realizo una busqueda cualquiera me presenta un error, we're sorry but your computer or network may be sending automated download queries, el cual anexo una imagen.

lo cual esto solamente sucede en youtube, en cualquier otra pagina no presenta nada, ni siquiera en google que son de ellos mismos

tambien he estado tratando de cambiar a firefox, pero este me este me da un error de memoria cuando va a presentar la pagina.
Imágenes Adjuntas
Tipo de Archivo: jpg error.jpg (37,8 KB, 12 visitas)

Última edición por pockelsm3 fecha: 12-11-2017 a las 05:42:01.
Responder Con Cita
  #2  
Antiguo 10-01-2019
El_Raso El_Raso is offline
Miembro
 
Registrado: oct 2003
Posts: 135
Poder: 21
El_Raso Va por buen camino
Saludos... tengo ese mismo error pero solo me pasa en los windows de 32bit aun teniendo la ultima version de IE actualizada a la fecha. A alguien de ustedes le a pasado lo mismo? Como lo han resuelto? Alguna idea?
Responder Con Cita
  #3  
Antiguo 10-01-2019
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola a todos,

Yo diría que el sitio web en cuestión está usando el "User agent" de nuestro navegador, y, seguramente, este no es "común", por decirlo así, de modo que, el sitio web evita servir el contenido. La solución, si fuera este el caso, pasaría por cambiar el "User agent" del navegador, a otro más o menos común, como pudiera ser el "User agent" de Mozilla Firefox, por ejemplo.
__________________
David Esperalta
www.decsoftutils.com
Responder Con Cita
  #4  
Antiguo 10-01-2019
Avatar de Ñuño Martínez
Ñuño Martínez Ñuño Martínez is offline
Moderador
 
Registrado: jul 2006
Ubicación: Ciudad Catedral, Españistán
Posts: 6.000
Poder: 25
Ñuño Martínez Tiene un aura espectacularÑuño Martínez Tiene un aura espectacular
Precisamente me acaba de pasar lo mismo con el programa que usamos en el trabajo, aunque no sé si está hecho con Delphi. Curiosamente sólo pasa con las búsquedas, pero reproduce el vídeo perfectamente, así que seguramente sea lo que dice dec, que el user agent le haga saltar la alarma o que haga algo "que no deba". También me pregunto si podría ser que no use JavaScript.
__________________
Proyectos actuales --> Allegro 5 Pascal ¡y Delphi!|MinGRo Game Engine
Responder Con Cita
  #5  
Antiguo 11-01-2019
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola a todos,

El compañero Ñuño me ha recordado otra posible causa del problema. Se trata de la versión de Internet Explorer que puede emular el componente "TWebBrowser". En efecto, si no hacemos nada más que poner un componente "TWebBrowser" en un formulario, dicho componente emulará una versión "antigua" de Internet Explorer, que, puede no ser compatible con los sitios web "modernos".

La siguiente unidad permite establecer la emulación de Internet Explorer 11, que, es suficiente (a día de hoy) para dar soporte a los sitios web "modernos" de que hablamos:

Código Delphi [-]
unit AppBuilder.Shared.BrowserFixes;

interface

type
  TBrowserFixes = class(TObject)
  public
    class procedure Initialize();
    class procedure Uninitialize();
  end;

implementation

uses
  // Delphi
  Winapi.Windows,
  System.SysUtils,
  System.Win.Registry;

const
  FEATURE_GPU_RENDERING_KEY = 'Software\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_GPU_RENDERING';
  FEATURE_BROWSER_EMULATION_KEY = 'Software\Microsoft\Internet Explorer\Main\FeatureControl\FEATURE_BROWSER_EMULATION';

{ TBrowserFixes }

class procedure TBrowserFixes.Initialize();
var
  ExeName: string;
begin
  ExeName := ExtractFileName(ParamStr(0));
  with TRegistry.Create() do
  try
    RootKey := HKEY_CURRENT_USER;

    if OpenKey(FEATURE_BROWSER_EMULATION_KEY, True) then
    begin
      if not ValueExists(ExeName) then
      begin
        // http://msdn.microsoft.com/en-us/libr...8VS.85%29.aspx
        WriteInteger(ExeName, 11001);
      end;
      CloseKey();
    end;

    if OpenKey(FEATURE_GPU_RENDERING_KEY, True) then
    begin
      if not ValueExists(ExeName) then
      begin
        // https://msdn.microsoft.com/en-us/lib...=vs.85%29.aspx
        WriteInteger(ExeName, DWORD(1));
      end;
      CloseKey();
    end;

  finally
    Free();
  end;
end;

class procedure TBrowserFixes.Uninitialize();
var
  ExeName: string;
begin
  ExeName := ExtractFileName(ParamStr(0));

  with TRegistry.Create() do
  try
    RootKey := HKEY_CURRENT_USER;

    if OpenKey(FEATURE_BROWSER_EMULATION_KEY, False) then
    begin
      if ValueExists(ExeName) then
        DeleteValue(ExeName);
      CloseKey();
    end;

    if OpenKey(FEATURE_GPU_RENDERING_KEY, False) then
    begin
      if ValueExists(ExeName) then
        DeleteValue(ExeName);
      CloseKey();
    end;

  finally
    Free();
  end;
end;

initialization

finalization
  TBrowserFixes.Uninitialize();

end.

Para utilizar dicha unidad hay que incluirla en nuestro proyecto, y, a continuación usar el método "TBrowserFixes.Initialize()". Como puede verse, la propia unidad realiza el "Uninitialize" por sí sola. Adicionalmente (esto puede quitarse, si no se precisa, porque, no tiene que ver con la emulación de Internet Explorer) esta unidad también establece que el componente "TWebBrowser" "renderize" su contenido usando la GPU, si fuese posible.

He mencionado lo del "User agent", pero, lo cierto es que yo probaría primero con la "emulación" de Internet Explorer: es posible que esto solucione el problema y por tanto ya no sea necesario cambiar el "User agent".
__________________
David Esperalta
www.decsoftutils.com

Última edición por dec fecha: 11-01-2019 a las 09:32:07.
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
Error E2009 en evento de TWebBrowser : Parameter lists differ (MAJ) OOP 8 29-07-2015 20:26:02
TWebBrowser error "Interface not supported" kotai Internet 2 22-10-2012 13:50:53
TWebBrowser sin URL rafa_adrim Internet 1 20-10-2006 19:02:05
TWebBrowser - Error al cerrar la página mediante un botón pepsi Internet 2 02-05-2006 17:59:05
TWebBrowser RoyTan Internet 4 27-10-2003 23:06:09


La franja horaria es GMT +2. Ahora son las 13:24:24.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi