Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Varios
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Grupo de Teaming del ClubDelphi

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 01-11-2003
darkone2k3 darkone2k3 is offline
Miembro
 
Registrado: oct 2003
Ubicación: Frente al Computador.
Posts: 29
Poder: 0
darkone2k3 Va por buen camino
Question Existe la funcion EVAL en Delphi

Salu2 amigos foristas, esto sería de mucha ayuda.

Hay alguna funcion o procedimiento en dephi para poder evaluar expresiones desde cadenas de caracteres ingresadas por el usuario.
algo asi como la funcion EVAL de Javascript

Gracias y salu2 desde Chile.
Responder Con Cita
  #2  
Antiguo 01-11-2003
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Cita:
darkone2k3 comentó:
Hay alguna funcion o procedimiento en dephi para poder evaluar expresiones desde cadenas de caracteres ingresadas por el usuario.
No. Porque Delphi es un lenguaje compilado y no interpretado como JavaScript.

Pero si nos quieres comentar el uso que quisieras darle a tal función quizá podamos ayudarte a lograr el objetivo utilizando otras técnicas.

// Saludos
Responder Con Cita
  #3  
Antiguo 01-11-2003
darkone2k3 darkone2k3 is offline
Miembro
 
Registrado: oct 2003
Ubicación: Frente al Computador.
Posts: 29
Poder: 0
darkone2k3 Va por buen camino
Gracias por responder roman.

Mira, lo que pasa que tengo el siguiente codigo en jscrip:

Código:
function ratio(x_old,str1,str2){
  var xvalue=x_old
  var f=""
  var fdash=""
          for (var i=0;i<str1.length;i++)
       {
         var temp =str1.substring(i,i+1);
         if (temp=='z' || temp=='Z')temp=xvalue
         f+=temp}
  
     for (var i=0;i<str2.length;i++)
        {
         var temp =str2.substring(i,i+1);
         if (temp=='z' || temp=='Z')temp=xvalue
         fdash+=temp}
    
   var term = eval(f)/eval(fdash); 
   return term 
  }
Como te darás cuenta, en la linea que he resaltado de color azul, va la funcion eval, que es la que quiero pasar a Delpih 6.

Espero que te quede un poco más claro para que me puedas ayudar.
De ante manos, muchas gracias y salu2 desde Chile.
Responder Con Cita
  #4  
Antiguo 01-11-2003
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
Me cuesta trabajo entender el código ya que no sé en qué consisten los parámetros.

¿Podrías explicarme cual es el objetivo de la función y algún ejemplo?

// Saludos
Responder Con Cita
  #5  
Antiguo 01-11-2003
darkone2k3 darkone2k3 is offline
Miembro
 
Registrado: oct 2003
Ubicación: Frente al Computador.
Posts: 29
Poder: 0
darkone2k3 Va por buen camino
Hola roman, lo que pasa es que ese codigo es parte de un programa que calcula raices a traves del metodo de Newton Raphson, y éste está hecho en jscript.

Te pongo el enlace de la página donde está el código:
http://www.fim.utp.ac.pa/Laboratorio...um/newton.html

Si no es mucha la molestia, para que la revises.

En todo caso, conoces alguna página donde pueda descargar o encontrar alguna codificacion para poder realizar el método de Newton Raphon, en delphi.

Gracias y salu2 desde Chile.
Responder Con Cita
  #6  
Antiguo 01-11-2003
Avatar de roman
roman roman is offline
Moderador
 
Registrado: may 2003
Ubicación: Ciudad de México
Posts: 20.269
Poder: 10
roman Es un diamante en brutoroman Es un diamante en brutoroman Es un diamante en bruto
En resumen, se trata de un método (parte de) para hallar las raíces de una función.

Aquí el problema consta de dos partes:
  1. Evaluación de una expresión matemática
  2. Implementación del algoritmo

El algoritmo en sí es independiente de la evaluación, se trata sólo de un algoritmo matemático de manera que su implementación en Delphi o cualquier otro lenguaje sólo requeriría de un buen entendimiento del algoritmo.

La parte de evaluación es necesaria para que el usuario de la aplicación pueda escribir la función que desee. Pero entonces el programa debe poder analizar la expresión (dada como una cadena de caracteres) para poder evaluarla. Por ejemplo, si la expresión es

Z^2

el programa debe de alguna forma descomponer la expresión en tokens:

z - variable
^ - operador
2 - constante

sustituir cada aparición de la variable por el valor numérico proporcionado y aplicar el operador:

Código:
if Operador = '^' then
  Resultado := Power(Valor, Potencia)
else if Operador = ...
...
Este no es un problema tan sencillo y ciertamente se facilita en los lenguajes interpretados. Sin embargo sí puede hacerse y en la web encontrarás seguramente varios evaluadores de expresiones.

Yo realmente desconozco el tema pero quizá te sirva algo de esta página:

http://www.efg2.com/Lab/Library/Delp...ns/Parsers.htm

// Saludos
Responder Con Cita
  #7  
Antiguo 01-11-2003
darkone2k3 darkone2k3 is offline
Miembro
 
Registrado: oct 2003
Ubicación: Frente al Computador.
Posts: 29
Poder: 0
darkone2k3 Va por buen camino
Gracias roman por responder, voy a investigar lo que me dices.
Salu2 desde Chile.
Responder Con Cita
  #8  
Antiguo 27-09-2013
rarratia rarratia is offline
Miembro
 
Registrado: sep 2004
Posts: 50
Poder: 20
rarratia Va por buen camino
Smile

Cita:
Empezado por darkone2k3 Ver Mensaje
Gracias roman por responder, voy a investigar lo que me dices.
Salu2 desde Chile.
Estimado, la función Eval para delphi es fácil, aquí va:

Código Delphi [-]
function Eval(const expression : string) : extended;
var
  pos : Integer;
  ch : char;
  function GetChar : char;
  begin
    if pos < Length (expression) then
    begin
      Inc (pos);
      ch := expression [pos]
    end
    else ch := #0;
    result := ch
  end;
  function GetNonWhitespace : char;
  begin
    repeat
      GetChar
    until not (ch in [' ', #9]);
    result := ch
  end;
  function CalcAddition : extended; forward;
  function CalcNumber : extended;
  var
    s : string;
    gotPoint : boolean;
  begin
    gotPoint := False;
    while ch in ['0'..'9'] do
    begin
      s := s + ch;
      if (GetChar = '.') and not gotPoint then
      begin
        s := s + ch;
        GetChar;
        gotPoint := True
      end
    end;
    result := StrToFloat (s)
  end;
  function CalcExpressionInBrackets : double;
  begin
    result := CalcAddition;
    if ch = ')' then
      GetChar
    else
      raise Exception.Create ('Missing '')'' in expression')
  end;
  function CalcTerm : extended;
  begin
    case ch of
      '0'..'9' : result := CalcNumber;
      '(' : result := CalcExpressionInBrackets;
      else raise Exception.Create ('Syntax error in expression')
    end
  end;
  function CalcSignedTerm : extended;
  begin
    case GetNonWhitespace of
      '+' : result := CalcSignedTerm;
      '-' : result := -CalcSignedTerm;
      else result := CalcTerm
    end
  end;
  function CalcPower : extended;
  begin
    result := CalcSignedTerm;
    while ch = '^' do
      result := exp (ln (result) * CalcSignedTerm)
  end;
  function CalcMultiplication : extended;
  begin
    result := CalcPower;
    while ch in ['*', '/'] do
      case ch of
        '*' : result := result * CalcPower;
        '/' : result := result / CalcPower
      end
  end;
  function CalcAddition : extended;
  begin
    result := CalcMultiplication;
    while ch in ['+', '-'] do
      case ch of
        '+' : result := result + CalcMultiplication;
        '-' : result := result - CalcMultiplication
      end
  end;
begin
  pos := 0;
  result := CalcAddition
end;
Responder Con Cita
  #9  
Antiguo 27-09-2013
Avatar de mamcx
mamcx mamcx is offline
Moderador
 
Registrado: sep 2004
Ubicación: Medellín - Colombia
Posts: 3.911
Poder: 25
mamcx Tiene un aura espectacularmamcx Tiene un aura espectacularmamcx Tiene un aura espectacular
Otra manera es incluir python, javascript, lua u otro lenguaje de script.

Por ejemplo, con python:

http://www.atug.com/andypatterns/pythonDelphiTalk.htm

Lo he usado antes y funciona bien.

Con lua:

http://blog.spreendigital.de/2009/09...r-delphi-2010/

http://luapascal.luaforge.net/
__________________
El malabarista.
Responder Con Cita
  #10  
Antiguo 27-09-2013
Avatar de Casimiro Notevi
Casimiro Notevi Casimiro Notevi is offline
Moderador
 
Registrado: sep 2004
Ubicación: En algún lugar.
Posts: 32.011
Poder: 10
Casimiro Notevi Tiene un aura espectacularCasimiro Notevi Tiene un aura espectacular
Cita:
Empezado por mamcx Ver Mensaje
Otra manera es incluir python, javascript, lua u otro lenguaje de script.
Por ejemplo, con python:
http://www.atug.com/andypatterns/pythonDelphiTalk.htm
Lo he usado antes y funciona bien.
Con lua:
http://blog.spreendigital.de/2009/09...r-delphi-2010/
http://luapascal.luaforge.net/
¿Y eso qué tiene que ver con delphi?
Responder Con Cita
  #11  
Antiguo 27-09-2013
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola,

Cita:
Empezado por Casimiro Notevi Ver Mensaje
¿Y eso qué tiene que ver con delphi?
Si lo que se quiere es evaluar expresiones, este tipo de "lenguajes de scripts" resultan útiles. El componente ArtFormula, por ejemplo, permite evaluar expresiones bastante complejas, además de proporcionar también cierto lenguaje de script similar a Pascal.
__________________
David Esperalta
www.decsoftutils.com
Responder Con Cita
  #12  
Antiguo 27-09-2013
Avatar de Casimiro Notevi
Casimiro Notevi Casimiro Notevi is offline
Moderador
 
Registrado: sep 2004
Ubicación: En algún lugar.
Posts: 32.011
Poder: 10
Casimiro Notevi Tiene un aura espectacularCasimiro Notevi Tiene un aura espectacular
Sí, pero en el foro de club delphi, alguien pregunta por un eval en delphi, lo lógico no es contestar que use python, javascript, lua u otro lenguaje de script.
Responder Con Cita
  #13  
Antiguo 27-09-2013
Avatar de dec
dec dec is offline
Moderador
 
Registrado: dic 2004
Ubicación: Alcobendas, Madrid, España
Posts: 13.107
Poder: 34
dec Tiene un aura espectaculardec Tiene un aura espectacular
Hola,

Cita:
Empezado por Casimiro Notevi Ver Mensaje
Sí, pero en el foro de club delphi, alguien pregunta por un eval en delphi, lo lógico no es contestar que use python, javascript, lua u otro lenguaje de script.
Lo que pasa es que estos "lenguajes de script" suelen incluir un "evaluador de expresiones" puesto que ellos mismos necesitan de uno. Es el caso de ArtFormula, que, no sólo ofrece un lenguaje de script, pero, además un evaluador de expresiones que puede usarse por separado y que incluso se recomienda, puesto que es cinco veces más rápido que usarlo en conjunto con el lenguaje de script que incluye el propio ArtFormula. Yo creo que el compañero iba por ahí Casimiro: de hecho ArtFormula es un componente para Delphi escrito en el propio Delphi.
__________________
David Esperalta
www.decsoftutils.com

Última edición por dec fecha: 27-09-2013 a las 12:59:07.
Responder Con Cita
  #14  
Antiguo 27-09-2013
Avatar de mamcx
mamcx mamcx is offline
Moderador
 
Registrado: sep 2004
Ubicación: Medellín - Colombia
Posts: 3.911
Poder: 25
mamcx Tiene un aura espectacularmamcx Tiene un aura espectacularmamcx Tiene un aura espectacular
Esas opciones son las mejores si se quiere tener un abanico mas completo de funcionalidad de scripting en la app, pero un evaluador matematico es suficiente si es algo muy simple.

A proposito, recorde que hay una opcion en pascal:

http://www.remobjects.com/ps.aspx
__________________
El malabarista.
Responder Con Cita
  #15  
Antiguo 27-09-2013
Avatar de nlsgarcia
[nlsgarcia] nlsgarcia is offline
Miembro Premium
 
Registrado: feb 2007
Ubicación: Caracas, Venezuela
Posts: 2.206
Poder: 21
nlsgarcia Tiene un aura espectacularnlsgarcia Tiene un aura espectacular
Club Delphi,

Otra opción para evaluar expresiones en Delphi

Revisen este código :
Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, CalcExpress, Math;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Expr1: TEdit;
    Expr2: TEdit;
    Vars: TMemo;
    Values: TMemo;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    ResultExpr1: TLabel;
    ResultExpr2: TLabel;
    CalcExpress1: TCalcExpress;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
   ResultExpr1.Caption := EmptyStr;
   ResultExpr2.Caption := EmptyStr;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin

   if Expr1.Text <> EmptyStr then
   begin
      try
         CalcExpress1.Formula := Expr1.Text;
         ResultExpr1.Caption := 'Result: ' + FloatToStr(RoundTo(CalcExpress1.calc([]),-6));
      except
         ResultExpr1.Caption := EmptyStr;
      end;
   end;

end;

procedure TForm1.Button2Click(Sender: TObject);
var
   args : Array of Extended;
   i : Integer;

begin

   if (Vars.Lines.Count = Values.Lines.Count) and (Expr2.Text <> EmptyStr) then
   begin

      try

         CalcExpress1.Formula := Expr2.Text;

         CalcExpress1.Variables:= Vars.Lines;

         SetLength(args,Values.Lines.Count);

         for i := 0 to Values.Lines.Count - 1 do
            args[i] := StrToFloat(Values.Lines[i]);

         ResultExpr2.Caption := 'Result: ' + FloatToStr(RoundTo(CalcExpress1.calc(args),-6));

      except

         ResultExpr2.Caption := EmptyStr;

      end;

   end
   else
      MessageDlg('Error en Expresión, Variables o Valores',mtError,[mbOK],0);

end;

end.
El código anterior realiza una evaluación de expresiones por medio del componente TCalcExpress (Freeware), como se puede ver en la siguiente imagen:



Consulten este link:
Espero sea útil

Nelson.

Última edición por nlsgarcia fecha: 27-09-2013 a las 22:52:17.
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro


La franja horaria es GMT +2. Ahora son las 06:35:35.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi