Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > Varios
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos

Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 03-11-2016
rmendoza83 rmendoza83 is offline
Miembro
 
Registrado: Aug 2006
Posts: 48
Poder: 0
rmendoza83 Va por buen camino
Exclamation Asignar Dinamicamente Propiedad DisplayFormat antes de ejecutar X formulario o Report

Buenas Tardes amigos, un saludo cordial a todos, vuelvo al foro con una duda para ver si me pueden orientar de una forma poca engorrosa de como hacer esta rutina, muchos clientes me han pedido en mis sistemas que la cantidad de decimales se pueda editar, que sean menos o que no tenga, mayor fastidio ya que se imaginan cambiar en diseño de unos 200 formularios esa propiedad en todos los componentes que lo pidan, adicionalmente de unos 120 reportes que muestran montos y cantidades?

Entonces se me ocurrió hacer una rutina que verifique todos los componentes si posee dicha propiedad, lo que quería saber si delphi tiene métodos para "preguntar si dicha clase posee el displayformat" ya que en un principio pensé en hacer un arreglo de strings y colocar el nombre de cada posible componente que puede tener esa propiedad! lo bueno es que tengo como 4 plantillas de formularios y que la mayoría de los forms heredan estas plantillas y pues sera cómodo implementarlo, en el proyecto hago uso de componentes zeos y las rusas (rxlib), también los reportes están hechos en nevrona rave reports 7.0, y estamos usando BDS 2006, imagino que estos datos son importantes para el aporte de ideas.

De antemano les doy las gracias por cualquier ayuda que me presten!
Responder Con Cita
  #2  
Antiguo 03-11-2016
Avatar de Al González
[Al González] Al González is offline
In .pas since 1991
 
Registrado: May 2003
Posts: 5.512
Poder: 23
Al González Es un diamante en brutoAl González Es un diamante en brutoAl González Es un diamante en bruto
¿Cuántos diferentes formatos podría indicar el usuario en una misma aplicación?

¿Desean aplicar el cambio de manera global o selectivamente por formulario/componente?

¿Cuántas clases de componentes se involucran en ello y cuáles son sus nombres y de qué biblioteca provienen?

¿Cómo se llama(n) la(s) propiedad(es) de formato?

¿El formato de máscara es el mismo para todas esas clases o la interpretación varía dependiendo de la implementación de los componentes? ¿Todos ellos se adhieren al estándar de la clásica propiedad DisplayFormat?
__________________
Twitter
Código
Blog
WhatsApp para consultas rápidas y asesorías profesionales: +52 1 2711260117
Responder Con Cita
  #3  
Antiguo 03-11-2016
Avatar de movorack
[movorack] movorack is offline
Miguel A. Valero
 
Registrado: Feb 2007
Ubicación: Bogotá - Colombia
Posts: 1.100
Poder: 13
movorack Va camino a la fama
Código Delphi [-]
implementation
uses TypInfo;
{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
   if IsPublishedProp (Button1, 'Visible') then
    begin
      SetPropValue (Button1, 'Visible',false);
    end;

end;
__________________
Buena caza y buen remar... http://mivaler.blogspot.com
Responder Con Cita
  #4  
Antiguo 03-11-2016
rmendoza83 rmendoza83 is offline
Miembro
 
Registrado: Aug 2006
Posts: 48
Poder: 0
rmendoza83 Va por buen camino
Cita:
Empezado por Al González Ver Mensaje
¿Cuántos diferentes formatos podría indicar el usuario en una misma aplicación?

¿Desean aplicar el cambio de manera global o selectivamente por formulario/componente?

¿Cuántas clases de componentes se involucran en ello y cuáles son sus nombres y de qué biblioteca provienen?

¿Cómo se llama(n) la(s) propiedad(es) de formato?

¿El formato de máscara es el mismo para todas esas clases o la interpretación varía dependiendo de la implementación de los componentes? ¿Todos ellos se adhieren al estándar de la clásica propiedad DisplayFormat?
Al Gonzalez, gracias por la respuesta, basicamente el formato el formato sera uno solo siempre! "#,##0.0000", por defecto seran siempre 4 decimales, lo que me interesa hacer dinamico, es la cantidad de decimales, basicamente hare una funcion que devuelva el formato según una cantidad de decimales. El cambio sera siempre global! osea mucho hago con consentir al cliente con los decimales y pues mas adelante hare configurable ese cambio por formulario (realmente no sera dificil al tener el procedimiento basico que funcione para cualquier formulario), clases de componentes muchisimas, mas que todo las estandar de delphi y componentes de terceros solo uso las rusas (rxlib) , y la propiedad a cambiar (basicamente ya la dije en el titulo) es displayformat, en formularios y reportes, ojo, en el caso de componentes como el rx numeric field, debe asignar tambien el numero de decimales, que no seria gran problema ya que es simplemente preg por ese tipo de componente.
Responder Con Cita
  #5  
Antiguo 03-11-2016
rmendoza83 rmendoza83 is offline
Miembro
 
Registrado: Aug 2006
Posts: 48
Poder: 0
rmendoza83 Va por buen camino
Gracias movorack!!!

Cita:
Empezado por movorack Ver Mensaje
Código Delphi [-]
implementation
uses TypInfo;
{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
   if IsPublishedProp (Button1, 'Visible') then
    begin
      SetPropValue (Button1, 'Visible',false);
    end;

end;
creo que basicamente era lo que estaba buscando! sera implementable estos métodos en delphi 2006? BDS 2006, el otro detalle es con los reportes de rave reports! hay muy poca documentación de ellas en la red!
Responder Con Cita
  #6  
Antiguo 03-11-2016
Avatar de movorack
[movorack] movorack is offline
Miguel A. Valero
 
Registrado: Feb 2007
Ubicación: Bogotá - Colombia
Posts: 1.100
Poder: 13
movorack Va camino a la fama
Tengo D5 y XE3 en mi pc y ahí funciona. Creo que deberá funcionar en 2006.

Con respecto a Rave Reports, La verdad, no lo manejo.
__________________
Buena caza y buen remar... http://mivaler.blogspot.com
Responder Con Cita
  #7  
Antiguo 03-11-2016
Avatar de Al González
[Al González] Al González is offline
In .pas since 1991
 
Registrado: May 2003
Posts: 5.512
Poder: 23
Al González Es un diamante en brutoAl González Es un diamante en brutoAl González Es un diamante en bruto
Creo que este hilo, y en especial la respuesta de cadetill (a quien envío un cordial saludo), te servirá:
http://www.clubdelphi.com/foros/showthread.php?t=8730

Por cierto, lo que comenté ahí en 2004 ha perdido un poco de vigencia. Ya que desde la versión 2010 existe una RTTI extendida con mayores capacidades.

Saludos.
__________________
Twitter
Código
Blog
WhatsApp para consultas rápidas y asesorías profesionales: +52 1 2711260117
Responder Con Cita
  #8  
Antiguo 04-11-2016
rmendoza83 rmendoza83 is offline
Miembro
 
Registrado: Aug 2006
Posts: 48
Poder: 0
rmendoza83 Va por buen camino
Cita:
Empezado por movorack Ver Mensaje
Tengo D5 y XE3 en mi pc y ahí funciona. Creo que deberá funcionar en 2006.

Con respecto a Rave Reports, La verdad, no lo manejo.
Listo! Me pondre en estos momentos a hacer la rutina! la compartire al tenerla lista, estoy seguro que a muchos les sera de utilidad!
Responder Con Cita
  #9  
Antiguo 04-11-2016
rmendoza83 rmendoza83 is offline
Miembro
 
Registrado: Aug 2006
Posts: 48
Poder: 0
rmendoza83 Va por buen camino
Cita:
Empezado por Al González Ver Mensaje
Creo que este hilo, y en especial la respuesta de cadetill (a quien envío un cordial saludo), te servirá:
http://www.clubdelphi.com/foros/showthread.php?t=8730

Por cierto, lo que comenté ahí en 2004 ha perdido un poco de vigencia. Ya que desde la versión 2010 existe una RTTI extendida con mayores capacidades.

Saludos.
Considerado amigo! muchas gracias por la ayuda
Responder Con Cita
  #10  
Antiguo 04-11-2016
rmendoza83 rmendoza83 is offline
Miembro
 
Registrado: Aug 2006
Posts: 48
Poder: 0
rmendoza83 Va por buen camino
Completado Los Formularios Muchachos!!!

Bueno mi gente, muchas gracias por el aporte de ideas, logre resolver por el lado de delphi, me queda ahora ver como lo hago con Rave Reports, en un principio pensaba que la clase Component manejaba una propiedad de los componentes contenidos en el y ya me habia hecho una funcion recursiva y todo jejejeje, pero al depurar note que el arreglo Components y el ComponentCount devuelven los datos de todos los componentes indiferentemente de si estan contenidos o no, creo que debio haber sido una duda que tuve desde hace muchos años ya que programo en otros lenguajes, creo que java es asi y pense que delphi tambien, pero bueh funciona muy bien, les adjunto el codigo para quien le pueda ser util.

Código Delphi [-]
//Procedimientos y Funciones especiales para el cambio automatico del DisplayFormat
procedure AsignarDisplayFormat(Component: TComponent; NumeroDecimales: Integer);
var
  Formato: string;
begin
  Formato := '#,##0.' + StringOfChar('0',NumeroDecimales);
  if (Component.ClassName = 'TCurrencyEdit') then
  begin
    (Component as TCurrencyEdit).DisplayFormat := Formato;
    (Component as TCurrencyEdit).DecimalPlaces := NumeroDecimales;
  end;
  if (Component.ClassName = 'TFloatField') then
  begin
    (Component as TFloatField).DisplayFormat := Formato;
  end;
end;

procedure BuscarDisplayFormat(Form: TForm; NumeroDecimales: Integer);
var
  i: Integer;
begin
  for i := 0 to Form.ComponentCount - 1 do
  begin
    if (IsPublishedProp(Form.Components[i],'DisplayFormat')) then
    begin
      AsignarDisplayFormat(Form.Components[i],NumeroDecimales);
    end;
  end;
end;

Hice el procedimiento AsignarDisplayFormat de esa manera ya que no se si haya otra manera mas agradable de escribir jejejeje, se aceptan sugerencias en el codigo tambien.

Me pondre ahora con rave! ahi creo que si sera una total aventura!!! jejeje

Última edición por rmendoza83 fecha: 04-11-2016 a las 19:06:16. Razón: Correccion en el Codigo de Delphi
Responder Con Cita
  #11  
Antiguo 04-11-2016
Avatar de ecfisa
ecfisa ecfisa is offline
Moderador
 
Registrado: Dec 2005
Ubicación: Tres Arroyos, Argentina
Posts: 10.126
Poder: 30
ecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to behold
Hola.

No uso los componentes que mencionas pero tal vez esta opción, que almacena y por tanto "recuerda" el último formato elegido, te podría ser útil:
Código Delphi [-]
unit uCurrFormat;

interface

uses Classes;

type
  TCurrFormat  = class
  private
    FIniFileName  : string;
    FDefaultFormat: string;
    FGlobalFormat : string;
    function  GetGlobalFormat: string;
    procedure SetGlobalFormat( const StrFormat: string );
  public
    constructor Create;
    procedure SetDisplayFormat( TC: TComponent );
    property Format: string read FGlobalFormat write SetGlobalFormat;
  end;

var
  CurrFormat: TCurrFormat;

implementation

uses SysUtils, Forms, TypInfo, IniFiles, DB;

constructor TCurrFormat.Create;
begin
  FIniFileName   := ExtractFilePath(Application.ExeName) + 'IniFile.ini';
  FDefaultFormat := '#,##0.0000';
  FGlobalFormat  := GetGlobalFormat;
end;

function TCurrFormat.GetGlobalFormat: string;
var
  ini : TIniFile;
begin
  ini := TIniFile.Create( FIniFileName );
  try
    if not FileExists( FIniFileName ) then
    begin
      Result := FDefaultFormat;
      ini.WriteString( 'DisplayFormat', 'Format', Result );
    end
    else
      Result := ini.ReadString( 'DisplayFormat', 'Format', '' );
  finally
    ini.Free;
  end;
end;

procedure TCurrFormat.SetGlobalFormat( const StrFormat: string );
var
  ini : TIniFile;
begin
  ini := TIniFile.Create( FIniFileName );
  try
    FGlobalFormat := StrFormat;
    if not FileExists( FIniFileName ) then
      ini.WriteString( 'DisplayFormat', 'Format', FDefaultFormat )
    else
      ini.WriteString( 'DisplayFormat', 'Format', FGlobalFormat );
  finally
    ini.Free;
  end;
end;

procedure TCurrFormat.SetDisplayFormat( TC: TComponent );
var
  i, j: Integer;
  fld : TField;
  pNfo: PPropInfo;
begin
  for i := 0 to TC.ComponentCount-1 do
  begin
    if TC.Components[i] is TDataSet then
    begin
      for j := 0 to TDataSet( TC.Components[i] ).FieldCount-1 do
      begin
        fld := TDataSet( TC.Components[i] ).Fields[j];
        if fld is TCurrencyField then
          TCurrencyField(fld).DisplayFormat := FGlobalFormat;
      end;
    end
    else
    begin
      pNfo := GetPropInfo( TC.Components[i], 'DisplayFormat' );
      if Assigned( pNfo ) then
        SetStrProp( TC.Components[i], pNfo, FGlobalFormat );
    end;
  end;
end;

initialization
  if not Assigned ( CurrFormat ) then
    CurrFormat := TCurrFormat.Create;

finalization
  CurrFormat := nil;
end.

Ejemplo del uso:

DataModule,
Código Delphi [-]
unit Unit2;
...
implementation

uses uCurrFormat;

procedure TDataModule1.DataModuleCreate(Sender: TObject);
begin
  DataSet.Open;
  CurrFormat.SetDisplayFormat(DataModule1); // (*)
end;

Form,
Código Delphi [-]
...
var
  MainForm: TMainForm;

implementation

uses Unit2{ DataModule }, uCurrFormat;

procedure TMainForm.Button1Click(Sender: TObject);
var
  peso: string;
begin
  if CheckBox1.Checked then
    peso := '$ '
  else
    peso := '';
  CurrFormat.Format := peso +'#,##0.' + StringOfChar('0', SpinEdit1.Value);
  CurrFormat.SetDisplayFormat(DataModule1);
end;
...

Vista del ejemplo:


(*) En esta línea se aplica el formato almacenado a los componentes del contenedor (form, datamodule, ) , por lo que tendrías que usarla en todas aquellas unidades en que desees visualizar el formato.

Saludos

Pd: (Si tenes alguna dificultad para implementarlo, avisame y te adjunto el código fuente del ejemplo)
__________________
Daniel Didriksen

Guía de estilo - Uso de las etiquetas - La otra guía de estilo ....
Responder Con Cita
  #12  
Antiguo 04-11-2016
rmendoza83 rmendoza83 is offline
Miembro
 
Registrado: Aug 2006
Posts: 48
Poder: 0
rmendoza83 Va por buen camino
Cita:
Empezado por ecfisa Ver Mensaje
Hola.

No uso los componentes que mencionas pero tal vez esta opción, que almacena y por tanto "recuerda" el último formato elegido, te podría ser útil:
Código Delphi [-]
unit uCurrFormat;

interface

uses Classes;

type
  TCurrFormat  = class
  private
    FIniFileName  : string;
    FDefaultFormat: string;
    FGlobalFormat : string;
    function  GetGlobalFormat: string;
    procedure SetGlobalFormat( const StrFormat: string );
  public
    constructor Create;
    procedure SetDisplayFormat( TC: TComponent );
    property Format: string read FGlobalFormat write SetGlobalFormat;
  end;

var
  CurrFormat: TCurrFormat;

implementation

uses SysUtils, Forms, TypInfo, IniFiles, DB;

constructor TCurrFormat.Create;
begin
  FIniFileName   := ExtractFilePath(Application.ExeName) + 'IniFile.ini';
  FDefaultFormat := '#,##0.0000';
  FGlobalFormat  := GetGlobalFormat;
end;

function TCurrFormat.GetGlobalFormat: string;
var
  ini : TIniFile;
begin
  ini := TIniFile.Create( FIniFileName );
  try
    if not FileExists( FIniFileName ) then
    begin
      Result := FDefaultFormat;
      ini.WriteString( 'DisplayFormat', 'Format', Result );
    end
    else
      Result := ini.ReadString( 'DisplayFormat', 'Format', '' );
  finally
    ini.Free;
  end;
end;

procedure TCurrFormat.SetGlobalFormat( const StrFormat: string );
var
  ini : TIniFile;
begin
  ini := TIniFile.Create( FIniFileName );
  try
    FGlobalFormat := StrFormat;
    if not FileExists( FIniFileName ) then
      ini.WriteString( 'DisplayFormat', 'Format', FDefaultFormat )
    else
      ini.WriteString( 'DisplayFormat', 'Format', FGlobalFormat );
  finally
    ini.Free;
  end;
end;

procedure TCurrFormat.SetDisplayFormat( TC: TComponent );
var
  i, j: Integer;
  fld : TField;
  pNfo: PPropInfo;
begin
  for i := 0 to TC.ComponentCount-1 do
  begin
    if TC.Components[i] is TDataSet then
    begin
      for j := 0 to TDataSet( TC.Components[i] ).FieldCount-1 do
      begin
        fld := TDataSet( TC.Components[i] ).Fields[j];
        if fld is TCurrencyField then
          TCurrencyField(fld).DisplayFormat := FGlobalFormat;
      end;
    end
    else
    begin
      pNfo := GetPropInfo( TC.Components[i], 'DisplayFormat' );
      if Assigned( pNfo ) then
        SetStrProp( TC.Components[i], pNfo, FGlobalFormat );
    end;
  end;
end;

initialization
  if not Assigned ( CurrFormat ) then
    CurrFormat := TCurrFormat.Create;

finalization
  CurrFormat := nil;
end.

Ejemplo del uso:

DataModule,
Código Delphi [-]
unit Unit2;
...
implementation

uses uCurrFormat;

procedure TDataModule1.DataModuleCreate(Sender: TObject);
begin
  DataSet.Open;
  CurrFormat.SetDisplayFormat(DataModule1); // (*)
end;

Form,
Código Delphi [-]
...
var
  MainForm: TMainForm;

implementation

uses Unit2{ DataModule }, uCurrFormat;

procedure TMainForm.Button1Click(Sender: TObject);
var
  peso: string;
begin
  if CheckBox1.Checked then
    peso := '$ '
  else
    peso := '';
  CurrFormat.Format := peso +'#,##0.' + StringOfChar('0', SpinEdit1.Value);
  CurrFormat.SetDisplayFormat(DataModule1);
end;
...

Vista del ejemplo:


(*) En esta línea se aplica el formato almacenado a los componentes del contenedor (form, datamodule, ) , por lo que tendrías que usarla en todas aquellas unidades en que desees visualizar el formato.

Saludos

Pd: (Si tenes alguna dificultad para implementarlo, avisame y te adjunto el código fuente del ejemplo)
Interesante lo que propones, de verdad, aunque con lo que hice logre implementarlo sin ningun problema! como bien dije anteriormente solo me queda solucionar lo de rave reports!
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
Asignar dinámicamente valores a propiedades sin conocer previamente cuáles Leviatan OOP 4 31-01-2012 01:34:59
La propiedad DisplayFormat gcaffe Varios 1 25-12-2009 16:18:01
Cambiar propiedad de componente del formulario padre al cerrar el formulario hijo jzginez OOP 5 22-06-2007 22:40:51
Asignar evento on exit y otros a varios labeledit creados dinamicamente cotoprix OOP 2 09-01-2004 00:05:53
asignar evento a control creado dinamicamente jorgeganc Varios 4 17-12-2003 03:47:51


La franja horaria es GMT +2. Ahora son las 18:06:09.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi