Duda con inicialización de variables

[lucasarts_18]

Hola Estimados.

Mucho tiempo que no posteaba, ahora retomando un proyecto en delphi me sale la duda con una variable pública que tengo en un formulario.

Este es el código donde seteo esa variable.

Código Delphi [-]
var
v_Id_Ajuste : Integer;
Frm_IngAjuste : TFrm_IngAjuste;
begin
if ZQry_Ajustes.RecordCount > 0 then
begin
v_Id_Ajuste := ZQry_Ajustes.FieldValues['id_ajuste'];
Frm_IngAjuste := TFrm_IngAjuste.Create(nil);
Frm_IngAjuste.f_Id_Ajuste := v_Id_Ajuste;
Frm_IngAjuste.ShowModal ;
end;
end;

Como ven hasta acá todo perfecto. Pero mi duda es al momento que el formulario donde utilizaré esta variable no se inicializa mediante el evento onshow.

Código Delphi [-]

procedure TFrm_IngAjuste.FormShow (Sender: TObject);
begin
LimpiarCampos;
dt_Fecha.Text := vg_fechasys;
Edt_Bodega.Text := vg_nombodega;
ZQry_Ajuste.ParamByName('p_id_ajuste').AsInteger := f_Id_Ajuste;
ZQry_Ajuste.Open;
if ZQry_Ajuste.RecordCount > 0 then
begin
Edt_NroAjuste.Text := IntToStr(f_Id_Ajuste);
Edt_Fecha.Text := ZQry_Ajuste.FieldValues['fecha'];
Edt_Bodega.Text := ZQry_Ajuste.FieldValues['nom_bod'];
ZQry_AjusteDet.ParamByName('p_id_bodega').AsInteger := vg_idbodega;
ZQry_AjusteDet.ParamByName('p_id_ajuste').AsInteger := f_Id_Ajuste;
ZQry_AjusteDet.Active := False;
ZQry_AjusteDet.Active := True;
end;
 
Edt_NroAjuste.Text := IntToStr(f_Id_Ajuste);
end;

La variable f_id_Ajuste que es de tipo integer y publica del formulario llega en 0, sin embargo en el evento onpaint llega con valor.



Qué evento más podría usar, el onpaint no me sirve mucho, lo ideal era el onshow, pero por lo visto no se inicializan en ese momento dicha variables públicas.

Gracias..

Saludos .-

[ecfisa]

Hola lucasart.

Si te interpreto bién y la varible f_id_Ajuste es pública al segundo Form, deberías tener el valor en el Evento OnShow del Form2 ya séa declarada como variable global o en la sección public de Form2.

Hice una prueba simple y obtengo el valor sin problemas. Fijate si el código te orienta en algo.
Form1:

Código Delphi [-]
uses Unit2;

procedure TForm1.Button1Click(Sender: TObject);
begin
  with TForm2.Create(nil) do
  try
    f_id_Ajuste:= 999;
    ShowModal;
  finally
    Free;
  end;
end;

Form2:

Código Delphi [-]
type
  TForm2 = class(TForm)
    procedure FormShow(Sender: TObject);
  private
  public
     f_id_Ajuste: Integer;
  end;

var
  Form2: TForm2;
  // f_id_Ajuste: Integer ( igual funciona si la situás aca )
implementation {$R *.dfm}

procedure TForm2.FormShow(Sender: TObject);
begin
  Caption:= IntToStr(f_id_Ajuste);
end;

Si no malentendí tu planteo, me animaría a decir que el problema está en el procedimiento LimpiarCampos...

Saludos.

[lucasarts_18]

Gracias ecfisa por tu respuesta.

El procedimiento LimpiarCampos solo vacia unos par de texbox, creo haber descubierto cual es el problema o mejor dicho cuando sucede.

Olvidé comentarte que ese código funcionaba ok hasta que cambie la propiedad del formulario FormStyle = fsMDIForm. Cuando hice este cambio comenzó a fallar. Lo más extraño es que si dejo tal cual estaba la propiedad FormStyle = fsNormal sigue no funcionando correctamente el evento onShow. y para terminar la curiosidad esta, resulta si vuelvo a crear el evento onShow de nuevo y la propiedad FormStyle = fsNormal el problema ya no aparece.

Amigo ecfisa, tu podrías hacer las pruebas cambiando dicha propiedad a FormStyle = fsMDIForm y ver si te resulta.

Amigo, intenta sin showmodal al momento de llamar al formulario ya que así lo estoy haciendo en este momento, disculpa si el código inicial estaba incorporado.

Gracias...

[ecfisa]

Hola lucasart.

Si, tenés razón. Al cambiar de SDI a MDI, el segundo form en el evento OnShow, pareciera que no tiene aún el valor asignado ...

Es un comportamiento que yo también desconocía... lo voy a investigar.

Pero hasta que averiguemos alguna manera más elegante de hacerlo, a ver si esto te sirve:

MDIForm:

Código Delphi [-]
uses Unit2, ClipBrd;

procedure TForm1.Mostrar;
var
  i: Integer;
begin
  for i:= 0 to Screen.FormCount -1 do
   if Screen.Forms[i].ClassName = 'TForm2' then
   begin
     Screen.Forms[i].Show;
     Screen.Forms[i].BringToFront;
     Exit;
   end;
   TForm2.Create(nil);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Numero: Integer;
begin
  Mostrar;
  Numero:= 1234;
  ClipBoard.Clear;
  ClipBoard.SetTextBuf(PChar(IntToStr(Numero)));
end;

MDIChild:

Código Delphi [-]
uses ClipBrd;

procedure TForm2.FormShow(Sender: TObject);
begin
  f_id_Ajuste:= StrToInt(ClipBoard.AsText);
  Caption:= IntToStr(f_id_Ajuste);
end;

Saludos.

[ecfisa]

Hola de nuevo.

Probando con Trace Into a ver por qué OnShow se disparaba en diferente órden que en los Forms SDI, se me ocurrió otra forma de hacerlo:

MDIForm:

Código Delphi [-]
uses Unit2;

procedure TForm1.Button1Click(Sender: TObject);
begin
  TForm2.Mostrar(1234);
end;

MDIChild:

Código Delphi [-]
type
  TForm2 = class(TForm)
    procedure FormShow(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormCreate(Sender: TObject);
  private
    f_id_Ajuste: Integer;
  public
    property IDAjuste: Integer read f_id_Ajuste write f_id_Ajuste;
    class procedure Mostrar(Num: Integer);
  end;

var
  Form2: TForm2;

implementation {$R *.dfm}

procedure TForm2.FormCreate(Sender: TObject);
begin
  ...
  ...
  OnShow:= nil;
end;

class procedure TForm2.Mostrar(Num: Integer);
begin
  if not Assigned(Form2) then
    Form2:= Create(nil);
  with Form2 do
  begin
    f_id_Ajuste:= Num;
    OnShow:= FormShow;
    FormShow(nil);
  end;
end;

procedure TForm2.FormShow(Sender: TObject);
begin
  Caption:= IntToStr(f_id_Ajuste);
end;

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action:= caFree;
  Form2:=nil; // por: if Assigned(Form2) ...
end;

Me gusta un poco más que la anterior. Aunque no estoy seguro que sea la mejor forma...

Saludos.

[lucasarts_18]

Gracias amigo, tu última solución creo que es lo mejor.

Para ver si entiendo con el código OnShow:= nil;
haces que el evento OnShow se omita, para luego lanzarlo con FormShow(nil). porque todo al parecer resulta que al momento del onshow las variables no se encuentran disponibles cuando el formulario es de tipo fsMDIChild.

Pero me quedan las dudas, será un bug del delphi ?? o quizás lo erroneo es lo que estaba haciendo, pero siguiendo una lógica si uno ya tiene instanciada la clase (create(nil)) esta ya se encuentra totalmente accesible, lo raro es que el evento onshow no se entere de estos valores ni por si acaso.

Gracias estimado, por ahora me parece una solución fantastica, aunque igual que a ti, el por qué de tal comportamiento no me lo explico ya que el evento onpaint si tiene conocimientos de estos valores.

Saludos .-

[ecfisa]

Hola lucasart.

Si correcto, lo de OnShow:= nil, es por que cuando realiza el OnCreate inmediatamente dispara el OnShow y no está el valor aún.

Pero como te dije antes, lo averigué probando. Y al igual que vos no tengo idea del por que de este comportamiento.
Deberíamos consultarlo en un nuevo hilo, quizá algún compañero tenga el dato...

La property no es para embrollar la cosa... , me quedó de una prueba...

Saludos.

[lucasarts_18]

Estimado.

Segun la ayuda de delphi.

Use OnCreate to perform special processing when the form is created and is invoked by TCustomForm’s constructor. Either implement this event or override the constructor of the form; do not do both. Any objects created in the OnCreate event should be freed by the OnDestroy event.
When a form is being created and its Visible property is true, the following events occur in the order listed:
1. OnCreate
2. OnShow
3. OnActivate
4. OnPaint

Al parecer cuando la propiedad está visible=true se disparan los eventos de más arriba, quizás teniendo la propiedad visible=false funcione, bueno, mañara haré pruebas de esto y ver si estableciendo la propiedad a false los valores logren asignarse.

Saludos .-

[ecfisa]

Amigo... ¡¡¡ Felicitaciones, diste justo en el clavo !!!

Código Delphi [-]
class procedure TForm2.Mostrar(Num: Integer);
begin
  if not Assigned(Form2) then
    Form2:= Create(nil);
  with Form2 do
  begin
    Visible:= False;
    f_id_Ajuste:= Num;
    Visible:= True;
  end;
end;

procedure TForm2.FormShow(Sender: TObject);
begin
  Caption:= IntToStr(f_id_Ajuste);
end;

Saludos.

[ecfisa]

Hola de nuevo lucasart.

Me parece que me apuré a alegrarme, quedaba tan sencillo ajustando la propiedad Visible...
Despues de tanta prueba olvidé poner como MDIChild a Form2, fué por eso que no me dío error. Pero no se puede ocultar un Form MDIChild.

Esto no funciona:

Código Delphi [-]
  with Form2 do
  begin
    Visible:= False;
    f_id_Ajuste:= Num;
    Visible:= True;
  end;

La solución hasta el momento, sigue siendo:

Código Delphi [-]
procedure TForm2.FormCreate(Sender: TObject);
begin
   OnShow:= nil;
end;

class procedure TForm2.Mostrar(Num: Integer);
begin
  if not Assigned(Form2) then
    Form2:= Create(nil);
  with Form2 do
  begin
    f_id_Ajuste:= Num;
    OnShow:= FormShow;
    FormShow(nil);
  end;
end;

procedure TForm2.FormShow(Sender: TObject);
begin
  Caption:= IntToStr(f_id_Ajuste);
end;

Si encontrás alguna otra solución, agradecido si la pones.

Un saludo.

[lucasarts_18]

Estimado.

No he encontrado otra manera de hacerlo, bueno también está la opción de sobreescribir el constructor del formulario y pasarle un parametro adicional para utilizar (solución propuesta a mí en el mismo club hace unos par de años).

Mientras tanto para pantallas MDIChild estoy usando tu solución.

Saludos .-

[cloayza]

No se si entendi mal, pero igual va mi solucion.

Si f_id_Ajuste es una variable publica se puede asignar valor en cualquier momento. Por lo tanto antes de crear el formulario MDI, se le puede dar un valor {1}.

En este ejemplo incluso la sentencia Show, se puede obviar e igualmente se mostrara el formulario.

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
begin
    Unit2.f_id_Ajuste:=999;  {1}

    with TForm2.Create(nil) do
    try
        Show;
    finally
      //Free;
    end;
end;

Saludos

[ecfisa]

Hola cloayza.

Si declaras la variable f_id_Ajuste como global en Unit2, tenés toda la razón.

Pero si está declarada en una sección de la clase, no es posible hacerlo como arriba. Ya que la instancia de TForm2, y por tanto f_id_Ajuste,
todavía no están creados.

En este ejemplo incluso la sentencia Show, se puede obviar e igualmente se mostrara el formulario.

Voy corriendo a probarlo ! ( ¿ lo dejo en Auto-create no ?)


Saludos.

[cloayza]

ecfisa, ni siquiera es necesario dejarlo en auto create.

Saludos.