'Cast' basado en un arreglo.

[TiammatMX]

Buen día/tarde/noche según aplique, jóvenes.

A ver si ustedes ven el problema donde yo no lo encuentro. Tengo el siguiente código:

Código Delphi [-]
procedure TformReporteadorV2.ImprimeExportaSIS;
var
   ElReporte : TqckrprtPadre;
   wsNombreArchivo : WideString;
   iIndiceI: Integer;
   aReportes: array of TqckrprtPadre;
begin
   SetLength(aReportes,6);
   aReportes[00] := TqrpSIS_SS_PSQ_001;
   aReportes[01] := TqrpSIS_SS_PSQ_012;
   aReportes[02] := TqrpSIS_SS_PSQ_128;
   aReportes[03] := TqrpSIS_SS_PSQ_129;
   aReportes[04] := TqrpSIS_SS_PSQ_130;
   aReportes[05] := TqrpSIS_SS_PSQ_131;
   for iIndiceI := 0 to Length(aReportes) do
   try
      ElReporte := (aReportes[iIndiceI] as TqckrprtPadre).Create(Self);
      MessageDlg('Reporte '+ElReporte.Name+' creado y funcionando.', mtInformation, [mbOK], 0);
   finally
      ElReporte := nil;
   end;
end;

en el cual intento tomar el reporte que corresponda de acuerdo a un índice que apunta a un elemento de un arreglo, pero aparentemente estoy haciendo algo que no debo por que me manda éste error:

[Error] uformReporteadorV2.pas(5364): Incompatible types: 'TqckrprtPadre' and 'Class reference'

Agradeciendo de antemano. ¿Alguna idea que puedan darme para solucionar ésto?

[Casimiro Notevi]

En principio, ahí falta el -1

Código Delphi [-]
for iIndiceI := 0 to Length(aReportes) -1 do

[Caminante]

Hola

Me parece que debes declarar la referencia de clase para TqckrprtPadre

Código Delphi [-]
TqckrprtPadreclass= class of TqckrprtPadre;

y luego

Código Delphi [-]
aReportes: array of TqckrprtPadreclass;

Luego

Código Delphi [-]
for iIndiceI := 0 to Length(aReportes) -1 do
   try
      ElReporte := TqckrprtPadreclass(aReportes[iIndiceI]).Create(nil);
      MessageDlg('Reporte '+ElReporte.Name+' creado y funcionando.', mtInformation, [mbOK], 0);
   finally
      ElReporte.free;
      ElReporte := nil
   end;

Espero que sea util

Saludos

[cloayza]

Sugiero este pequeño cambio al código de Caminante

Código Delphi [-]
for iIndiceI := 0 to Length(aReportes) -1 do
   try
      //ElReporte := TqckrprtPadreclass(aReportes[iIndiceI]).Create(nil);
     ElReporte := aReportes[iIndiceI].Create(nil);
      MessageDlg('Reporte '+ElReporte.Name+' creado y funcionando.', mtInformation, [mbOK], 0);
   finally
      ElReporte.free;
      ElReporte := nil
   end;

Saludos cordiales

[Caminante]

Me parece que si.

Saludos

[mamcx]

Si tienes una version de dephi mas moderna, el uso de genericos es mejor.

Ademas, "caminar" una enumeracion es mucho mejor asi:

http://delphi.about.com/od/beginners/a/delphi_loops.htm

Código Delphi [-]
for varName in enumName do
begin
    
end;

Y pusiste el error, pero no cual de todas las lineas lo saco!

[TiammatMX]

Empezado por mamcx

...Y pusiste el error, pero no cual de todas las lineas lo saco!...

¿El número entre paréntesis no es el número de línea?
[Error] uformReporteadorV2.pas(5364): Incompatible types: 'TqckrprtPadre' and 'Class reference'

Y de hecho, el error es para cada una de las líneas que se añaden a la matriz.

[mamcx]

Si pero la linea 5364 es cual en el codigo que pusiste de ejemplo?

Uno deduce que es

Código Delphi [-]
ElReporte := (aReportes[iIndiceI] as TqckrprtPadre).Create(Self);

Pero es mejor ser explicito.

[ecfisa]

Hola Tiammat.

Hay algo que no me quedo claro, ¿ Cual es la declaración de la clase TqckrprtPadre ? (de quién deriva, etc)

Saludos.

[ozsWizzard]

Yo creo que falta algo así... (Casteo a TQckRptPadre al asignar a ELReporte)

Empezado por cloayza

Sugiero este pequeño cambio al código de Caminante

Código Delphi [-]
for iIndiceI := 0 to Length(aReportes) -1 do
   try
      //ElReporte := TqckrprtPadreclass(aReportes[iIndiceI]).Create(nil);
     ElReporte := TQckRptPadre(aReportes[iIndiceI].Create(nil));
      MessageDlg('Reporte '+ElReporte.Name+' creado y funcionando.', mtInformation, [mbOK], 0);
   finally
      ElReporte.free;
      ElReporte := nil
   end;

Saludos cordiales

En cualquier caso, Caminante ha indicado el camino correcto, en mi opinión.

Yo tengo una unidad donde abro varios Quick report que descienden del mismo y hago lo siguiente:

En una unidad uFrmQR tengo algo así.

Código Delphi [-]
  TFrmQRClass = class of TFrmQR;

pPraram es un parámtetro que tiene el Create de TFrmQr.

Código Delphi [-]
procedure CrearQR(const pClassQr, pParam: String);
var
   i: Integer;
   fc: TFrmQRClass;
   f: TFrmQr;
   Qr: TQuickRep;
   Encontrado: Boolean;
begin
   fc := TFrmQRClass(FindClass(ClassQr));
   f := TFrmQr(fc.Create(Self, pParam));
   try
      i := 0;
      Encontrado := false;
      repeat
         if f.Components[i] is TQuickRep then
         begin
            Qr := (f.Components[i] as TQuickRep);
            Qr.PreviewModal;
            Encontrado := true;
         end;
         inc(i);
      until  (i >= f.ComponentCount) or Encontrado;
   finally
      f.Free;
   end;
end;

Espero te pueda servir de ayuda. Un saludo