Problema cargando Imagen desde base de Datos

[[enecumene]]

Saludos Compañeros, estoy teniendo problemas para cargar una imagen en un TJvImage desde un campo BLOB en la base de datos, lo mas cerca que he podido encontrar en el foro es esto:

Código Delphi [-]
Var B: TJPEGImage;
     MS: TMemoryStream;
begin
              B := TJPEGImage.Create;
              MS := TMemoryStream.Create;
              ZTable1FOTO2.SaveToStream(MS);
              B.LoadFromStream(MS);
              Foto.Picture.Assign(B);
              MS.Free;
              B.Free;
end;

Pues no me funciona, me tira este error:

---------------------------
Debugger Exception Notification
---------------------------
Project TimerPunch.exe raised exception class EJPEG with message 'JPEG error #42'. Process stopped. Use Step or Run to continue.
---------------------------
OK Help
---------------------------

Existe una mejor manera una Imagen BLOB en un TJvImage o TImage?, Trabajo con Delphi 7 y Firebird 2.0.

Saludos.

[roman]

Buscando en google por "JPEG error #42" encuentro esto:

Or using streams and forgetting to rewind the stream?

Y parece que puede ser por ahí. Luego de ZTable1FOTO2.SaveToStream(MS) usa MS.Seek para volver al principio del Stream. Es posible que B.LoadFromStream(MS) no lo haga por su cuenta de manera que está leyendo el stream desde el final.

// Saludos

[[enecumene]]

Gracias Roman, Ahora estoy teniendo este error:

---------------------------
Debugger Exception Notification
---------------------------
Project TimerPunch.exe raised exception class EJPEG with message 'JPEG error #53'. Process stopped. Use Step or Run to continue.
---------------------------
OK Help
---------------------------

y le agregue lo siguiente:

Código Delphi [-]
MS.Seek(80,0);

Saludos.

[roman]

¿Por qué MS.Seek(80,0)? ¿De dónde sale ese 80?

Yo pondría MS.Seek(0, soFromBeginning)

// Saludos

[[enecumene]]

Empezado por roman

¿Por qué MS.Seek(80,0)? ¿De dónde sale ese 80?

Yo pondría MS.Seek(0, soFromBeginning)

// Saludos

De la ayuda de Delphi:

The following example deletes the stream from position 60 within the blob stream to the end.

procedure TForm1.Button1Click(Sender: TObject);

var
Stream1: TBlobStream;
begin
Table1.Edit;
if Table1.State = dsEdit then
begin
Stream1 := Table1.CreateBlobStream(FieldByName('Notes', bmReadWrite);
try
Stream1.Seek(60, 0); { Move to byte 60}
Stream1.Truncate; { Delete from current position (60) to end of stream.}
Table1.Post;
finally
Stream1.Free;
end;
end;

end;

¡gracias Roman ahora sí me funcionó!.

Saludos.

[[enecumene]]

Vale, El amor duró poco, otra vez me sale el bendito "JEPG Error #42", y no le hecho más cambios salvo lo propuesto por Roman.

Ya no sé que hacer.

Saludos.

[[enecumene]]

Sigo con mi Odisea con este asunto lo que he hecho:

Función:

Código Delphi [-]
function CargarImagen(Campo:TBlobField): integer;
var
bS : TBlobStream;
buffer : Word;
hx : string;
begin
  Result := -1;
  bS := TBlobStream.Create(Campo, bmRead);
    try
      while (Result = -1) and
        (bS.Position + 1 < bS.Size) do
          begin
            bS.ReadBuffer(buffer, 1);
            hx := IntToHex(buffer, 2);
          if hx = 'FF' then begin
            bS.ReadBuffer(buffer, 1);
            hx := IntToHex(buffer, 2);
          if hx = 'D8' then Result := bS.Position - 2
            else if hx = 'FF' then
              bS.Position := bS.Position-1;
            end; //if
           end; //while
          finally
        bS.Free
      end; //try
end;

Aquí para cargar la imagen:

Código Delphi [-]
var
  bs: TBlobStream;
  Pic: TJPEGImage
begin
bS := TBlobStream.Create(ZTable1FOTO2, bmRead);
                try
                  bS.Seek(CargarImagen(ZTable1FOTO2),soFromBeginning);
                  Pic:=TJpegImage.Create;
                    try
                       Pic.LoadFromStream(bS);
                       Foto.Picture.Graphic := Pic;
                    finally
                       Pic.Free;
                    end;
                finally
                  bS.Free
                end;
end;

Resultado:

---------------------------
Debugger Exception Notification
---------------------------
Project TimerPunch.exe raised exception class EInvalidCast with message 'Invalid class typecast'. Process stopped. Use Step or Run to continue.
---------------------------
OK Help
---------------------------

Me voy a tirar de la ventana!! .

Saludos.

[[enecumene]]

Ya, joder!!!, Desisto!!, he decidido solo guardar el nombre del archivo, no la ruta, solo "Imagen.Jpg", lo voy a cargar así:

Código Delphi [-]
Foto.Picture.LoadFromFile(ExtractFilePath(Application.ExeName)+'\FOTOS\'+ZTable1FOTO.AsString);

Ahora mi duda es la siguiente, ¿es factible en una pc Cliente en la red?, o sea, de esa manera puedo llamar la imagen desde la red?, porque el programa se correrá de esta manera:

\\PC\TimePunch\TimePunch.exe

también estuve pensando guardar la foto en un servidor web y llamarlo así:

Foto.Picture.LoadFromFile('Http://IP/FOTOS/Imagen.jpg');

Sé que no va a funcionar, pero existirá alguna forma de hacerlo?


Saludos.

[roman]

He estado haciendo algunas pruebas con ZEOS y MySQL y me ha funcionado tal como te dije al principio. Quizá el problema lo tengas desde el momento de guardar la imagen, que no se esté guardando correctamente.

En todo caso, por lo que he visto, ni siquiera es necesario usar streams ya que tanto los objetos TBlobField como los gráficos tienen soporte integrado para escribir y leer desde aquellos.

En resumen, me he armado con este par de funciones que me han dado buenos resultados:

Código Delphi [-]
{
  Transfiere el contenido del campo Field al objeto Picture
  El campo debe ser un BLOB con una imagen en formato JPEG
}
procedure FieldToPicture(Field: TField; Picture: TPicture);
var
  Jpeg: TJpegImage;

begin
  if Field is TBlobField then
  begin
    if Field.IsNull then
      Picture.Graphic := nil
    else
    begin
      Jpeg := TJpegImage.Create;

      try
        Jpeg.Assign(Field);
        Picture.Assign(Jpeg);
      finally
        Jpeg.Free;
      end;
    end;
  end;
end;

{
  Transfiere el contenido del objeto Picture al campo Field
  El campo debe ser un BLOB y Picture debe contener una imagen en formato JPEG
}
procedure PictureToField(Picture: TPicture; Field: TField);
begin
  if (Picture.Graphic is TJPegImage) or not Assigned(Picture.Graphic) then
  begin
    Assert(Field.DataSet <> nil);
    
    Field.DataSet.Edit;
    Field.Assign(Picture.Graphic);
  end;
end;

FieldToPicture se usaría para copiar la imagen de un campo Blob a un objeto TPicture, como lo es la propiedad Picture de un componente Image. Lo normal sería usarla en el evento AfterScroll del DataSet:

Código Delphi [-]
procedure TForm1.ZTable1AfterScroll(DataSet: TDataSet);
begin
  FieldToPicture(DataSet.FieldByName('foto'), Image1.Picture);
end;

aunque también iría bien en el AfterCancel para restaurar la imagen original en caso de cancelar la edición.

PictureToField es la inversa y copia el contenido del objeto Picture en el campo. La función se asegura de que Picture contenga un gráfico JPEG. Lo normal aquí sería usarla al cargar una imagen desde un archivo:

Código Delphi [-]
procedure TForm1.btnLoadPictureClick(Sender: TObject);
begin
  if OpenPictureDialog.Execute then
  begin
    Image1.Picture.LoadFromFile(OpenPictureDialog.FileName);
    PictureToField(Image1.Picture, ZTable1.FieldByName('foto'));
  end;
end;

o bien, si queremos borrar la imagen:

Código Delphi [-]
procedure TfrmMain.btnClearPictureClick(Sender: TObject);
begin
  Image1.Picture.Graphic := nil;
  PictureToField(Image1.Picture, ZTable1.FieldByName('foto'));
end;

Como digo, me han funcionado bien con ZEOS y MySQL.

// Saludos

[[enecumene]]

Muchas gracias Roman, probaré las funciones mañana y te comento como me fue.

Saludos.

[[enecumene]]

Hola, perdona por la tardanza amigo Roman, estaba entretenido con otro proyecto, vale, probé tu último código, y me funcionó perfecto en firebird igual en MySQL.

Saludos.

[JULIPO]

Recibe un cordial saludo.

Buscando por el foro encontre esta respuesta a mis requerimientos, roman dejo unas rutinas realmente interesantes pero no me funcionan aparecen errores de acceso, estoy trabajando con delphi 2007 mysql y zeos trabajo con zquery pero tambien probe con ztable y me aparece el mismo error.


la rutina que trabajo es la siguiente

procedure Tcusuario.DataSource1DataChange(Sender: TObject; Field: TField);
 begin
  if zquery1.FieldByName('foto').AsVariant<> null then
   begin
    Image1.Picture.LoadFromFile('c:\biodyn\imagen.jpg');
    image1.Stretch:=true;
    PictureToField(image1.Picture, Zquery1.FieldByName('foto'));
  end;

la idea es que si no hay foto en la base de datos grabe una imagen de muestra

pero me aparece el siguiente error.

access violation at 0X7c925d4e write of address 0x00030fb0;

Esto por que puede ser el campo foto en la tabla es del tipo blob

Espero me puedan ayudar.

[Asanta]

Mi Problema Es Que Tengo Una Base De Datos En Mysql, En Una Tabla Guardo Imagenes En Tipo Blob,
Guardo Los Daots Los Modifico Todos Correctamente,
Pero Ahora Quiero Que Me Muestre Todas Las Imagenes Seguidad En Un Dbcontrolgrid, Pero Solo Me Muestra La Primera, Tambien Queria Saber Si Existe Algun Componente De Delphi Que Directamentente Me Abra Imagenes En Jpg, Saludos

[BetoAlonso]

Gracias por las rutinas me fueron de mucha ayuda.