Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Otros entornos y lenguajes > Lazarus, FreePascal, Kylix, etc.
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #41  
Antiguo 09-05-2018
bucanero bucanero is offline
Miembro
 
Registrado: Nov 2013
Ubicación: Almería, España
Posts: 110
Poder: 5
bucanero Va por buen camino
hola danielmj,

Puedes poner la parte del código que te da error. Y el error que te da

saludos
Responder Con Cita
  #42  
Antiguo 09-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
Hola bucanero, ya no se ni que poner, estoy tan quemado con esto que me tiene frustrado.
Estoy comenzando un núevo método para generar números aleatorios sin repeticiones y a partir de ahí sacar los mas repetidos y sobre los mas repetidos (que formarian una combinacion de 6 numeros) le implementaria tu método de comparar combinaciones, solo que sería entre esos 6 unicos numeros y todo un listbox en el que he volcado los elementos de un listview (que por ejemplo tiene 5000 combinaciones). Voy a dejarlo ahora por que me tiene ya saturado y prefiero despejarme un poco para poder seguir. XD
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.
Responder Con Cita
  #43  
Antiguo 09-05-2018
Avatar de Casimiro Notevi
Casimiro Notevi Casimiro Notevi is offline
Moderador
 
Registrado: Sep 2004
Ubicación: En algún lugar.
Posts: 28.398
Poder: 10
Casimiro Notevi Tiene un aura espectacularCasimiro Notevi Tiene un aura espectacular
Recuerda, lo primero es apagar el ordenador, después tomar papel y lápiz.
Responder Con Cita
  #44  
Antiguo 09-05-2018
Avatar de ecfisa
ecfisa ecfisa is offline
Moderador
 
Registrado: Dec 2005
Ubicación: Tres Arroyos, Argentina
Posts: 10.083
Poder: 29
ecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to behold
Hola.

Te pongo un ejemplo que crea las seis columnas con sus títulos y agrega los seis items del ListBox en cada columna creada:
Código Delphi [-]
...
var
  col: TListColumn;
  it : TListItem;
  i  : Integer;
begin
  ListView1.ViewStyle := vsReport;

  // columnas y titulos
  for i := 0 to ListBox1.items.Count-1 do
  begin
    col := ListView1.Columns.Add;
    col.Caption := Format('Campo %d',[i+1]);
    col.Width := ListView1.Canvas.TextWidth('Campo 0')+20;
  end;

  // items y subitems
  it := ListView1.Items.Add;
  it.Caption := ListBox1.Items[0];
  for i := 1 to ListBox1.Items.Count-1 do
    it.SubItems.Add(ListBox1.Items[i]);
end;

Muestra:


Saludos
__________________
Daniel Didriksen

Guía de estilo - Uso de las etiquetas - La otra guía de estilo ....

Última edición por ecfisa fecha: 09-05-2018 a las 13:50:38. Razón: Agregar imágen de muestra
Responder Con Cita
  #45  
Antiguo 09-05-2018
bucanero bucanero is offline
Miembro
 
Registrado: Nov 2013
Ubicación: Almería, España
Posts: 110
Poder: 5
bucanero Va por buen camino
Te dejo por aquí otro ejemplo en donde he creado una especie de clase llamada TCOMBINACION con las posibles funciones que necesitas y donde puedes ver su funcionamiento.

Es unidad totalmente independiente y sin enlaces a la parte visual de la aplicación

Código Delphi [-]
unit Combinaciones;

interface

type
  TCombinacion = Int64;
  TCombinacionHelper = record helper for TCombinacion
  private
    function GetNumero(ANum: byte): Boolean;
    function AsString(const value: TCombinacion): string; overload;
    function GetCount: Integer;
  public
    procedure AddNumero(const ANum: byte);                 // Inserta un numero en la combinacion
    procedure aleatorio;                                   // rellena con una combinacion aleatoria
    function AsString: string; overload;                   // devuelve la combinacion como un string
    procedure clear;                                       // vacia la combinacion
    function comparar(const combinacion: TCombinacion): Tcombinacion;
    function obtenerComunes(const combinacion: Tcombinacion): string;

    property Count:Integer read GetCount;                  // Indica cuantos numeros tiene esta combinacion
    // esta propiedad es para comparar si un determinado numero pertenece a la combinación
    property Numero[ANum:byte]:Boolean read GetNumero;
  published
    // añadir tantos metodos load como sea necesarios
    function load(list: array of Byte): boolean; overload; // carga una combinacion determinada
  end;


