Ayuda con Variables Globales y Locales en Pascal

[Novatin]

Que tal Amigos,
Estoy aprendiendo los conceptos de programacion básicos de Pascal, aunque debo decir que aprendí a programar en Turbo C++... hasta acá todo bien, sin embargo hay algo que no puedo pasar el codigo de C++ a Pascal... siento que algo le falta a Pascal

Tengo el siguiente codigo en Turbo C++ que usa una variable global y una variable local

...
int varGlobal;
int main()
{
   int varLocal;
   varGlobal=10;
   varLocal=10;
   printf("%d",varGlobal+varLocal);
   getch();
}

E intento pasar el codigo a Pascal así:

var
   varGlobal : Integer;

begin
var
   varLocal : Integer;
   varGlobal:=10;
   varLocal:=10;
   WriteLn(varGlobal+varLocal);
   ReadKey;
   
end.

Pero no me funciona...!
en realidad la idea es no "abusar" del uso de variables globales.. pero Pascal me obliga a declarar todas mis variables de la funcion "main" como globales??

O tengo algun problema al traducir el codigo??

[ecfisa]

Hola Novatin.

Te pongo un código de ejemplo que te puede clarificar el ámbito de las variables en Pascal:

Código Delphi [-]
...
var
  varGlobal: Integer; // Global

function Funcion: Integer;
var
  Local: Integer; // Local a la función
begin
  varGlobal := 10; // Correcto
  Local     := 5;  // Correcto obviamente
  varLocal  := 10; // ¡¡ Error !! no accecible por Funcion
  Funcion   := Local;
end;

var
  varLocal: Integer; // Local a main, desconocida por todo el código que está encima.
                     // A diferencia de C/C++, Pascal no permite la inclusión de código 
                     // despues de finalizado el cuerpo principal del programa (.)
begin
  varGlobal := 10;  // Correcto
  varLocal  := 10;  // Correcto obviamente
  Local     := 15;  // ¡¡ Error !! no accesible
  WriteLn(varGlobal+varLocal);
  Readln;
end.

En el caso que utilices unidades, las variables declaradas en la sección de interface serán accesibles desde cualquier otra unidad que las incluya y las declaradas en la sección de implementation, privadas a la unidad.

Saludos.

[[FGarcia]]

Este codigo hace uso de un Form con un boton y un memo. Usa los nombres por defecto y el evnto OnClick del Boton.

Código Delphi [-]
unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
    varGlobal: integer;  //Declaro una variable Global
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
var
  varLocal: integer;
  otraVarLocal : integer;
begin
  varGlobal := 10;
  varLocal := 10;
  otraVarLocal := varGlobal + varLocal; //Suma aritmetica
  memo1.lines.add(IntToStr(varGlobal) + IntToStr(varLocal)); //Concatenacion de cadenas
  memo1.Lines.Add (inttostr(otravarlocal));
end;

end.

Al parecer tu estas haciendo un programa de terminal, no debe de variar demasiado.

Saludos y cuentanos si resuelves tus dudas.

[[FGarcia]]

Despues de postear mi anterior mensaje vi que Eficsa (Salve maestro!) te habia contestado. Asi que hice esto para clarificar mi conocimiento jejej

Código Delphi [-]
program Terminal;

//Aqui declaro variables globales o alguna otra cosa
var
  varGlobal: Integer; // Global


//declaramos procedimientos y funciiones que pueden ser usados por main
function SumaEnteros(A,B: Integer):integer;
var
  Local: Integer; // Local a la función
begin
  Local := A + B;
  result := Local;
end;

//Aqui inicia Main

var
  varLocal: Integer; // Local a main, desconocida por todo el código que está encima.
                       // A diferencia de C/C++, Pascal no permite la inclusión de código
                       // despues de finalizado el cuerpo principal del programa (.)
  otraLocal:integer;
begin
  varGlobal := 10;  // Correcto
  varLocal  := 10;  // Correcto obviamente
  //Local     := 15;  // ¡¡ Error !! no accesible

  otraLocal := SumaEnteros(varGlobal, varLocal);  //La forma larga
  WriteLn(otraLocal);

  WriteLn(SumaEnteros(varGlobal, varLocal)); //La forma corta

  Readln;
end.

end.

[Novatin]

Se me aclaro todo en el acto...

Creo que mi confusion surgió de los "Tontoriales" de pascal que lei.. , todos ellos indican una sola seccion de "VAR"... y no se me ocurrio incluir otra seccion "VAR" justo antes de main... yo me figuraba que debia estar dentro de BEGIN (principal)...

Menos mal que acá siempre puedo contar con Uds... Gracias por sus respuestas..

Un saludo.