implementation

uses System.SysUtils;

const
  NumeroMax: Byte = 49;  // 1.. 49
  MaxCount: integer = 5;


{ TCombinacionHelper }
procedure TCombinacionHelper.AddNumero(const ANum: byte);
begin
  Self := self or (int64(1) shl ANum);
end;

procedure TCombinacionHelper.aleatorio;
var
  i: longint;
  value: Byte;
begin
  i := 0;
  clear;
  repeat
    //Genera un numero aleatorio entre 1 y 49
    value := Random(NumeroMax - 1) + 1;
    if not Numero[value] then begin
      //si el numero no esta en la combinacion entonces lo añade
      AddNumero(value);
      Inc(i);
    end;
    //y se repite hasta obtener el maximo de numeros necesarios para la combinacion
  until (i >= MaxCount);
end;

function TCombinacionHelper.AsString: string;
begin
  result := AsString(Self);
end;

procedure TCombinacionHelper.clear;
begin
  Self := 0;
end;

function TCombinacionHelper.comparar(
  const combinacion: TCombinacion): Tcombinacion;
begin
  Result := self and combinacion;
end;

function TCombinacionHelper.GetCount: Integer;
var
  aux: Int64;
begin
  Result := 0;
  aux := self;
  while (aux > 0) do begin
    if (aux and Int64(1)) = 1 then
      Inc(result);
    aux := aux shr 1;
  end;
end;

function TCombinacionHelper.GetNumero(ANum: byte): Boolean;
begin
  Result := ((self and (int64(1) shl ANum)) <> 0);
end;

function TCombinacionHelper.load(list: array of Byte): boolean;
var
  i: LongInt;
begin
  Result := False;
  clear;
  if length(list) = MaxCount then begin
    for i := 0 to High(list) do
      AddNumero(list[i]);
    Result := true;
  end;
end;

function TCombinacionHelper.obtenerComunes(
  const combinacion: Tcombinacion): string;
begin
  Result := Comparar(combinacion).AsString;
end;

function  TCombinacionHelper.AsString(const value: TCombinacion):string;
var
  i:integer;
begin
  result := '';
  for i := 1 to NumeroMax do
    if value.Numero[i] then
      result := result + IntToStr(i) + ' ';
end;

end.

y en la pantalla principal se puede usar de la siguiente manera (solo hay dos botones y un memo):

Código Delphi [-]
uses Combinaciones;

procedure TForm1.Button1Click(Sender: TObject);
var
  Combinacion: TCombinacion;
begin
  //genera una combinacion aleatoria
  Combinacion.aleatorio;
  //combierte la combinacion en un texto
  memo1.lines.add(Combinacion.AsString + #9 + '(' + IntToStr(Combinacion.count) + ')');
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  cs1: string;
  Combinacion1, Combinacion2: TCombinacion;
  comunes: TCombinacion;
  i: LongInt;
begin
  //cargar una combinacion predeterminada
  if not Combinacion1.load([1, 5, 8, 13, 33]) then begin
    MessageDlg('La combinacion no es valida!!!', mtError, [mbOK], 0);
    exit;
  end;

  //guarda la combinacion1 en un string;
  cs1 := Combinacion1.AsString;
  //genera un bucle para analizar 100 combinaciones aleatorias
  for i := 1 to 100 do begin
    //generar una combinacion aleatoria
    Combinacion2.aleatorio;
    /// compara una combinacion con otra y obtine los comunes a ambas combinaciones
    comunes := Combinacion2.comparar(Combinacion1);
    /// si el valor es 0 entonces no hay numeros comunes
    if comunes <> 0 then
      memo1.Lines.Add(cs1 + #9 + Combinacion2.AsString + #9 + '(' + IntToStr(comunes.count) + ') ' + comunes.AsString);
  end;
end;
Responder Con Cita
  #46  
Antiguo 09-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
Gracias ecfisa y bucanero, miraré vuestro codigo sin falta por que ya no sé que mas hacer (lmitación de conocimientos siendo honesto)

En este momento, tengo este codigo para generar los aleatorios no repeditos

en una unidad aparte, uso esta funcion para generar los aleatorios no repetidos:

Código Delphi [-]
unit RandomArray; //fuente: https://www.experts-exchange.com/que...f-numbers.html

{$MODE Delphi}

interface

uses LCLIntf, LCLType, LMessages;

type
  TIntegerArray = array[0..32760*2] of Integer;
  PIntegerArray = ^TIntegerArray;

function CompRandArray(var IntArrayPtr: PIntegerArray; Count, LowRange, HighRange: integer): boolean;

implementation

function CompRandArray(var IntArrayPtr: PIntegerArray; Count, LowRange, HighRange: integer): boolean;
var
  I, J: integer;
  HaveDup: boolean;
begin
  Result := True;
  if (HighRange - LowRange + 1) < (Count) then
  begin
    Result := False;
    Exit;
  end;
  Randomize;
  for I := 0 to Count - 1 do
  begin
    IntArrayPtr^[i] := LowRange + Random(HighRange - LowRange + 1);
    Repeat
    HaveDup := False;
    for J := 0 to I - 1 do
    begin
      if (IntArrayPtr^[J] = IntArrayPtr^[i]) and (I <> J) then
      begin
        IntArrayPtr^[i] := LowRange + Random(HighRange - LowRange + 1);
        HaveDup := True;
        break;
      end;
    end;
    Until HaveDup = False;
  end;
end;

end.

en la unidad principal tengo esto...

Código Delphi [-]
unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  ComCtrls, Grids, RandomArray;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    grid: TStringGrid;
    Label1: TLabel;
    lista: TListView;
    ListBox1: TListBox;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private

  public

  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
var
  RandomArray: PIntegerArray; //This is a pointer type to Dynamic array
  i, Ctr, Count, Low, High: integer;

  begin
    Count := 6; //fill with 20 items
    Low := 1; //Lowest Random Number
    High := 49; //Highest Random Number
    GetMem(RandomArray, Count*SizeOf(Integer)); //Allocate memory
    try
      ListBox1.Clear;
      if CompRandArray(RandomArray, Count, Low, High) then
        For Ctr := 0 to Count - 1 do
        //if false Something went wrong
        ListBox1.Items.Add(IntToStr(RandomArray^[Ctr])); //dont forget ^
    finally
      FreeMem(RandomArray, Count*SizeOf(Integer)); //DeAllocate
    end;
  end;

procedure TForm1.Button2Click(Sender: TObject);
var
  i,j: integer;

begin
  with Lista.Items.Add do
      begin
        for i:= 0 to listBox1.Items.Count -1 do
        SubItems.Add(listBox1.Items.Strings[i]);
      end;
  button1.Click;
end;

end.

Bien, cada vez que pulso el button1, se genera en el listbox1 una combinacion de 6 numeros aleatorios sin repeticion y si pulso el button2, mete el contenido del listbox1 en el listview y hace una llamada a button1.
Y aqui viene mi problema por mucho que coloco for y while... no consigo rellenar el listview con por ejemplo 50, 100, 140 combinaciones de 6 numeros aleatorios que me entrege la funcion, o mejor dicho, lo rellena pero salvo la primera fila, el resto siempre son la misma combinacion.

Ejemplo:
3 5 7 12 45 32
23 4 12 41 33 13
23 4 12 41 33 13
23 4 12 41 33 13
23 4 12 41 33 13
...

Saludos y muchas gracias por vuestro tiempo, ayuda y paciencia.
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.
Responder Con Cita
  #47  
Antiguo 09-05-2018
bucanero bucanero is offline
Miembro
 
Registrado: Nov 2013
Ubicación: Almería, España
Posts: 110
Poder: 5
bucanero Va por buen camino
Cita:
Empezado por danielmj Ver Mensaje
Y aqui viene mi problema por mucho que coloco for y while... no consigo rellenar el listview con por ejemplo 50, 100, 140 combinaciones de 6 numeros aleatorios que me entrege la funcion, o mejor dicho, lo rellena pero salvo la primera fila, el resto siempre son la misma combinacion.
A mi el código que has publicado me funciona correctamente, el botón numero 1 genera una combinación aleatoria y el botón 2 la inserta en un listview. Y vuelve a generar otra combinación distinta. Si le doy al botón muchas veces, todas las combinaciones que genera son distintas.

Puede ser que tu problema vaya por el RANDOMIZE aunque creo que ya no es necesario inicializarlo pero no se exactamente en LAZARUS como va. Incluye en el create del form el comando randomize.
Responder Con Cita
  #48  
Antiguo 09-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
Hola bucanero, si, si voy pulsando el boton 2, si lo hace bien, pero mi proposito es que al pulsar el boton 1, se cargue el listview de forma automantica y con por ejemplo 400 combinaciones diferentes y no tener que estar pulsando el button2 todo el tiempo.
Voy a probar lo del randomize pero dudo que me solucione nada en este caso. Gracias.
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.
Responder Con Cita
  #49  
Antiguo 09-05-2018
Avatar de mamcx
mamcx mamcx is offline
Moderador
 
Registrado: Sep 2004
Ubicación: Medellín - Colombia
Posts: 3.492
Poder: 18
mamcx Tiene un aura espectacularmamcx Tiene un aura espectacular
Tu problema es que estas mezclando muchas cosas e ignorando la recomendacion de casimiro.

Tienes que aislar cada sub-tarea y una vez este resuelto, ir a la siguiente.

Tu primer problema es generar los numeros aleatorios. Es claro que no entiendes bien esto porque vas pegando el codigo sin darte cuenta que es ineficiente o que tiene errores obvios (como el que sacaste de ese foro).

Una cosa importante es tratar de eliminar las variables globables y semiglobales de tu programa, que mutar estado es de lo mas problematico y fuente de muchos errores.

Te paso un ejemplo de como limitas el codigo a un unico problema: Generar numeros aleatorios no repetidos, y ademas, de forma elegante:


Código Delphi [-]
program project1;

{$mode objfpc}{$H+}

uses
  {$IFDEF UNIX}{$IFDEF UseCThreads}
  cthreads,
  {$ENDIF}{$ENDIF}
  Classes, SysUtils, fgl
  { you can add units after this };

type
  TCheckDuplicate = specialize TFPGMap; // Para verificar que el numero no este repetido
  TRandomInt = class; // La clase "externa" que usaras
  TRandomIntEnumerator = class // la clase que se encarga de generar los numeros, usando un enumerador
  private
    FMax: int64; // Cuantos numeros por generar?
    FIndex: int64;
    FGen: TRandomInt;
    FSet: TCheckDuplicate;
  public
    constructor Create(generator:TRandomInt; max: int64);
    function MoveNext: Boolean;
    function GetCurrent: int64;
    property Current: int64 read GetCurrent;
  end;

  TRandomInt = class(TObject)
  private
    FMax: int64;
  public
    constructor Create(max: int64);
    function GetEnumerator: TRandomIntEnumerator;
  end;
{ TRandomInt }

constructor TRandomInt.Create(max: int64);
begin
  inherited Create;
  FMax := max;
end;

function TRandomInt.GetEnumerator: TRandomIntEnumerator;
begin
  Result := TRandomIntEnumerator.Create(Self, FMax);
end;

{ TRandomIntEnumerator }

constructor TRandomIntEnumerator.Create(generator:TRandomInt; max: int64);
begin
  inherited Create;
  FSet := TCheckDuplicate.Create;
  FIndex := 0;
  FMax := max;
  FGen := generator;
end;

function TRandomIntEnumerator.GetCurrent: int64;
var
  num: int64;
begin
  num := random(MaxInt); // O colocas el maximo posible
  while True do
  begin
       //Verifico que no se ha generado antes...
       if FSet.IndexOf(num) = -1 then
       begin
         break;
       end;
       FSet.Add(num);
       num := random(MaxInt);
  end;
  Result := num;
end;

function TRandomIntEnumerator.MoveNext: Boolean;
begin
  Result := FIndex < FMax;
  Inc(FIndex);
end;

var
  i:int64;

// Como se usa:
begin

  for i in TRandomInt.Create(100000) do
  begin
    writeln(IntToStr(i));
  end;
  ReadLn;
end.

Nota que queda funcionando sin necesidad de decidir si usas array u otra cosa, y sin complicar con variables la claridad del codigo. Cada vez que uses for i in TRandomInt se encargara clase solita de manejar sus datos y reglas internas.

El chequeo de si el numero ya fue usado antes se puede eliminar y la clase queda totalmente eficiente ya que no consume casi nada de memoria, pero veo que te enrueda mucho y el paso de quitar los duplicados quedaria complicado ya que tocaria reajustar las matrices.

Asi, es totalmente encapsulado!


---

Ya teniendo el tema resuelto de los numeros la parte visual deberia resultarte trivial y con los que te han mostrado suficiente...


P.D: Hay mas cosas que se pueden optimizar (como cambiar el hashset por un bitset) pero creo que es suficiente asi...
__________________
Nuevo Blog.
Ahora en Twitter!.

Última edición por mamcx fecha: 09-05-2018 a las 23:11:35.
Responder Con Cita
  #50  
Antiguo 10-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
Hola mamcx,
Tal vez tienes razón, pero creo que es obvio que yo no me dedico a esto de la programación, ni tengo una carrera en sistemas, análisis o informática en general. Para mí es un hobby, y lo mucho o poco que sé es por los 5 años de fp en informática de gestión del 95 al 2000, y ya ha llovido desde entonces como para acordarme de la mayoría de las cosas amén que muchas otras jamás vi.
Es cierto que encontré el código en un foro, pero tengo que coger un poco de aquí y un poco de allí podrá formar una especie de puzzle que me permita evadir mi falta de conocimientos que seguro tu tienes.

Yo vengo aquí buscando ayuda y lo único que puedo dar a cambio es la intención. La intención en intentarlo una y otra vez, buscando aquí y allá y sumando lo poco que sé.
Por otra parte, no he ignorado el consejo de Casimiro, se leer e interpretar un algoritmo sobre papel siempre y cuando esté dentro de mi alcance. En este caso no lo está por eso pregunto. Sino, no podría hacer este programa. Voy a ser más concreto.. en el código que ya tenía, conseguía generar números aleatorios sin repetir, el problema es que desconozco la sintaxis para agregar el contenido del listbox al listview x número de veces.
Antes dije, que estudie 5 años de informática de gestión, pero nunca use programas con interfaz gráfica, siempre fueron Pascal 7 y COBOL para MSDOS ambos. Lo poco que sé de Delphi y su manejo en entornos gráficos, ha sido por cuenta propia de ahí que no conozca tantas rutinas o formas de realizar un programa como podais tener vosotros.

En fin, no me extiendo más, esto lo digo sin ánimo de acritud y su estoy resultando muy pesado, pues me lo decís y yo recojo los bártulos y me voy tal como vine.
Ahora mismo estoy en el curro, fuera de turno pero en el curro, cuando llegue a casa miraré tu código.
Gracias por todo a todos.
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.

Última edición por danielmj fecha: 10-05-2018 a las 01:00:06.
Responder Con Cita
  #51  
Antiguo 10-05-2018
Avatar de Casimiro Notevi
Casimiro Notevi Casimiro Notevi is offline
Moderador
 
Registrado: Sep 2004
Ubicación: En algún lugar.
Posts: 28.398
Poder: 10
Casimiro Notevi Tiene un aura espectacularCasimiro Notevi Tiene un aura espectacular
Cita:
Empezado por danielmj Ver Mensaje
el problema es que desconozco la sintaxis para agregar el contenido del listbox al listview x número de veces.
El último ejemplo de ecfisa hace eso.

Cita:
Empezado por danielmj Ver Mensaje
pero nunca use programas con interfaz gráfica, siempre fueron Pascal 7 y COBOL para MSDOS ambos.
Eso te comenté antes, que no necesitas la parte gráfica, porque hace al programa muy lento. Fíjate en el código que ha puesto mamcx, no usa la interfaz gráfica tampoco.
Eso es algo opcional para presentar finalmente los números, o los botones, etc. pero no es necesario para la ejecución del programa.

Cita:
Empezado por danielmj Ver Mensaje
En fin, no me extiendo más, esto lo digo sin ánimo de acritud y su estoy resultando muy pesado, pues me lo decís y yo recojo los bártulos y me voy tal como vine.
Nada hombre, con un poco de paciencia y poquito a poquito, verás como lo consigues, pero no debes "empecinarte" en cuestiones gráficas, sino en la rutina de funcionamiento del programa.
Responder Con Cita
  #52  
Antiguo 10-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
gracias Casimiro, en un rato tengo que salir hacia la oficina del trabajo pero mientras me pongo a revisar codigos. Un saludo.
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.
Responder Con Cita
  #53  
Antiguo 13-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
Hola bucanero, estoy teniendo problemas con la linea "record helper for" lazarus no la reconoce, al parecer se implementó a partir de la version XE3. Intengo encontrar algo similar pero por ahora nada. Así que no puedo probar tu codigo. Saludos.
Por cierto, tengo d7 corriendo en linux y tampoco lo reconoce.
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.
Responder Con Cita
  #54  
Antiguo 13-05-2018
bucanero bucanero is offline
Miembro
 
Registrado: Nov 2013
Ubicación: Almería, España
Posts: 110
Poder: 5
bucanero Va por buen camino
Veo que en lazarus los HELPER son un poco distintos a DELPHI,

prueba de la siguiente forma:

Código Delphi [-]
{$mode objfpc}{$H+}
{$MODESWITCH TYPEHELPERS}

uses SysUtils;

type
  TCombinacion = Int64;
  TCombinacionHelper = type helper for TCombinacion
  private
    function GetNumero(ANum: byte): Boolean;
    function AsString(const value: TCombinacion): string; overload;
    function GetCount: Integer;
  public
    procedure AddNumero(const ANum: byte);                 // Inserta un numero en la combinacion
    procedure aleatorio;                                   // rellena con una combinacion aleatoria
    function AsString: string; overload;                   // devuelve la combinacion como un string
    procedure clear;                                       // vacia la combinacion
    function comparar(const combinacion: TCombinacion): Tcombinacion;
    function obtenerComunes(const combinacion: Tcombinacion): string;

    property Count:Integer read GetCount;                  // Indica cuantos numeros tiene esta combinacion
    // esta propiedad es para comparar si un determinado numero pertenece a la combinación
    property Numero[ANum:byte]:Boolean read GetNumero;

    // añadir tantos metodos load como sea necesarios
    function load(list: array of Byte): boolean; overload; // carga una combinacion determinada
  published
  end;
Responder Con Cita
  #55  
Antiguo 14-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
Hola bucanero, estoy mirando tu codigo y hay un par de cosas que no consigo "llevar" a mis intereses, es decir, que no consigo implementarlo.

Cita:
if not Combinacion1.load([1, 5, 8, 13, 33]) then begin
Se le pasa una combinación dada, pero cuando entre los corchetes como valor pongo "1, 45, 33, 14, 20, 22" salta el msg diciendo que la combinacion no es valida. Entonces mi duda es, teniendo en cuenta que esa combinación estaría formada por los numeros mas repetidos entre 50.000 combinaciones aleatorias (por ejemplo) y que sería comparada con cada una de esas combinaciones ¿por que da error?
Tu codigo hace 2 cosas, primero genera una serie de aleatorios y luego lo compara con una combinacion dada, pero lo que intento es por ejemplo generar x numero de combinaciones repetidas y metidas en un listview, de ella extraigo los numeros mas repetidos y sobre esa unica combinacion, hago las comparaciones. Pero no puedo por que en el momento en que "combinaicon.load es distitno, el programa se detiene.
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.
Responder Con Cita
  #56  
Antiguo 15-05-2018
bucanero bucanero is offline
Miembro
 
Registrado: Nov 2013
Ubicación: Almería, España
Posts: 110
Poder: 5
bucanero Va por buen camino
Hola Danielmj

El error te lo da por la pre-condición establecida donde estas debe tener siempre 5 elementos a la hora de leerla, puedes quitar esa condición, o añadirle otras que tu consideres.

Código Delphi [-]
const
  MaxCount: integer = 5;

  ...
  
function TCombinacionHelper.load(list: array of Byte): boolean;
var
  i: LongInt;
begin
  Result := False;
  clear;
  // if length(list) = MaxCount then begin   //<-- Quita esta linea 
    for i := 0 to High(list) do
      AddNumero(list[i]);
    Result := true;
  // end;    //<-- Quita esta linea
end;


Cita:
Empezado por danielmj Ver Mensaje
...
lo que intento es por ejemplo generar x numero de combinaciones repetidas y metidas en un listview, de ella extraigo los numeros mas repetidos y sobre esa unica combinacion, hago las comparaciones.
Para operar olvídate del listview, (al fin y al cabo mostrar 5000 o 10000 combinaciones la mayoría inutiles no le es interesante al usuario) usalo solamente una vez que tengas los resultados esperados con las combinaciones ya filtradas. Ademas al ser un componente visual no obtendrás la velocidad adecuada. Haz las operaciones sobre array que es mucho mas rápido. aquí tienes un ejemplo:

Código Delphi [-]
var
  i:longint;
  combinacion1, comunes:Tcombinacion;
  cs1: string;
  lista:  array of TCombinacion;
begin
  try
    setLength(lista, 5000);
    //rellenar una lista de 5000 elementos con una combinación aleatoria
    for i:=0 to high(lista) do
      lista[i].aleatorio;

    //cargar la combinación maestra
    if not Combinacion1.load([1, 45, 33, 14, 20, 22]) then begin
      MessageDlg('La combinacion no es valida!!!', mtError, [mbOK], 0);
      exit;
    end;

    // guarda la combinacion1 en un string,
    // esto es solamente por acelerar el proceso a la hora de mostrar la combinacion
    // como string y no repetirlo en cada ciclo del bucle
    cs1 := Combinacion1.AsString;
    //recorre el bucle para analizar todas las combinaciones con la combinacion principal
    for i := 0 to high(lista) do begin
      /// compara una combinacion con otra y obtine los comunes a ambas combinaciones
      comunes := lista[i].comparar(Combinacion1);
      /// si el valor es 0 entonces no hay numeros comunes
      if comunes <> 0 then
        memo1.Lines.Add(cs1 + #9 + lista[i].AsString + #9 + '(' + IntToStr(comunes.count) + ') ' + comunes.AsString);
    end;
  finally
    setLength(lista, 0);
  end;

Un saludo
Responder Con Cita
  #57  
Antiguo 16-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
Hola bucanero, gracias por tu tiempo. Mirando tu codigo y poniendolo en practica veo un resultado inesperado. Lo que hago es lo siguiente, en un edit he volcado el valor de 6 labels.caption con valores entereos y aleatorios del 1 al 49 con lo que se forma un longint en el edit.text Esta será la combinacion maestra a comparar, pero lo que veo que hace es que en todas y cada una de las 5000 combinaciones se repite el mismo numero y simpre siempre, se da un unico acierto.
Y el codigo modificado sería este:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  i:longint;
  combinacion1, comunes:Tcombinacion;
  cs1: string;
  lista:  array of TCombinacion;
begin
  try
    setLength(lista, 50000);
    //rellenar una lista de 5000 elementos con una combinación aleatoria
    for i:=0 to high(lista) do
      lista[i].aleatorio;

    //cargar la combinación maestra
    if not Combinacion1.load([StrToInt(edit1.Text)]) then begin
      MessageDlg('La combinacion no es valida!!!', mtError, [mbOK], 0);
      exit;
    end;

    // guarda la combinacion1 en un string,
    // esto es solamente por acelerar el proceso a la hora de mostrar la combinacion
    // como string y no repetirlo en cada ciclo del bucle
    cs1 := Combinacion1.AsString;
    //recorre el bucle para analizar todas las combinaciones con la combinacion principal
    for i := 0 to high(lista) do begin
      /// compara una combinacion con otra y obtine los comunes a ambas combinaciones
      comunes := lista[i].comparar(Combinacion1);
      /// si el valor es 0 entonces no hay numeros comunes
      if comunes <> 0 then
        memo1.Lines.Add(cs1 + #9 + lista[i].AsString + #9 + '(' + IntToStr(comunes.count) + ') ' + comunes.AsString);
    end;
  finally
    setLength(lista, 0);
  end;
end;

https://drive.google.com/open?id=1NG...XSeWz8qTKfoZL4
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.
Responder Con Cita
  #58  
Antiguo 16-05-2018
bucanero bucanero is offline
Miembro
 
Registrado: Nov 2013
Ubicación: Almería, España
Posts: 110
Poder: 5
bucanero Va por buen camino
La combinación maestra solo te esta cogiendo el numero 48.

Eso es porque el edit1 al convertirlo a un numero entero y pasarlo como un array of byte que es el parámetro esperado de la función load, y me extraña que no este dando ningún error de tipos, en realidad lo que esta haciendo es cortando y tomando solamente los 8 primeros bits del numero, omitiendo el resto. De hay que solo tome el valor 48.
Cita:
Empezado por danielmj Ver Mensaje
Código Delphi [-]
Combinacion1.load([StrToInt(edit1.Text)])
Aunque no le veo mucha utilidad a que el usuario introduzca y/o maneje un numero de INT64 que es al fin y al cabo la forma interna en que maneja el programa una combinación determinada, pero si lo deseas así, puedes utilizar la carga de datos de la siguiente forma:
* añade una nueva función LOAD junto a la que ya tienes definida, utilizando la directiva overload, de la siguiente forma:

Código Delphi [-]
    ...
    // añadir tantos metodos load como sea necesarios
    function load(list: array of Byte): boolean; overload; // carga una combinacion determinada
    function load(value:int64):boolean; overload; //carga a partir de un Int64   

    ...

function TCombinacionHelper.load(value: int64): boolean;
begin
  self:=value;
  result:=true;
end;

y ahora ya puedes leer el numero de tu edit1 de esta forma (sin los corchetes), el compilador determinara que rutina LOAD utilizar en función de los parámetros que le suministres:
Código Delphi [-]
  if not Combinacion1.load(StrToInt(edit1.Text)) then begin
      MessageDlg('La combinacion no es valida!!!', mtError, [mbOK], 0);
      exit;
  end;

y en particular para el valor que tienes en la imagen (34324051248), yo obtengo la siguiente combinación:
Código:
4 5 8 10 12 13 14 16 17 18 19 20 22 23 24 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49
Saludos
Responder Con Cita
  #59  
Antiguo 16-05-2018
bucanero bucanero is offline
Miembro
 
Registrado: Nov 2013
Ubicación: Almería, España
Posts: 110
Poder: 5
bucanero Va por buen camino
Viendo tu vídeo, veo que lo que tienes en el edit1 son los mismos números que se ven en los label a la izquierda del edit1, dando la sensación que lo que estas haciendo es concatenando los valores de los labels, y guardándolos en el EDIT1. Eso no te va a dar la misma combinación que tienes en los labels cuando hagas el load del edit1.

Si pretendes obtener la misma combinación que muestras en los labels, entonces deberías hacer algo así:

Código Delphi [-]
var
   numeros:Array[1..6] of byte;
begin
  ...
  numeros[1]:=StrToInt(label1.caption);  
  numeros[2]:=StrToInt(label2.caption);
  ...
  numeros[6]:=StrToInt(label6.caption);

  combinacion1.load(numeros);
  ...
end;
Responder Con Cita
  #60  
Antiguo 16-05-2018
Avatar de danielmj
danielmj danielmj is offline
Miembro
 
Registrado: Jun 2011
Posts: 380
Poder: 8
danielmj Va por buen camino
Hola bucanero, gracias ya va corriendo perfectamente, pero sigo con la misma idea ya sabes.. R que R... y es que no quisiera abandonar la idea de al menos usar un listview que muestre x numero de combinaciones aleatorias, pongamos por ejemplo 20.000 y de entre ellas, busca los 6 numeros que mas se repiten formando de este modo una combinación en si misma. Esa combinacion con los 6 numeros que mas salen, SI podría usarlo como combinación clave en tu codigo y a partir de ahí hacer el resto. Pero ahora mismo no lo tengo y es algo que siento que me falta. Ya tengo que irme a trabajar, mañana sigo. Un saludo.
__________________
La juventud pasa, la inmadurez se supera, la ignorancia se cura con la educación, y la embriaguez con la sobriedad, pero la estupidez dura para siempre. Aristofanes.
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
sumando valores de un listview danielmj Varios 28 14-11-2014 21:52:30
VALORES FANTASMAS FIREBIRD 2.1 valores Grandes ASAPLTDA Firebird e Interbase 17 02-12-2012 12:09:02
Rellenar con 0.... buitrago Varios 6 17-11-2011 20:02:53
¿Cómo insertar una imágen en un lisbox o un memo? Acuarius3000 Gráficos 3 27-06-2005 08:44:53
arastrar archivos a un lisbox gulder C++ Builder 3 05-05-2005 13:31:50


La franja horaria es GMT +2. Ahora son las 18:40:44.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi